字典含有重复的key不覆盖_VBA学习笔记28:VBA字典2

学习资源：《Excel VBA从入门到进阶》第28集 by兰色幻想

本课学习字典的唯一值、求和和查找。

一、字典与唯一值

例：提取“产品名称“表的不重复产品名称放在D列”提取唯一“表中。

思路：

1. 把表格数据先装入数组（数组运行速度快）。
2. 字典的key是唯一的，把产品名称数组放入key，item没有值就直接为空。
3. 装入字典后，再读取字典到”提取唯一“表即可。

Sub 提取不重复的产品()
Dim d As New Dictionary
Dim arr, x

arr = Range("B3:B13")

For x = 1 To UBound(arr)
    d(arr(x, 1)) = ""
Next x
'这里不用add是为了避免key出现重复值导致运行出错。

Range("D3").Resize(d.Count) = Application.Transpose(d.Keys)

End Sub

运行结果

二、字典与求和

例：根据下表，计算各个商品的总销量，计算结果放入E3:F11。

思路：

1. 先把数据装入数组。
2. 装入字典，同样利用key唯一原则，把商品名称当做key，如遇到不重复值，就把不重复值的数值加到对应的item里。
3. 读取字典。

Sub 汇总()
Dim d As New Dictionary
Dim arr, x

arr = Range("B3:C11")

For x = 1 To UBound(arr)
    d(arr(x, 1)) = d(arr(x, 1)) + arr(x, 2)
    'key对应的item的值在原来的基础上加新的
Next x

Range("E3").Resize(d.Count) = Application.Transpose(d.Keys)
Range("F3").Resize(d.Count) = Application.Transpose(d.Items)

End Sub

运行结果

三、字典与查找

例：把三张班级学生名单装进字典，设计为无论使用学号能找到姓名，用姓名能找到学号。

共有三个班级，表格所在位置是sheet4-6，序号在A列，姓名在B列。

“查找”sheet的界面

思路：

1. 利用循环，先把数据装入数组。
2. 把数组装入字典，因为无论输入姓名还是学号，都能查找到对应的值，那就把姓名和学号都作为key：当装入的key是姓名时，item就装入学号；当装入的key是学号时，item就装入姓名。
3. 按输入值C2，读取字典，输入对应的item值。

Sub 多表双向查找()
Dim d As New Dictionary
Dim x, y, a, b
Dim arr

For x = 4 To 6
    
b = Sheets(2).Name
a = Sheets(x).Range("a65536").End(xlUp).Row - 1
    arr = Sheets(x).Range("a2").Resize(Sheets(x).Range("a65536").End(xlUp).Row - 1, 2)

    For y = 1 To UBound(arr)
        d(arr(y, 1)) = arr(y, 2)
        d(arr(y, 2)) = arr(y, 1)
    Next y
    '以姓名和学号都作为key放入字典。
Next x

If Sheets("查找").Range("C2") <> "" Then Sheets("查找").Range("C3") = d(Sheets("查找").Range("C2").Value)

End Sub

输入“云梦泽”，查找结果是A1，正确

输入A1，查找结果是“云梦泽”，正确

字典d的item

注意：这个例子有个bug，就是重名的话，按姓名查找学号可能会有误，因为key值是唯一的，如果有重复值会覆盖原来item的值。