Solidity合约间相互调用

以调用MetaCoin为例

部署MetaCoin合约

1、下载MetaCoin

mkdir MetaCoin
cd MetaCoin
truffle unbox metacoin

2、迁移MetaCoin到本地ganache网络

truffle migrate --reset

3、得到合约的地址

4、MetaCoin合约代码

pragma solidity >=0.4.25 <0.7.0;

import "./ConvertLib.sol";

contract MetaCoin {
	mapping (address => uint) balances;

	event Transfer(address indexed _from, address indexed _to, uint256 _value);

	constructor() public {
		balances[tx.origin] = 10000;
	}

	function sendCoin(address receiver, uint amount) public returns(bool sufficient) {
		if (balances[msg.sender] < amount) return false;
		balances[msg.sender] -= amount;
		balances[receiver] += amount;
		emit Transfer(msg.sender, receiver, amount);
		return true;
	}

	function getBalanceInEth(address addr) public view returns(uint){
		return ConvertLib.convert(getBalance(addr),2);
	}

	function getBalance(address addr) public view returns(uint) {
		return balances[addr];
	}
}

下面创建测试项目调用MetaCoin合约的getBalance方法。 

创建测试项目

1、创建空项目

mkdir testDemo
cd testDemo
truffle init

2、创建合约demo.sol

pragma solidity >=0.6.0 <0.9.0;

interface MetaCoinInterface {
	function getBalance(address addr) external view returns(uint);
}

contract Demo {    
    address private immutable reserveAddress;
    MetaCoinInterface metacoinContract;

    constructor(address _reserveAddress) {
        reserveAddress = _reserveAddress;
    }
    
    modifier onlyOwner() {
        require(msg.sender == reserveAddress, "only owner can call this");
        
        _;
    }

    function setMetaCoin(address _metacoinAddress) public onlyOwner {
        metacoinContract = MetaCoinInterface(_metacoinAddress);
    }

    function getMetaCoinBalance(address addr) public view returns(uint) {
        return metacoinContract.getBalance(addr);
    }
}

3、创建部署文件2_deploy_contracts.js

const Demo = artifacts.require("Demo");

module.exports = function(deployer) {
  deployer.deploy(Demo, "发布者的钱包地址");
};

4、进入控制台

truffle console

5、执行脚本

let accounts = await web3.eth.getAccounts()
let instance = await Demo.deployed()

await instance.setMetaCoin("MetaCoin合约地址")
let balance = await instance.getMetaCoinBalance(accounts[0])
balance.toString()