iOS之身份证识别-CSDN博客

这段时间项目的需求，需要在注册的时候进行身份证识别。就简单的搞了一下。

身份证识别

项目的需求是通过摄像头的采集获取到身份证上面的一些数据，比如身份证号码、姓名等信息。而不是简单的知晓身份证号码后来一波正则判断。

实现方案

首先通过手机摄像头获取到手机的身份证的图片，务必要背景简单，色调单一，主要是在后面处理图像的时候对识别率的提升有帮助。
通过openCV对原始图片处理，把图片变成灰度图->二值化->腐蚀、膨胀->轮廓检测->剪裁等处理，使得图片成为我们想要的样式。
然后裁剪出合适的区域，如只要身份证的号码的区域就只需要裁剪出身份证号码即可。
通过OCR对图片进行识别，让图片中显示的文字转换成文字。
识别好号码后，进行一波身份证号码识别的预处理，网上有很多的正则表达式，可以搜索下。我的代码中也会有体现的。
通过身份证号码就可以得知出生年月以及性别(18位身份证:第17位代表的是性别，奇数为男性，偶数为女性)

openCV相关

opencv的相关代码是用C++写的，所以在引用这个opencv的头文件的那个类，需要把.m文件修改为.mm文件。
相关的类引用了opencv，需要把引用的头文件放在最前面，建议使用pch来引用，可以避免造成不必要的麻烦。

下面弄个简单的代码演示下：

原始图片：女神新垣结衣
处理后的图片

opencv demo下载里面没有opencv的framework，另行[下载](链接: https://pan.baidu.com/s/1o8LjSgi) 密码: 7ubn。

OCR相关

利用谷歌的tesseractOCR和tessdata的库(其中有英文的库和中文的库)来识别处理完成后的图片。

注意：其中tessdata拖入到工程中需要拖入一个真实的文件夹(蓝色文件)，而不是一个在工程中虚拟的文件夹。 #引入的依赖库

处理图片

#pragma mark - 处理图片得到身份证号码图片
//扫描身份证图片，并进行预处理，定位号码区域图片并返回
- (UIImage *)opencvScanCardWithNumber:(UIImage *)image {
    //将UIImage转换成Mat
    cv::Mat resultImage;
    UIImageToMat(image, resultImage);
    //转为灰度图
    cvtColor(resultImage, resultImage, cv::COLOR_BGR2GRAY);
    //利用阈值二值化
    cv::threshold(resultImage, resultImage, 100, 255, CV_THRESH_BINARY);
    //腐蚀，填充（腐蚀是让黑色点变大）
    cv::Mat erodeElement = getStructuringElement(cv::MORPH_RECT, cv::Size(27,27));
    cv::erode(resultImage, resultImage, erodeElement);
    //轮廊检测
    std::vector<std::vector<cv::Point>> contours;//定义一个容器来存储所有检测到的轮廊
    cv::findContours(resultImage, contours, CV_RETR_TREE, CV_CHAIN_APPROX_SIMPLE, cvPoint(0, 0));
    //cv::drawContours(resultImage, contours, -1, cv::Scalar(255),4);
    //取出身份证号码区域
    std::vector<cv::Rect> rects;
    cv::Rect numberRect = cv::Rect(0,0,0,0);
    std::vector<std::vector<cv::Point>>::const_iterator itContours = contours.begin();
    for ( ; itContours != contours.end(); ++itContours) {
        cv::Rect rect = cv::boundingRect(*itContours);
        rects.push_back(rect);
        //算法原理
        if (rect.width > numberRect.width && rect.width > rect.height * 5) {
            numberRect = rect;
        }
    }
    //身份证号码定位失败
    if (numberRect.width == 0 || numberRect.height == 0) {
        return nil;
    }
    //定位成功成功，去原图截取身份证号码区域，并转换成灰度图、进行二值化处理
    cv::Mat matImage;
    UIImageToMat(image, matImage);
    resultImage = matImage(numberRect);
    cvtColor(resultImage, resultImage, cv::COLOR_BGR2GRAY);
    cv::threshold(resultImage, resultImage, 80, 255, CV_THRESH_BINARY);
    //将Mat转换成UIImage
    UIImage *numberImage = MatToUIImage(resultImage);
    return numberImage;
}
复制代码

识别已经处理过的图片

#pragma mark - 识别文字或者数字
//利用TesseractOCR识别文字
- (void)tesseractRecognizeImage:(UIImage *)image compleate:(CompleateBlock)compleate {
    dispatch_async(dispatch_get_global_queue(DISPATCH_QUEUE_PRIORITY_BACKGROUND, 0), ^{
        G8Tesseract *tesseract = [[G8Tesseract alloc] initWithLanguage:@"chi_sim"];
//        tesseract.image = [image g8_blackAndWhite];
        if (image == nil) {
            NSLog(@"图片没有处理成功");
            return;
        }
        tesseract.image = image;
        // Start the recognition
        BOOL done = [tesseract recognize];
        //执行回调
        compleate(tesseract.recognizedText);
    });
}
复制代码

获取摄像头的权限后，开启摄像头，在其代理中实现

- (void)imagePickerController:(UIImagePickerController *)picker didFinishPickingMediaWithInfo:(NSDictionary<NSString *,id> *)info;
复制代码

得到号码后，可以对性别进行判断

#pragma mark - 判断性别
- (NSString *)judgeGenderWithIdNumber:(NSString *)idNumber {
    NSInteger genderNumber = [[idNumber substringWithRange:NSMakeRange(16, 1)] integerValue];
    if (genderNumber % 2 == 0) {
        return [NSString stringWithFormat:@"性别:%@", @"女"];
    } else {
        return [NSString stringWithFormat:@"性别:%@", @"男"];
    }
}
复制代码

具体的代码

相关的[依赖文件]链接: https://pan.baidu.com/s/1gfkSXWn 密码: kan7。直接拖入到工程中就可以了(opencv、tesseractOCR以及tessdata)。