02-单片机入门_点灯

02-单片机入门_点灯

通过汇编代码点亮LED

先看看原理图-看点灯需要操作哪一些GPIO端口

在原理图中有三个LED , 分别是 nLED_1 , nLED_2 , nLED_4

同时nLED_1中的n，表示低电平有效

这三个LED分配连接的GPIO端口是：GPF4 , GPF5, GPF6

看用户手册，这3个GPIO端口怎么操作

配置GPF4 , GPF5 , GPF6 为输出端口

配置GPFDAT 的 4， 5 ，6 位为0（nLED_1低电平有效）

编写代码

led_on.S

.text
.global _start

_start:

/* 配置GPF4,GPF5,GPF6为输出引脚
 * 把=0x1500写到地址0x56000050
 */
	ldr r1, =0x56000050
	ldr r0, =0x1500	/* mov r0, #0x1500 */
	str r0, [r1]


/* 设置GPF4,GPF5,GPF6输出低电平 
 * 把0写到地址0x56000054
 */
	ldr r1, =0x56000054
	ldr r0, =0	/* mov r0, #0 */
	str r0, [r1]

	/* 死循环 */
halt:
	b halt

Makefile

all:
	arm-linux-gcc -c -o led_on.o led_on.S
	arm-linux-ld -Ttext 0 led_on.o -o led_on.elf
	arm-linux-objcopy -O binary -S led_on.elf led_on.bin
	arm-linux-objdump -D led_on.elf > led_on.dis
clean:
	rm *.bin *.o *.elf

进行编译，生成led_on.bin

通过openjtag刷入nand flash，将开发板启动项拨向Nand flash，打开电源，3个LED点亮

再通过openjtag将led_on.bin刷入nor flash，以nor flash启动，也是正常点亮

通过C语言代码点亮LED

C语言的函数需要用到栈传递参数（栈就是一片内存空间），这里就需要看看jz2440在单片机模式下的内存布局

先讲讲nor flash 和 nand flash 在非指令模式下的简单区别

nor flash	nand flash
可存储代码，像硬盘一样	可存储代码，像硬盘一样
可执行代码，但无法修改norFlash的数据（可读，可执行）	不能执行代码，需要把代码复制到SRAM（SRAM像内存条一样）执行

在上表中，包含了3个硬件：

• Nor flash：
  • 1）可以像固态硬盘一样存储数据，
  • 2）从nor flash启动之后，nor flash也像包含代码的内存空间，可以执行代码，
  • 3）由于nor flash本身是存储代码的，为了让其上的数据不被破坏，在其内存空间上无法进行写操作，
  • 4）JZ2440上nor flash的大小为2M
• Nand flash:
  • 1）可以单纯的理解为PC上的固态硬盘，
  • 2）在JZ440上Nand flash大小为256M
• SRAM :
  • 1）片内内存（可读，可写，可执行)，
  • 2）在JZ2440上SRAM大小为4K

在JZ2440中，也有像PC上内存条一样的硬件，叫做SDRAM，但是需要初始化，暂时就当这个硬件不存在

再说到C语言函数的栈，是需要可被修改的（能被进行写操作）

1）在之前的点亮3个LED的例子中，有nor启动和nand启动

nor启动：

• Nor Flash的基地址为0，片内RAM地址为0x4000 0000;
• CPU读出Nor上第1个指令（前4字节），执行；
• CPU继续读出其它指令执行。

nand启动：

• 片内4k RAM基地址为0，Nor Flash不可访问；
• 2440硬件把Nand前4K内容复制到片内的RAM，然后CPU从0地址取出第1条指令执行

2）当前需要编写C语言的函数，需要栈，而栈是往下增长的，所以nor flash启动和nand flash启动，栈的设置如下

3）怎么判断是Nor 启动还是Nand Flash启动

从Nor Flash 和 Nand Flash启动的区别是啥：

• 从Nor Flash启动：0地址在Nor Flash的地址空间上，0地址不可修改
• 从Nand Flash启动： 0地址在SRAM的地址空间上，0地址可被修改

通过判断0地址是否被修改，来判断是从nor启动还是nand启动

4）关闭看门狗

2440里面有个看门狗定时器，开发板上电后，需要在一定时间内“喂狗”（设置相应的寄存器），否则就会重启开发。这里直接关闭看门狗

编写如下

start.S

.text
.global _start

_start:

	/* 关闭看门狗 */
	ldr r0, =0x53000000
	ldr r1, =0
	str r1, [r0]

	/* 设置内存: sp 栈 */
	/* 分辨是nor/nand启动
	 * 写0到0地址, 再读出来
	 * 如果得到0, 表示0地址上的内容被修改了, 它对应ram, 这就是nand启动
	 * 否则就是nor启动
	 */
	mov r1, #0
	ldr r0, [r1] /* 读出原来的值备份 */
	str r1, [r1] /* 0->[0] */ 
	ldr r2, [r1] /* r2=[0] */
	cmp r1, r2   /* r1==r2? 如果相等表示是NAND启动 */
	ldr sp, =0x40000000+4096 /* 先假设是nor启动 */
	moveq sp, #4096  /* nand启动 */
	streq r0, [r1]   /* 恢复原来的值 */
	

	bl main

halt:
	b halt

led.c

void delay(volatile int d)
{
	while (d--);
}

int main(void)
{
	volatile unsigned int *pGPFCON = (volatile unsigned int *)0x56000050;
	volatile unsigned int *pGPFDAT = (volatile unsigned int *)0x56000054;
	int val = 0;  /* val: 0b000, 0b111 */
	int tmp;

	/* 设置GPFCON让GPF4/5/6配置为输出引脚 */
	*pGPFCON &= ~((3<<8) | (3<<10) | (3<<12));
	*pGPFCON |=  ((1<<8) | (1<<10) | (1<<12));

	/* 循环点亮 */
	while (1)
	{
		tmp = ~val;
		tmp &= 7;
		*pGPFDAT &= ~(7<<4);
		*pGPFDAT |= (tmp<<4);
		delay(100000);
		val++;
		if (val == 8)
			val =0;
		
	}

	return 0;
}

Makefile

all:
	arm-linux-gcc -c -o led.o led.c
	arm-linux-gcc -c -o start.o start.S
	arm-linux-ld -Ttext 0 start.o led.o -o led.elf
	arm-linux-objcopy -O binary -S led.elf led.bin
	arm-linux-objdump -D led.elf > led.dis
clean:
	rm *.bin *.o *.elf *.dis