VB API 之 第十一课 绘制矩形

先来介绍几个画矩形的函数：

DrawFocusRect()：画一个焦点矩形；
Rectangle()：用当前选定的画笔描绘矩形，并用当前选定的画刷填充；
DrawEdge()：用指定的样式描绘一个矩形的边框；
RoundRect()：用当前选定的画笔画一个圆角矩形，并用当前选定的画刷填充。

今天用的是DrawFocusRect()函数，函数原型如下

Private Declare Function DrawFocusRect Lib "user32" Alias "DrawFocusRect"
(
ByVal hDC As Long,
lpRect As RECT
) As Long

hDc: Long   //设备的句柄

lpRect: RECT结构，绘制矩形的坐标。

返回值为0，表示失败，不为0，则成功

示例：绘制矩形

Option Explicit
Private Type RECT
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type
'类型声明
Private Declare Function DrawFocusRect Lib "user32" (ByVal hdc As Long, lpRect As RECT) As Long
Dim Flag As Boolean
Dim Start As Boolean
Dim Pos As RECT
Dim tempPos As RECT
Private Sub Command1_Click()
Flag = True
'开始绘图
End Sub
Private Sub Command2_Click()
Flag = False
Picture1.Cls
'结束绘图
End Sub
Private Sub Form_Load()
Flag = False
Start = False
'禁止绘图
Me.ScaleMode = 3
Me.Picture1.ScaleMode = 3
'设置对象坐标的度量单位为像素
End Sub
Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
If Flag Then
Start = True
Pos.Left = X
Pos.Top = Y
Else
Start = False
End If
End Sub
Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
If Start Then
DrawFocusRect Me.Picture1.hdc, Pos
'擦除原有焦点矩形
Pos.Right = X
Pos.Bottom = Y
DrawFocusRect Me.Picture1.hdc, Pos
'绘制新的焦点矩形
End If
End Sub
Private Sub Picture1_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
If Start Then
DrawFocusRect Me.Picture1.hdc, Pos
'擦除原有焦点矩形
Pos.Right = X
Pos.Bottom = Y
DrawFocusRect Me.Picture1.hdc, Pos
'绘制新的焦点矩形
Start = False
End If
End Sub

 

转载于:https://www.cnblogs.com/delphi2014/p/4035271.html