列表框的上移下移

嗨，大家好！！！

今天，我要给大家分享一个列表框的示例。

我们先来看一下演示：

 

我们要做的就是对列表框的数据做上移与下移的操作。可以对列表框中的数据做一个排序的操作。

那我们来看一下这个功能是怎么实现的。

01、设计表与窗体

首先，先做如下图一样的表

 

然后，如下图做一下窗体，窗体比较简单，放一个列表框，放两个按钮。

02、添加代码

Option Compare Database
Option Explicit
'声明用于替代文本值的常量
Private Const adOpenKeyset As Long = 2
Private Const adLockOptimistic As Long = 3
'下移单击事件
Private Sub btnDown_Click()
 On Error GoTo ErrorHandler
    Dim rst As Object
    Dim varDown As Variant
    Dim varUp As Variant

    Set rst = CreateObject("ADODB.Recordset") 'ADO的方式打开记录集
    rst.Source = "select * from tblProduct where sort>=" & Me.ListUpDown.Column(1) & " ORDER BY sort "

    rst.Open , CurrentProject.Connection, adOpenKeyset, adLockOptimistic
    varUp = rst![Sort]
    rst.MoveNext
    If Not rst.EOF Then
        varDown = rst![Sort]
        rst![Sort] = varUp
        rst.MovePrevious
        rst![Sort] = varDown
        rst.Update
    End If
    rst.Close

Done:
    Set rst = Nothing
    Me.ListUpDown.Requery
    Exit Sub

ErrorHandler:
    MsgBox "#" & Err & " " & Err.Description, vbCritical, "出错"
    Resume Done
End Sub
'上移单击事件
Private Sub btnUP_Click()
 On Error GoTo ErrorHandler
    Dim rst As Object
    Dim varDown As Variant
    Dim varUp As Variant

    Set rst = CreateObject("ADODB.Recordset")
    rst.Source = "select * from tblProduct where sort<=" & Me.ListUpDown.Column(1) & " ORDER BY sort desc"
    rst.Open , CurrentProject.Connection, adOpenKeyset, adLockOptimistic
    varDown = rst![Sort]
    rst.MoveNext
    If Not rst.EOF Then
        varUp = rst![Sort]
        rst![Sort] = varDown
        rst.MovePrevious
        rst![Sort] = varUp
        rst.Update
    End If
    rst.Close


Done:
    Set rst = Nothing
    Me.ListUpDown.Requery
    Exit Sub

ErrorHandler:
    MsgBox "#" & Err & " " & Err.Description, vbCritical, "出错"
    Resume Done
End Sub

03、运行测试

最后一步就是我们经常要做的，测试运行了。

结尾我再来说一下原理，原理比较简单，就是对数的顺序号做了移动的操作，这样就实现在操作，具体的如下：

1、先将选中的顺序号赋给变量

2、记录集向下移

3、选中的上一条的顺序号记录赋给变量

4、当前记录的排序的值等于上一条记录的顺序号

5、记录集向上移

6、上一条记录的顺序号等于向上移数据的顺序号，这样就做到了上移