Maven工程自动打包脚本

为什么80%的码农都做不了架构师？>>>   

@echo off
title  Automatic Packaging Application
echo ==-Build this application start-================================
:: 设置一个共享地址的拷贝目录,需要映射成磁盘
set OTHERDESKTOP=Z:\Kxvz\PRO-PKG
:: 设置本地的存储目录
set DESKTOP=D:\PRO-PKG
:: 设置代码的根路径
set SOURCE=D:\Program Files\CODE\PRO\branches\dev-branch
:: 设置SVN工具目录
set SVN=G:\Program Files\TortoiseSVN\bin

:: 获取当前时间,2017-08-10
set d=%date:~0,10%

:: 删除已存在的日期文件目录并重建
rd /s /q "%DESKTOP%\%d%"
mkdir "%DESKTOP%\%d%"

rd /s /q "%OTHERDESKTOP%\%d%"
mkdir "%OTHERDESKTOP%\%d%"

:: 进入源码盘并进入目录
D:
cd "%SOURCE%\PRO-BUILD"

:: 执行SVN的更新
"%SVN%\TortoiseProc.exe" /command:update /path:"%SOURCE%" /closeonend:2

for /f "tokens=2" %%i in ('svn info ^| find "Revision"') do (
  set SvnVersion=%%i
)

:: 打包
call mvn clean install -U -Dmaven.test.skip=true

:: 复制已经打包好的工程和相关文件到指定的文件夹
copy "%SOURCE%\PRO\target\PRO-EAR-1.0.ear" "%DESKTOP%\%d%\PRO-SVN%SvnVersion%.ear" /y
copy "%SOURCE%\SystemLibrary\docs\db.table.sql" "%DESKTOP%\%d%\table.sql" /y
copy "%SOURCE%\SystemLibrary\docs\db.initdata.sql" "%DESKTOP%\%d%\initdata.sql" /y
copy "%SOURCE%\SystemLibrary\docs\db.update.sql" "%DESKTOP%\%d%\update.sql" /y
copy "%SOURCE%\SystemLibrary\docs\update.txt" "%DESKTOP%\%d%\desc.txt" /y

echo ==-Copy the file to Remote Files-==================================

copy "%DESKTOP%\%d%\PRO-SVN%SvnVersion%.ear" "%OTHERDESKTOP%\%d%\PRO-SVN%SvnVersion%.ear" /y
copy "%DESKTOP%\%d%\table.sql" "%OTHERDESKTOP%\%d%\table.sql" /y
copy "%DESKTOP%\%d%\initdata.sql" "%OTHERDESKTOP%\%d%\initdata.sql" /y
copy "%DESKTOP%\%d%\update.sql" "%OTHERDESKTOP%\%d%\update.sql" /y
copy "%DESKTOP%\%d%\desc.txt" "%OTHERDESKTOP%\%d%\desc.txt" /y


echo ==-Build this application end-==================================

echo ==-File Directory-==================================
echo All files into  "%DESKTOP%\%d%"
echo ==-File Directory-==================================
pause

 

转载于:https://my.oschina.net/Kxvz/blog/1505586