在不同版本的 SQL Server 之间传输登录和密码的完整解决方案

在不同版本的 SQL Server 之间传输登录和密码的完整解决方案
在不同版本的 SQL Server 之间传输登录和密码的完整解决方案
此方法适用于以下情况：
从 SQL Server 7.0 向 SQL Server 7.0 传输登录和密码。
从 SQL Server 7.0 向 SQL Server 2000 传输登录和密码。
从 SQL Server 7.0 向 SQL Server 2005 传输登录和密码。
在运行 SQL Server 2000 的服务器之间传输登录和密码。
从 SQL Server 2000 向 SQL Server 2005 传输登录和密码。
 
注意：请查看本文末尾的备注，以了解有关下列步骤的重要信息。

要在不同版本的 SQL Server 之间传输登录和密码，请按下列步骤操作：1. 在源 SQL Server 上运行以下脚本。此脚本可在 master 数据库中创建名为 sp_hexadecimal 和 sp_help_revlogin 的两个存储过程。请在完成过程的创建之后继续执行第 2 步。

注意：下面的过程取决于 SQL Server 系统表。这些表的结构在 SQL Server 的不同版本之间可能会有变化，请不要直接从系统表中选择。
----- Begin Script, Create sp_help_revlogin procedure -----

USE master
GO
IF OBJECT_ID ('sp_hexadecimal') IS NOT NULL
Drop PROCEDURE sp_hexadecimal
GO
Create PROCEDURE sp_hexadecimal
@binvalue varbinary(256),
@hexvalue varchar(256) OUTPUT
AS
DECLARE @charvalue varchar(256)
DECLARE @i int
DECLARE @length int
DECLARE @hexstring char(16)
Select @charvalue = '0x'
Select @i = 1
Select @length = DATALENGTH (@binvalue)
Select @hexstring = '0123456789ABCDEF'
WHILE (@i <= @length)
BEGIN
DECLARE @tempint int
DECLARE @firstint int
DECLARE @secondint int
Select @tempint = CONVERT(int, SUBSTRING(@binvalue,@i,1))
Select @firstint = FLOOR(@tempint/16)
Select @secondint = @tempint - (@firstint*16)
Select @charvalue = @charvalue +
SUBSTRING(@hexstring, @firstint+1, 1) +
SUBSTRING(@hexstring, @secondint+1, 1)
Select @i = @i + 1
END
Select @hexvalue = @charvalue
GO

IF OBJECT_ID ('sp_help_revlogin') IS NOT NULL
Drop PROCEDURE sp_help_revlogin
GO
Create PROCEDURE sp_help_revlogin @login_name sysname = NULL AS
DECLARE @name sysname
DECLARE @xstatus int
DECLARE @binpwd varbinary (256)
DECLARE @txtpwd sysname
DECLARE @tmpstr varchar (256)
DECLARE @SID_varbinary varbinary(85)
DECLARE @SID_string varchar(256)

IF (@login_name IS NULL)
DECLARE login_curs CURSOR FOR
Select sid, name, xstatus, password FROM master..sysxlogins
Where srvid IS NULL AND name <> 'sa'
ELSE
DECLARE login_curs CURSOR FOR
Select sid, name, xstatus, password FROM master..sysxlogins
Where srvid IS NULL AND name = @login_name
OPEN login_curs
FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @xstatus, @binpwd
IF (@@fetch_status = -1)
BEGIN
PRINT 'No login(s) found.'
CLOSE login_curs
DEALLOCATE login_curs
RETURN -1
END
SET @tmpstr = '/* sp_help_revlogin script '
PRINT @tmpstr
SET @tmpstr = '** Generated '
+ CONVERT (varchar, GETDATE()) + ' on ' + @@SERVERNAME + ' */'
PRINT @tmpstr
PRINT ''
PRINT 'DECLARE @pwd sysname'
WHILE (@@fetch_status <> -1)
BEGIN
IF (@@fetch_status <> -2)
BEGIN
PRINT ''
SET @tmpstr = '-- Login: ' + @name
PRINT @tmpstr
IF (@xstatus & 4) = 4
BEGIN -- NT authenticated account/group
IF (@xstatus & 1) = 1
BEGIN -- NT login is denied access
SET @tmpstr = 'EXEC master..sp_denylogin ''' + @name + ''''
PRINT @tmpstr
END
ELSE BEGIN -- NT login has access
SET @tmpstr = 'EXEC master..sp_grantlogin ''' + @name + ''''
PRINT @tmpstr
END
END
ELSE BEGIN -- SQL Server authentication
IF (@binpwd IS NOT NULL)
BEGIN -- Non-null password
EXEC sp_hexadecimal @binpwd, @txtpwd OUT
IF (@xstatus & 2048) = 2048
SET @tmpstr = 'SET @pwd = CONVERT (varchar(256), ' + @txtpwd + ')'
ELSE
SET @tmpstr = 'SET @pwd = CONVERT (varbinary(256), ' + @txtpwd + ')'
PRINT @tmpstr
EXEC sp_hexadecimal @SID_varbinary,@SID_string OUT
SET @tmpstr = 'EXEC master..sp_addlogin ''' + @name
+ ''', @pwd, @sid = ' + @SID_string + ', @encryptopt = '
END
ELSE BEGIN
-- Null password
EXEC sp_hexadecimal @SID_varbinary,@SID_string OUT
SET @tmpstr = 'EXEC master..sp_addlogin ''' + @name
+ ''', NULL, @sid = ' + @SID_string + ', @encryptopt = '
END
IF (@xstatus & 2048) = 2048
-- login upgraded from 6.5
SET @tmpstr = @tmpstr + '''skip_encryption_old'''
ELSE
SET @tmpstr = @tmpstr + '''skip_encryption'''
PRINT @tmpstr
END
END
FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @xstatus, @binpwd
END
CLOSE login_curs
DEALLOCATE login_curs
RETURN 0
GO
----- End Script -----
2. 在创建 sp_help_revlogin 存储过程后，请从源服务器上的查询分析器中运行 sp_help_revlogin 过程。sp_help_revlogin 存储过程可同时用于 SQL Server 7.0 和 SQL Server 2000。sp_help_revlogin 存储过程的输出是登录脚本，该脚本可创建带有原始 SID 和密码的登录。保存输出，然后将其粘贴到目标 SQL Server 上的查询分析器中，并运行它。例如：
EXEC master..sp_help_revlogin

备注
? 在目标 SQL Server 上运行输出脚本之前，请认真查看此脚本。如果必须将登录传输到与 SQL Server 源实例不在同一个域中的 SQL Server 实例，请编辑由 sp_help_revlogin 过程生成的脚本，并在 sp_grantlogin 语句中将域名替换为新的域名。由于在新域中被授予访问权的集成登录与原始域中的登录具有不同的 SID，因此数据库用户将从这些登录中孤立出去。要解决这些孤立用户，请查看以下项目符号项中引用的文章。如果在同一个域中的 SQL Server 实例之间传输集成登录，则会使用相同的 SID，而且用户不太可能被孤立。
? 在移动登录之后，用户将不再具有访问已被同时移动的数据库的权限。此问题称为“孤立用户”。如果尝试将访问此数据库的权限授予该登录，则可能会失败，这表明该用户已存在：
Microsoft SQL-DMO (ODBC SQLState:42000) Error 15023:User or role '%s' already exists in the current database.

? 能够这样做的原因在于：sp_addlogin 系统存储过程中的 @encryptopt 参数允许通过使用加密密码来创建登录。有关此过程的更多信息，请参见 SQL Server 联机丛书中的“sp_addlogin (T-SQL)”主题。
? 默认情况下，只有 sysadminfixed 服务器角色的成员可以从 sysxlogins 表中进行选择。除非 sysadmin 角色的成员授予了必要的权限，否则最终用户将无法创建或运行这些存储过程。
? 此方法不会尝试传输特定登录的默认数据库信息，因为默认数据库并不始终存在于目标服务器中。要为某个登录定义默认数据库，您可以使用 sp_defaultdb 系统存储过程，方法是将登录名和默认数据库作为参数传递给该过程。有关使用此过程的更多信息，请参见 SQL Server 联机丛书中的“sp_defaultdb”主题。
? 在 SQL Server 实例之间传输登录的过程中，如果源服务器的排序顺序不区分大小写，而目标服务器的排序顺序区分大小写，则在将登录传输到目标服务器后，必须以大写形式输入密码中的所有字母字符。如果源服务器的排序顺序区分大小写，而目标服务器的排序顺序不区分大小写，则无法通过本文所述的步骤使用已传输的登录进行登录，除非原始密码不包括字母字符或原始密码中的所有字母字符都是大写字符。如果两个服务器都区分大小写或者都不区分大小写，则不会出现此问题。这是 SQL Server 处理密码的方式所带来的副作用。有关更多信息，请参见 SQL Server 7.0 联机丛书中的“Effect on Passwords of Changing Sort orders”（更改排序顺序对密码的影响）主题。
? 在目标服务器上运行“sp_help_revlogin”脚本的输出时，如果该目标服务器已经定义了一个登录，且该登录名与脚本输出中的某个登录名相同，则在执行“sp_help_revlogin”脚本的输出时，可能会看到下面的错误：
Server:Msg 15025, Level 16, State 1, Procedure sp_addlogin, Line 56
The login 'test1' already exists.
同样，如果此服务器上存在其他登录，且其 SID 值与您要尝试添加的登录的 SID 值相同，则会收到以下错误消息：
Server:Msg 15433, Level 16, State 1, Procedure sp_addlogin, Line 93
Supplied parameter @sid is in use.
因此，您必须仔细复查这些命令的输出，检查 sysxlogins 表的内容，并相应地解决这些错误。
? 特定登录的 SID 值用作在 SQL Server 中实现数据库级别访问的基础。因此，如果同一登录在该数据库级别（在该服务器上的两个不同数据库中）有两个不同的 SID 值，则此登录将仅能访问其 SID 与该登录的 syslogins 中的值相匹配的数据库。如果所讨论的两个数据库已从两个不同的服务器合并在一起，则可能出现这种情形。要解决此问题，必须使用 sp_dropuser 存储过程从具有不匹配 SID 的数据库中手动删除所讨论的登录，然后再使用 sp_adduser 存储过程添加它。

转载于:https://www.cnblogs.com/sanle/archive/2009/04/20/1439926.html