用groovy写H2数据库的存储过程

2019独角兽企业重金招聘Python工程师标准>>>

以前看H2的roadmap，里边有这样一条“Groovy Stored Procedures: http://groovy.codehaus.org/GSQL”，就一直期盼着哪一天能够用上groovy写存储过程。如果能够这样，用groovy.sql.Sql写数据库操作，语法简易（eachRow、Rows、execute），不会泄露resultset、statment资源，直接支持SQL占位符（“拼sql”永别了），把易变的代码放到数据库中，以便管理。H2加上jetty加上groovy，单个JVM完成数据库、WEB服务器、应用服务器的所有功能，安装发布维护会幸福许多（当然是对于超微型系统而言）。

这一等就溜溜的等了近三年。

近期读H2的源代码，写了一个补丁，修改了org.h2.util.SourceCompiler的实现，不超过50行代码，已经支持groovy存储过程了，并且完美兼容原来的java代码写存储过程。

实现原理：

1. 声明全局的GroovyCompiler提供groovy编译功能（这里未考虑多个数据库分别采用不同的编译器，可能存在多H2在同一JVM中相互影响问题）
2. 修改org.h2.util.SourceCompiler.getClass(String)方法，判断如果为groovy代码（代码以//groovy或@groovy开始）则调用GroovyCompiler编译
3. Method的选择：编译出的类中的静态public方法（不以“_”开始、不是“main”，这些是groovy自动编译出的方法）
   
4. 其它以考虑问题：GroovyCompiler为单独的类，这样即使classpath中没有groovy的jar也不会造成SourceCompiler不可用；classloader自动import"java.sql.Connection、java.sql.Types、java.sql.ResultSet、groovy.sql.Sql、org.h2.tools.SimpleResultSet"，加上groovy自动加载的java.util、java.math、java.lang，足够一般代码用了。

闲言少叙，上代码样例：

简单样例：
     在这里使用了@groovy.transform.CompileStatic注解，使用静态编译，对于简单的代码有助于提高性能。

CREATE ALIAS tr AS $$@groovy.transform.CompileStatic 
 static String tr(String str, String sourceSet, String replacementSet)  { 
 return str.tr(sourceSet, replacementSet); 
 } 
$$

调用：

call tr('hello', 'a-z', 'A-Z')='HELLO';
--结果
public.tr('hello', 'a-z', 'a-z') = 'hello'  
TRUE
(1 行, 2 ms)

复杂样例：

    演示以表返回一些系统信息；（注：H2文档中已明确写明，如果函数第一个参数为Connection，则在调用时自动传入数据库连接）

create alias sysinfo as $$//groovy
	import java.lang.management.ManagementFactory
	static ResultSet sysinfo(Connection conn, String pat){
		SimpleResultSet rs = new SimpleResultSet()
		rs.addColumn('type', Types.VARCHAR, 255, 0)
		rs.addColumn('key', Types.VARCHAR, 255, 0)
		rs.addColumn('value', Types.VARCHAR, 255, 0)
		switch (pat){
			case 'h2': _h2(rs, conn); break;
			case 'groovy': _groovy(rs); break;
			case 'jvm': _jvm(rs); break;
			default: _h2(rs, conn); _groovy(rs); _jvm(rs);
		}
		rs
	}
	static void _h2(SimpleResultSet rs, Connection conn){
		rs.addRow('h2', 'BUILD_DATE', org.h2.engine.Constants.BUILD_DATE)
		rs.addRow('h2', 'BUILD_ID', org.h2.engine.Constants.BUILD_ID.toString())
		//sample of db process
		def sql = new Sql(conn)
		sql.eachRow('SELECT TABLE_TYPE, count(1) AS ct FROM INFORMATION_SCHEMA.TABLES GROUP BY TABLE_TYPE'){
			rs.addRow('h2', it['TABLE_TYPE'], it['CT'].toString())
		}
	}

	static void _groovy(SimpleResultSet rs){
		rs.addRow('groovy', 'version', groovy.lang.GroovySystem.getVersion())
	}
	static void _jvm(SimpleResultSet rs){
		def defs = [ ['os', ManagementFactory.operatingSystemMXBean, ['arch', 'name', 'version', 'availableProcessors']],
			['runtime', ManagementFactory.runtimeMXBean, ['name', 'specName', 'specVendor', 'specVersion', 'managementSpecVersion']],
			['classloading', ManagementFactory.classLoadingMXBean, ['loadedClassCount', 'totalLoadedClassCount', 'unloadedClassCount']],
			['compilation', ManagementFactory.compilationMXBean, ['totalCompilationTime']],
			['heap', ManagementFactory.memoryMXBean.heapMemoryUsage, ['committed', 'init', 'max', 'used']],
			['noneheap', ManagementFactory.memoryMXBean.nonHeapMemoryUsage, ['committed', 'init', 'max', 'used']],
		]
		for (ad in defs){
			def mx=ad[1]
			for (fe in ad[2]){
				rs.addRow(ad[0], fe, mx[fe].toString())
			}
		}
	}
$$;

转载于:https://my.oschina.net/wonder365/blog/109612