VBA学习9_ fso提取汇总文件夹及其下的文件名及内容（递归操作字典汇总）

文件系统对象FSO的英文全称是File System Object ，这种对象模型提出了有别于传统的文件操作语句处理文件和文件夹的方法。通过采用object.method这种在面向对象编程中广泛使用的语法，将一系列操作文件和文件夹的动作通过调用对象本身的属性直接实现。

FSO 对象模型不仅可以象使用传统文件操作语句那样实现文件的创建、改变、移动和删除，而且可以检测是否存在指定的文件夹，如果存在，那么，这个文件夹又位于磁盘上的什么位置。更令人高兴的是FSO 对象模型还可以获取关于文件和文件夹的信息，如名称、创建日期或最近修改日期等以及当前系统中使用的驱动器的信息，如驱动器的种类是CD－ROM还是可移动磁盘，当前磁盘的剩余空间还有多少。

Fso对象有关的方法属性等，大家可以自行查阅帮助，在此不具体介绍。

对于用的相对较多的便利当前文件夹下的文件、文件夹；汇总相关文件等进行一个简单的介绍。仅仅是个人对于问题处理过程的一个介绍，具体代码有很大的调整空间，各位可以根据需求调整。

当然大家也完全可以考虑使用dir的

一、遍历当前文件夹下一层子文件夹

提取当前文件夹下一层文件夹名称并放在A列

二、遍历当前文件夹内文件名

提取当前文件夹下的文件名称并放在A列

三、遍历当前文件夹所有子文件夹

采用递归遍历

四、遍历当前文件夹及所有子文件夹下的文件

采用递归遍历

五、汇总当前文件夹及子文件夹下所有excel文件内容

Excel文件格式一致，汇总求和，其他需求自行变通 容
遍历当前文件夹及子文件，汇总各个excel文件的各个sheet里的内容

7楼对本段代码做了调整

一、遍历当前文件夹下一层子文件夹
Sub 按钮1_Click()
    Application.ScreenUpdating = False
    Set fso = CreateObject("scripting.filesystemobject")
    Set ff = fso.getfolder(ThisWorkbook.Path) 'ThisWorkbook.Path是当前代码文件所在路径，路径名可以根据需求修改
    ActiveSheet.UsedRange.ClearContents
    a = 1
    For Each fd In ff.subfolders
        Cells(a, 1) = fd.Name '子文件夹名,相对于当前文件夹的名字
        Cells(a, 2) = fd '子文件夹全路径
        a = a + 1
    Next fd
    Application.ScreenUpdating = True
End Sub

二、遍历当前文件夹内文件名

提取当前文件夹下的文件名称并放在A列
Sub 按钮1_Click()
    Application.ScreenUpdating = False
    Set fso = CreateObject("scripting.filesystemobject")
    Set ff = fso.getfolder(ThisWorkbook.Path) 'ThisWorkbook.Path是当前代码文件所在路径，路径名可以根据需求修改
    ActiveSheet.UsedRange.ClearContents
    a = 1
    For Each f In ff.Files
        Rem 如果不需要提取本代码文件名，可以增加if语句 if f.name<> thisworkbook.name then.....
        Rem 如果值需要提取某类文件，需要对f.name的扩展名进行判断
        Rem 个人感觉split取 扩展名：split（f.name,".")(ubound（split（f.name,".")）)，然后再判断，避免文件名还有其他“.”
        Cells(a, 1) = f.Name '相对路径名
        Cells(a, 2) = f '全路径名
        a = a + 1
    Next f
    Application.ScreenUpdating = True
End Sub

三、遍历当前文件夹所有子文件夹 使用了递归。。。。 Sub 按钮1_Click()     Application.ScreenUpdating = False     ActiveSheet.UsedRange.ClearContents     Cells(1, 1) = "文件夹名"     Getfd (ThisWorkbook.Path) 'ThisWorkbook.Path是当前代码文件所在路径，路径名可以根据需求修改     Application.ScreenUpdating = True End Sub Sub Getfd(ByVal pth)     Set Fso = CreateObject("scripting.filesystemobject")     Set ff = Fso.getfolder(pth)     Cells(Rows.Count, 1).End(3).Offset(1) = pth     For Each fd In ff.subfolders         Getfd (fd)     Next fd End Sub

四、遍历当前文件夹及所有子文件夹下的文件
还是递归

Sub 按钮1_Click()
    Application.ScreenUpdating = False
    ActiveSheet.UsedRange.ClearContents
    Cells(1, 1) = "相对路径文件名"
    Cells(1, 2) = "绝对路径文件名"
    Getfd (ThisWorkbook.Path) 'ThisWorkbook.Path是当前代码文件所在路径，路径名可以根据需求修改
    Application.ScreenUpdating = True
End Sub
Sub Getfd(ByVal pth)
    Set Fso = CreateObject("scripting.filesystemobject")
    Set ff = Fso.getfolder(pth)
    For Each f In ff.Files
        Rem 具体提取哪类文件，还是需要根据文件扩展名进行处理
        Cells(Rows.Count, 1).End(3).Offset(1) = f.Name
        Cells(Rows.Count, 2).End(3).Offset(1) = f
    Next f
    For Each fd In ff.subfolders
        Getfd (fd)
    Next fd
End Sub

五、汇总当前文件夹及子文件夹下所有excel文件内容 Excel文件格式一致，汇总求和，其他需求自行变通容 汇总使用了字典 Public d Sub 按钮1_Click()     Application.ScreenUpdating = False     ActiveSheet.UsedRange.ClearContents     Cells(1, 1) = "编号"     Cells(1, 2) = "数量"     Set d = CreateObject("scripting.dictionary")     Getfd (ThisWorkbook.Path) 'ThisWorkbook.Path是当前代码文件所在路径，路径名可以根据需求修改     Application.ScreenUpdating = True     If d.Count > 0 Then         ThisWorkbook.Sheets(1).[a2].Resize(d.Count) = WorksheetFunction.Transpose(d.keys)         ThisWorkbook.Sheets(1).[b2].Resize(d.Count) = WorksheetFunction.Transpose(d.items)     End If End Sub Sub Getfd(ByVal pth)          Set Fso = CreateObject("scripting.filesystemobject")     Set ff = Fso.getfolder(pth)     For Each f In ff.Files         Rem 具体提取哪类文件，还是需要根据文件扩展名进行处理         If InStr(Split(f.Name, ".")(UBound(Split(f.Name, "."))), "xl") > 0 Then             If f.Name <> ThisWorkbook.Name Then                 Set wb = Workbooks.Open(f)                 For Each sht In wb.Sheets                     If WorksheetFunction.CountA(sht.UsedRange) > 1 Then                         arr = sht.UsedRange                         For j = 2 To UBound(arr)                             d(arr(j, 1)) = d(arr(j, 1)) + arr(j, 2)                         Next j                     End If                 Next sht                 wb.Close False             End If         End If     Next f     For Each fd In ff.subfolders         Getfd (fd)     Next fd End Sub

五-改、汇总当前文件夹及子文件夹下所有excel文件内容
增加了红色字体部分
Public d
Sub 按钮1_Click()
    Application.ScreenUpdating = False
    ActiveSheet.UsedRange.ClearContents
    Cells(1, 1) = "编号"
    Cells(1, 2) = "数量"
    Set d = CreateObject("scripting.dictionary")
    Getfd (ThisWorkbook.Path) 'ThisWorkbook.Path是当前代码文件所在路径，路径名可以根据需求修改
    Application.ScreenUpdating = True
    If d.Count > 0 Then
        ThisWorkbook.Sheets(1).[a2].Resize(d.Count) = WorksheetFunction.Transpose(d.keys)
        ThisWorkbook.Sheets(1).[b2].Resize(d.Count) = WorksheetFunction.Transpose(d.items)
    End If
    d.RemoveAll
End Sub
Sub Getfd(ByVal pth)
    
    Set Fso = CreateObject("scripting.filesystemobject")
    Set ff = Fso.getfolder(pth)
    For Each f In ff.Files
        Rem 具体提取哪类文件，还是需要根据文件扩展名进行处理
        If InStr(Split(f.Name, ".")(UBound(Split(f.Name, "."))), "xl") > 0 Then
            If f.Name <> ThisWorkbook.Name Then
                Set wb = Workbooks.Open(f)
                For Each sht In wb.Sheets
                    If WorksheetFunction.CountA(sht.UsedRange) > 1 Then
                        arr = sht.UsedRange
                        For j = 2 To UBound(arr)
                            d(arr(j, 1)) = d(arr(j, 1)) + arr(j, 2)
                        Next j
                    End If
                Next sht
                wb.Close False
            End If
        End If
    Next f
    For Each fd In ff.subfolders
        Getfd (fd)
    Next fd
End Sub

原文来自：http://club.excelhome.net/thread-1165866-1-1.html