王爽《汇编语言》实验12

2019独角兽企业重金招聘Python工程师标准>>>

编写0号中断的处理程序，使得在除法溢出发生时，在屏幕中中间显示字符串"divide error!"，然后返回到DOS。

分析：在编写本程序时首先要了解到，当发生除法溢出时，产生0号中断信息，CPU到底做了什么：
1）、取得中断类型码0；
2）、标志寄存器入栈，TF、IF设置为0（防止单步执行）；
3）、CS、IP入栈
4）、(IP)=(0*4)，(CS)=(0*4+2)即由0号中断信息在中断向量表中得到0号中断的处理程序地址，并
        设置对应的IP和CS，实现跳转执行中断处理程序。
那我们应该做什么呢？根据CPU的中断处理过程，我们可知，要想使CPU执行我们编写的0号中断处理程序，就必须将中断向量表中指向0号中断处理程序的入口地址（在0000:0000~0000:0003处，高位存CS，低位存IP），改写成我们编写的程序的入口地址；由于入口地址改写后是不变的，因此我们也要将我们的中断处理程序写在一个恒定的内存单元中，使其不被覆盖，在这里我们选取内存单元的0000:0200~0000:02FF处。
综上所述：编写自定义的0号中断处理程序就是要将我们的程序数据复制到0000:0200~0000:02FF处的内存单元中，并改写0号中断向量项中的入口地址，使其指向0000:0200处.

参考代码：

assume cs:codesg

codesg segment
begin: mov ax,cs
       mov ds,ax
       mov si,offset do0            ; 存放源程序数据地址

       mov ax,0
       mov es,ax
       mov di,200H                  ; 用于存放中断程序的内存单元地址

       mov cx, offset end_do0 - offset do0   ; 得到自定义中断程序do0所占字单位
       cld
       rep movsb                    ; 安装中断程序

       mov word ptr es:[0],200H     ; 设置0号中断项的IP偏移地址
       mov word ptr es:[2],0        ; 设置0号中断项的CS段地址

       mov ax,4c00h
       int 21h
  do0: jmp short s
       db 'divide error!',0
    s: mov ax,0B800H
       mov es,ax
       mov di,12*160+33*2            ; 即从屏幕的12行，33列处显示提示字符

       mov ax,0
       mov ds,ax
       mov si,202H                   ; 待显示字符地址

 show: mov cl,[si]
       mov ch,0
       jcxz ok
       mov es:[di],cl
       mov byte ptr es:[di+1],2      ; 设置字体颜色为绿色
       add di,2
       inc si
       jmp short show
   ok: mov ax,4c00h
       int 21h

end_do0: nop
 codesg ends
 end begin

先在DOS中执行本程序，然后查看内存单元中的内存如下：

然后执行一个除法溢出操作，触发0号中断：

转载于:https://my.oschina.net/websoft/blog/78105