最长公共回文子序列ah

题目描述
YJC最近在学习字符串的有关知识。今天，他遇到了这么一个概念：最长公共回文子序列。一个序列S，如果S是回文的且分别是两个或多个已知序列的子序列，且是所有符合此条件序列中最长的，则 S 称为已知序列的最长公共回文子序列。YJC很聪明，他很快就学会了如何求最长公共回文子序列。他现在想把问题规模扩大一些，于是他提出了这么一个问题：给一个长度为n(1≤n≤100000)的字符串a和一个长度为m(1≤m≤20)的字符串b，求a和b的最长公共回文子序列的长度。YJC发现他不会做了，于是他来问你这个问题的答案。

输入
第一行包含一个字符串，表示字符串a。
第二行包含一个字符串，表示字符串b。
输出
一行，包含一个整数，表示a和b的最长公共回文子序列的长度。

样例输入
aaaba
aabba
样例输出
3

提示
最长公共回文子序列是aaa，长度为3。最长公共子序列是aaba，但它不是回文的。
【数据说明】
对于50%的数据，满足1≤n≤100。
对于100%的数据，满足1≤n≤100000，1≤m≤20，字符串只包含小写字母。

注意到m只有20，暴力枚举b的所有子序列，再用O(m)判断是否回文和是否存在于a串中，至于如何判断在a串中，只需对a串进行预处理，预处理出next[i,s]表示在i位置只有，离i最近的字符s在哪个位置。O(m)扫一遍就可以了。

var
s1:ansistring;
s2:string;
len,i,ans,j:longint;
f:array[0..22] of longint;
pre:array['a'..'z'] of longint;
next:array[0..1000111,'a'..'z'] of longint;
function max(a,b:longint):longint;
begin
  if a>b then exit(a) else exit(b);
end;

function check(x:string):boolean;
var
i,len:longint;
begin
  if x='' then exit(false);
  len:=length(x);
  for i:=1 to len do
    if x[i]<>x[len-i+1] then exit(false);
  exit(true);
end;

function pd(x:string):boolean;
var
i,p:longint;
begin
  p:=0;
  for i:=1 to length(x) do
    if next[p,x[i]]=0 then exit(false)
                      else p:=next[p,x[i]];
  exit(true);
end;

procedure add;
var
x:string;
i:longint;
begin
  x:='';
  for i:=1 to len do
    if f[i]=1 then x:=x+s2[i];
  if check(x) then if pd(x) then ans:=max(ans,length(x));
end;

procedure dfs(i:longint);
begin
  if i=len then begin add; exit; end;
  i:=i+1;
  f[i]:=1;
  dfs(i);
  f[i]:=0;
  dfs(i);
end;

begin
  readln(s1);
  readln(s2);
  len:=length(s2);
  for i:=1 to length(s1) do
  begin
    for j:=pre[s1[i]] to i-1 do
      next[j,s1[i]]:=i;
    pre[s1[i]]:=i;
  end;
  dfs(0);
  write(ans);
end.