拯救世界_vijos1225_带权中位数

描述

话说在3085年，外星人打算来入侵地球，这个消息被我VIJOS国的情报部门秘密截获，于是便打算联系世界各个国家，一起研究商量对策。
由于每个国家所需派的技术员人数不同，所以目前无法决定到底要在哪个国家设置个研究所进行研究，幸运的是所有国家都在一条直线上，现在知道每个国家与我国的距离和该国的研究员人数。请你为他们决定一下到底在那个国家建立研究所可以使所有研究员集中到该国的费用最小。
格式

输入格式

输入文件每一行描述一个国家的信息。
首先是该国派出的技术员人数，紧跟着的是这个城市相对于我国的距离，最后是国家的名称。

输出格式

输出文件只需要一行，即研究所设定的国家名称。

样例1

样例输入1

7 9289 JAPAN
5 8523 AMERICA
3 5184 CHINA
8 2213 VIJOS
10 0 DDS

样例输出1

VIJOS

限制

1s内出解

提示

对于30%的数据，国家数不大于100。
对于60%的数据，国家数不大于500。
对于全部的数据，国家数不大于5000。

翔法

这是一题一维的带权中位数，求距离每个国家最近的国家，模板不说了

代码/pas

type
  rec=record
    x,w:extended;
    y:string;
  end;
var
  t:array[1..5000]of rec;
  n:longint;
  sum:extended;
procedure qsort(l,r:longint);
var
  i,j:longint;
  key:extended;
  tmp:rec;
begin
  if l>=r then exit;
  i:=l;
  j:=r;
  key:=t[l+random(r-l+1)].x;
  repeat
    while  (t[i].x<key) do inc(i);
    while  (t[j].x>key) do dec(j);
    if i<=j then
    begin
      tmp:=t[i];
      t[i]:=t[j];
      t[j]:=tmp;
      inc(i);
      dec(j);
    end;
  until i>j;
  qsort(l,j);
  qsort(i,r);
end;
function work:string;
var
  i,f:longint;
  p:extended;
  g:string;
begin
  p:=0;
  for i:=1 to n do
  begin
    p:=p+t[i].w;
    if p>sum/2 then
    begin
      f:=i;
      break;
    end;
  end;
  g:=t[f].y;
  exit(g);
end;
procedure main;
var
  ans:string;
begin
  qsort(1,n);
  ans:=work;
  writeln(ans);
end;
procedure init;
var
  s:char;
begin
  n:=0;
  while not seekeof do
  begin
    inc(n);
    readln(t[n].w,t[n].x,s,t[n].y);
    sum:=sum+t[n].w;
  end;
end;
begin
  init;
  main;
end.

转载于:https://www.cnblogs.com/olahiuj/p/5781279.html