android studio 动画引擎,将开源渲染引擎bgfx移植出Android版本

起因

之前看云风的博客说他们正在弄一个游戏引擎，用的就是bgfx库作为渲染库，结果这么久了游戏引擎还没开源出来，所以我就先弄弄bgfx。

GitHub有一个像是用bgfx的Android版本，项目地址是：https://github.com/Nodrev/bgfx-android-activity。打开看了一眼代码，发现这简直就是一个坑，哪里有半分bgfx代码的影子。所以就自己捣鼓了一个。

捣鼓的过程中遇到很多问题，比如CMake用着不熟，Android Studio用着不熟等等，逐步解决问题的过程就是一个积累成长的过程(没错，之前的文章也都是为了这次的移植所总结的)。

准备工作

首先要从github中clone三个项目，分别是bx、bimg、bgfx将这三个项目放到同一个目录下，这样，引用起来会比较方便。

然后，从google-samples里拷贝一份native-activity项目出来，将它放到前三个项目的同级目录下。完成之后，笔者的目录结构就是这个样子：

bgfx-ancroid-activity是github上别人移植bgfx的项目，就是笔者之前说的坑！

移植思路

从上面的项目选择就能看出，笔者采用的是NativeActivity的方式来显示界面。这样，项目中就不须要一行Java代码就能显示出想要的东西。

这一点，native-activity项目本身的配置就足以满足需要，如图:

需要编译成库的东西

用vs打开bgfx的解决方案，从工程列表中大致可以看出需要将哪些代码编译成库:

bgfx本身需要两个基础工程，分别是bimg和bx，这两个工程笔者之前已经下载完了。从工程目录来看，bx只需要编译成一个库，就是bx。bimg则需要编译成两个库，一个是bimg，另一个是bimg-decode。在添加编译命令的时候，笔者就把它分成了两个库来编译。然后，bgfx需要一个库，这点是毫无疑问的。这些是引擎的部分。

还有example的公共模块库，就是上图中的example-common。example-common工程中有3个库，分别是dear-imgui，ib-compress和其本身。

所以，需要编译的库大致有:

bx

bimg

bimg-decode

bgfx

dear-imgui

ib-compress

example-common

添加CMakeLists文件

因为笔者用的Android Studio版本是3.0.1，而且笔者也不熟悉原有的ndk-build编译方式，所以笔者选择了使用CMake作为编译器，在项目中添加CMakeLists文件来编译所有的库。主模块只有一个CMakeLists文件，位于src/main/cpp目录下面，该文件的完整内容是：

# 指定编译所需的CMake最低版本

cmake_minimum_required(VERSION 3.4.1)

# 设置c++编译器的编译选项：使用gnu++11库，打开警告开关，将所有警告当成错误处理

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=gnu++11 -Wall -Werror")

# 添加bx库

set(bx_dir ../../../../../bx)

add_subdirectory(${bx_dir} bx)

# 添加bimg库

set(bimg_dir ../../../../../bimg)

add_subdirectory(${bimg_dir} bimg)

# 添加bimg-decode库

set(bimg-decode_dir ../../../../../bimg/src)

add_subdirectory(${bimg-decode_dir} bimg-decode)

# 添加dear-imgui库

set(dear-imgui_dir ../../../../../bgfx/3rdparty/dear-imgui)

add_subdirectory(${dear-imgui_dir} dear-imgui)

# 添加ib-compress库

set(ib-compress_dir ../../../../../bgfx/3rdparty/ib-compress)

add_subdirectory(${ib-compress_dir} ib-compress)

# 添加bgfx库

set(bgfx_dir ../../../../../bgfx)

add_subdirectory(${bgfx_dir} bgfx)

# 添加examples-common库

set(examples-common_dir ../../../../../bgfx/examples/common)

add_subdirectory(${examples-common_dir} examples-common)

set(CMAKE_SHARED_LINKER_FLAGS

"${CMAKE_SHARED_LINKER_FLAGS} -u ANativeActivity_onCreate")

# 编译成共享库

add_library(native-activity SHARED main.cpp)

# 设置目标库的包含目录

target_include_directories(native-activity PRIVATE

${ANDROID_NDK}/sources/android/native_app_glue

${bx_dir}/include

${bimg_dir}/include

${bgfx_dir}/include

${bgfx_dir}/3rdparty

${examples-common_dir})

# 设置目标库的链接库

target_link_libraries(native-activity

bgfx

examples-common

dear-imgui)

看上去很长，关键点并不多，我们一个个来看。

首先是set和add_subdirectory：

set(bx_dir ../../../../../bx) # 这一行是设置bx_dir变量，将其设置为../../../../../bx

add_subdirectory(${bx_dir} bx) # 这是添加子目录的命令，CMake会从指定的目录中读取CMakeLists.txt文件，并且编译，生成指定的库(bx)。${bx_dir}就是引用上面设置的变量

然后是add_library：

add_library(native-activity SHARED main.cpp) # 将main.cpp编译成共享库，共享库的名字是native-activity

接着是target_include_directories：

target_include_directories(native-activity PRIVATE

${ANDROID_NDK}/sources/android/native_app_glue

${bx_dir}/include

${bimg_dir}/include

${bgfx_dir}/include

${bgfx_dir}/3rdparty

${examples-common_dir}) # 设置native-activity库的包含目录，PRIVATE的意思是这些包含目录只对native-activity起作用，这里我们设置了很多目录

最后是target_link_libraries：

target_link_libraries(native-activity

bgfx

examples-common

dear-imgui) # 添加native-activity的链接库，只有三个：bgfx、examples-common、dear-imgui

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=gnu++11 -Wall -fno-exceptions -fno-rtti")

add_library (examples-common STATIC

debugdraw/debugdraw.cpp

entry/cmd.cpp

entry/entry.cpp

entry/entry_android.cpp

entry/entry_asmjs.cpp

entry/entry_glfw.cpp

entry/entry_noop.cpp

entry/entry_sdl.cpp

entry/entry_windows.cpp

entry/entry_x11.cpp

entry/input.cpp

font/font_manager.cpp

font/text_buffer_manager.cpp

font/text_metrics.cpp

font/utf8.cpp

imgui/imgui.cpp

imgui/scintilla.cpp

nanovg/nanovg.cpp

nanovg/nanovg_bgfx.cpp

ps/particle_system.cpp

bgfx_utils.cpp

bounds.cpp

camera.cpp

cube_atlas.cpp

example-glue.cpp)

target_include_directories (examples-common PRIVATE

${ANDROID_NDK}/sources/android/native_app_glue

../../../bx/include

../../../bimg/include

../../include

../../3rdparty)

target_link_libraries (examples-common

bx

bimg

bimg-decode

ib-compress

bgfx

android

log

EGL

GLESv2) # 这里注意，一定要加上android、log、EGL、GLESv2，这些库都是必要的

和原有的native-activity项目不同，examples-common库才是和Android系统对接的库，所以像android、EGL这些库都需要链接到examples-common上才行。原本native_app_glue库就不需要了，因为android_native_app_glue.c文件已经被包含到entry/entry_android.cpp文件中。

严重吐槽bgfx这种include源文件的方式，增加很多找依赖文件的时间！

添加实现代码

这一步操作非常简单，先把bgfx/examples/00-helloworld中的logo.h文件放到native-activity项目中去，放到src/main/cpp/目录下面，和main.cpp同级。然后，将helloworld.cpp中的代码复制到main.cpp文件中，全部复制过去，将main.cpp原有的代码全部删除。

编译运行，不出意外的话，就能在模拟器上得到这样的结果：

运行效果

有问题的话也不要紧，到笔者的GitHub上把上面提到的那些东西clone下来，用Android Studio打开native-activity项目就可以编译运行了。

剩下的坑

没错，还有坑没有解决，那就是点击界面上的Exit按钮会崩溃，吼吼，不打算去改了，水平有限。

参考资料

程序员的自我修养-链接、装载与库：让你知道隐藏在IDE之后的过程