ORACLE EXECUTE IMMEDIATE 小结

一、总体介绍
EXECUTE IMMEDIATE代替了以前Oracle8i中DBMS_SQL package包.
它解析并马上执行动态的SQL语句或非运行时创建的PL/SQL块.
动态创建和执行SQL语句性能超前，推荐使用EXECUTE IMMEDIATE,因为它获的收益在DBMS_SQL包之上。

二、使用技巧
1. EXECUTE IMMEDIATE将不会提交一个DML事务执行，应该显式提交
如果通过EXECUTE IMMEDIATE处理DML命令，
那么在完成以前需要显式提交或者作为EXECUTE IMMEDIATE自己的一部分.
如果通过EXECUTE IMMEDIATE处理DDL命令,它提交所有以前改变的数据

2. 不支持返回多行的查询,这种交互将用临时表来存储记录(参照例子如下)或者用REF cursors.

3. 当执行SQL语句时，不要用分号，当执行PL/SQL块时，在其尾部用分号.

三、EXECUTE IMMEDIATE -- 用法例子
1. 在PL/SQL运行DDL语句
begin
   execute immediate 'set role all';
end;

2. 给动态语句传值(USING 子句)
declare
   l_depnam varchar2(20) := 'testing';
   l_loc     varchar2(10) := 'Dubai';
   begin
   execute immediate 'insert into dept values   (:1, :2, :3)'
     using 50, l_depnam, l_loc;
   commit;
end;

3. 从动态语句检索值(INTO子句)
declare
   l_cnt     varchar2(20);
begin
   execute immediate 'select count(1) from emp'
     into l_cnt;
   dbms_output.put_line(l_cnt);
end;

4. 动态调用例程.例程中用到的绑定变量参数必须指定参数类型.
黓认为IN类型,其它类型必须显式指定
declare
   l_routin    varchar2(100) := 'gen2161.get_rowcnt';
   l_tblnam    varchar2(20) := 'emp';
   l_cnt       number;
   l_status    varchar2(200);
begin
   execute immediate 'begin ' || l_routin || '(:2, :3, :4); end;'
     using in l_tblnam, out l_cnt, in out l_status;

   if l_status != 'OK' then
      dbms_output.put_line('error');
   end if;
end;

5. 将返回值传递到PL/SQL记录类型;同样也可用%rowtype变量
declare
   type empdtlrec is record (empno   number(4),
                            ename   varchar2(20),
                            deptno   number(2));
   empdtl empdtlrec;
begin
   execute immediate 'select empno, ename, deptno ' ||
                    'from emp where empno = 7934'
     into empdtl;
end;

6. 传递并检索值.INTO子句用在USING子句前

declare
   l_dept     pls_integer := 20;
   l_nam      varchar2(20);
   l_loc      varchar2(20);
begin
   execute immediate 'select dname, loc from dept where deptno = :1'
     into l_nam, l_loc
     using l_dept ;
end;

7. 多行查询选项.对此选项用insert语句填充临时表，
用临时表进行进一步的处理,也可以用REF cursors纠正此缺憾.

declare
   l_sal    pls_integer := 2000;
begin
   execute immediate 'insert into temp(empno, ename) ' ||
                    '           select empno, ename from emp ' ||
                    '           where   sal > :1'
     using l_sal;
   commit;
end;

要想实现在PL/SQL中使用DDL语句及系统控制语句，可以通过使用动态SQL来实现。
所谓静态SQL 指在PL/SQL块中使用的SQL语句在编译时是明确的，执行的是确定对象。而动态SQL是指在PL/SQL块编译时SQL语句是不确定的，如根据用户输入的参数的不同而执行不同的操作。
编译程序对动态语句部分不进行处理，只是在程序运行时动态地创建语句、对语句进行语法分析并执行该语句。
Oracle中动态SQL可以通过本地动态SQL来执行，也可以通过DBMS_SQL包来执行。下面就这两种情况分别进行说明：
一、本地动态SQL
　　本地动态SQL是使用EXECUTE IMMEDIATE语句来实现的。
二、使用DBMS_SQL包
　　使用DBMS_SQL包实现动态SQL的步骤如下：
  A、先将要执行的SQL语句或一个语句块放到一个字符串变量中。
  B、使用DBMS_SQL包的 parse过程来分析该字符串。
  C、使用DBMS_SQL包的bind_variable过程来绑定变量。
  D、使用DBMS_SQL包的execute函数来执行语句。
  如：
  sql_statment ：= 'select * from mc_t_custmain where department_code = :rightdepartmentCode';
  cid := DBMS_SQL.open_cursor;
    DBMS_SQL.parse(cid, sql_statment, DBMS_SQL.v7);
    --定义输出变量
    DBMS_SQL.define_column(cid, 1, v_department_code, 11);
  --绑定变量(必录)
    DBMS_SQL.bind_variable(cid,
                           ':rightdepartmentCode',
                           p_right_department_code);
  nrows := DBMS_SQL.execute(cid);    
  
  loop
      --创建循环点，过滤查询结果
      EXIT WHEN DBMS_SQL.FETCH_ROWS(cid) = 0;
      DBMS_SQL.column_value(cid, 1, v_department_code);     --将cid的第一个列赋值给v_department_code变量
    end loop;
    DBMS_SQL.close_cursor(cid);