一个通用的Delphi数据导出到Excel函数

最新推荐文章于 2017-11-14 19:08:00 发布
最新推荐文章于 2017-11-14 19:08:00 发布
阅读量137 收藏
点赞数

一个通用的Delphi数据导出到Excel函数

(2008-05-09 21:10:07)
关键字：delphi 对Excel编程，TDataSet（Tquery，TTabe）导到Excel，如何设置Excel字体、文本对齐方式，如何设置单元格边框，如何合并单元格，如何Excel打印设置，如何设置单元格为文本格式
 
 
    主要功能：
       1.数据集导出到Excel函数
       2.自动设置列宽
       3.自动调节适应A4纸张
       4.具有打开Excel、打印预览、直接打印选项
 
 
unit ExcelReport;
interface
uses
  SysUtils, Variants, Controls, Forms, Dialogs, ComObj, ComCtrls, DB, excel2000,
  StdCtrls, Graphics, Windows, Grids;
{**************************************************************************************
    数据集导出到Excel函数，自动设置列宽，自动调节适应A4纸张
    Columns：可以是DataSet的Fields，ListView的Columns，StringGrid之一
    DataSet：数据集
    Caption：大标题，
    SubCaption：子标题，
    LeftCaption：左标题，
    CenterCaption：中标题
    RightCaption：右标题
    Flag：1:预览，2:直接打印，0：打开Excel编辑
    ColAutoSize：是否允许自动列宽
**************************************************************************************}
procedure DataSetToExcel(Columns: TObject; DataSet: TDataSet; Caption: String = '';
                         SubCaption: String = ''; LeftCaption: String = '';
                         CenterCaption: String = ''; RightCaption: String = '';
                         Flag: Integer = 1; ColAutoSize: Boolean = True);
implementation
procedure DataSetToExcel(Columns: TObject; DataSet: TDataSet; Caption: String = '';
                         SubCaption: String = ''; LeftCaption: String = '';
                         CenterCaption: String = ''; RightCaption: String = '';
                         Flag: Integer = 1; ColAutoSize: Boolean = True);
const
  MaxColWidth           = 80;
 
  RowCaption            = 1;
  RowUse                = 5;
  FontSizeCaption            = 15;
  FontSizeSubCaption         = 10;
  FontSizeLeftCaption        = 12;
  FontSizeCenterCaption      = 12;
  FontSizeRightCaption       = 12;
  FontSizeColumns            = 10;
  FontSizeData               = 10;
  FontNameCaption            = '楷体';
  FontNameSubCaption         = '宋体';
  FontNameLeftCaption        = '宋体';
  FontNameCenterCaption      = '宋体';
  FontNameRightCaption       = '宋体';
  FontNameColumns            = '宋体';
  FontNameData               = '宋体';
  TextAlignLeft         = 2;
  TextAlignCenter       = 3;
  TextAlignRight        = 4;
  TextAlignTop          = 1;
  TextAlignVCenter      = 2;
  TextAlignBottom       = 3;
 
var
  Excel, Sheet: Variant;
  RowIndex: Integer;
  ColSum: Integer;
  Form: TForm;
  lb: TLabel;
 
  function GetExcel(): Integer;
  begin
    Result := DataSet.RecordCount + RowUse;
    if (Result > 65536 ) then
    begin
       if (MessageDlg('    需要导出的数据过大，Excel最大只能容纳65536行，'+
                                       #13'将会截断超过部分，是否还要继续？',
                   mtConfirmation, [mbYes, mbNo], 0) = mrNo) then
       begin
         Result := 0;
         exit;
       end else
         Result := 65536;
    end;
    try
      Excel := CreateOleobject('Excel.Application');
    except
      ShowMessage(#13'    Excel没有正确安装！');
    end;
  end;
  function GetColumnsWidth(): Integer;
  var
    i: Integer;
  begin
    Result := 0;
    for i := 1 to ColSum do
      Result := Result + Sheet.Columns[i].ColumnWidth;
    Result := Excel.InchesToPoints((Result * 2.2862) / 25.4);
  end;
  procedure SetColumns( Columns: TListColumns); overload;
  var
    i: Integer;
    s: String;
  begin
    for i := 0 to (Columns.Count - 1) do
    begin
      s := Columns[i].Caption;
      Sheet.Columns[i + 1].ColumnWidth := Length(s);
      Sheet.Cells[RowIndex, i + 1].value := s;
    end;
  end;
  procedure SetColumns( Columns: TFields); overload;
  var
    i: Integer;
    s: String;
  begin
    for i := 0 to (Columns.Count - 1) do
    begin
      s := Columns[i].FieldName;
      Sheet.Columns[i + 1].ColumnWidth := Length(s);
      Sheet.Cells[RowIndex, i + 1].value := s;
    end;
  end;
  procedure SetColumns( Columns: TStringGrid); overload;
  var
    i: Integer;
    s: String;
  begin
    for i := 1 to (Columns.ColCount - 1) do
    begin
      s := Columns.Cells[i, 0];
      Sheet.Columns[i].ColumnWidth := Length(s);
      Sheet.Cells[RowIndex, i].value := s;
    end;
  end;
  procedure DoDataSetToExcel();
    function GetDateTimeStr(DT: TDateTime): String;
    var
      nDT: Integer;
    begin
      Result := TimeToStr(DT);
      nDT := Trunc(DT);
      if nDT < 1000 then
      begin
        if nDT - 2 >= 1 then
          Result := IntToStr(nDT - 2) + '天' + Result;
      end else
        Result := DateToStr(DT) + ' ' + Result; 
    end;
  var
    i, RowEnd, Len: Integer;
    s: String;
  begin
    RowEnd := DataSet.RecordCount + RowIndex - 1;
    if RowEnd > 65536 then
      RowEnd := 65536;
    DataSet.First();
    while not DataSet.Eof do
    begin
      for i := 0 to DataSet.Fields.Count - 1 do
      begin
        if DataSet.Fields[i].DataType in [ftDateTime, ftDate, ftTime] then
        begin
          if DataSet.Fields[i].IsNull then
            s := ''
          else
            s := GetDateTimeStr(DataSet.Fields[i].AsDateTime);
        end else
          s := DataSet.Fields[i].AsString;
        if ColAutoSize then
        begin
          Len := Length(s) - 1;
          if Len > MaxColWidth then
            Len := MaxColWidth;
          if Sheet.Columns[i + 1].ColumnWidth < Len then
            Sheet.Columns[i + 1].ColumnWidth := Len;
        end;
        Sheet.Cells[RowIndex, i + 1].value := s;
      end;
      if RowIndex = RowEnd then
        break;
      if RowIndex mod 10 = 0 then
      begin
        lb.Caption := Format('正在导出数据，已经完成：%d', [Trunc(RowIndex / RowEnd * 100)]) + '%';
        Form.Update();
        Application.ProcessMessages();
      end;
      RowIndex := RowIndex + 1;
      DataSet.Next();
    end;
    lb.Caption := '数据导出完毕......';
    Form.Update();
  end;
  function RowColToStr( R1, C1, R2, C2: Integer): String;
    function ColToStr(C: Integer): String;
    var
      nDiv: Integer;
    begin
      Result := '';
      if C > 26 then
      begin
        nDiv := C div 26;
        C := (C mod 26);
        if C = 0 then
        begin
          C := 26;
          nDiv := nDiv - 1;
        end;
        Result := Char(Integer('A') + nDiv);
      end;
      Result := Result + Char(Integer('A') + C - 1);
    end;
  begin
     Result := ColToStr(C1) + IntToStr(R1) + ':' + ColToStr(C2) + IntToStr(R2);
  end;
var
  Range, RangeFind: Variant;
  RowEnd: Integer;
 
  function RepString(FindStr, ReplacedStr: String): Boolean;
  begin
    Result := False;
    RangeFind := Excel.Cells.Find(FindStr, EmptyParam, xlFormulas, xlPart, xlByRows, xlNext, False, False);
    try
      RowIndex := RangeFind.Row;
      RangeFind.Select;
      Excel.ActiveCell.value := ReplacedStr;
      Result := True;
    except
    end;
  end;
  procedure SetFormat();
  var
    i: Integer;
  begin
    for i := 0 to DataSet.Fields.Count - 1 do
    begin
      case DataSet.Fields[i].DataType of
          ftSmallint, ftInteger, ftWord, ftAutoInc, ftLargeint:
          begin
            Range := Sheet.Range[RowColToStr(RowIndex, i + 1, RowEnd, i + 1)];
            Range.HorizontalAlignment := TextAlignRight;
            //Range.NumberFormat := '#,##0;-#,##0';
          end;
          ftFloat:
          begin
            Range := Sheet.Range[RowColToStr(RowIndex, i + 1, RowEnd, i + 1)];
            Range.HorizontalAlignment := TextAlignRight;
            Range.NumberFormat := '#,##0.000000;-#,##0.00000';
          end;
          ftDate, ftTime, ftDateTime:
          begin
            Range := Sheet.Range[RowColToStr(RowIndex, i + 1, RowEnd, i + 1)];
            Range.HorizontalAlignment := TextAlignRight;
            Range.NumberFormatLocal := '@';
            if DataSet.Fields[i].AsDateTime < 1000 then
              Sheet.Columns[i + 1].ColumnWidth := 9.1
            else
              Sheet.Columns[i + 1].ColumnWidth := 17;
          end;
      end;
    end;
  end;
  procedure CheckPageWidth();
  var
    PageW, WordW, BorderMargin: Integer;
    tmp: Integer;
    i: Integer;
    ftmp: real;
  begin
    if (xlPaperA4 = Sheet.PageSetup.PaperSize) and (xlPortrait = Sheet.PageSetup.Orientation) then
    begin
      BorderMargin := Sheet.PageSetup.LeftMargin * 2;
      WordW := GetColumnsWidth();
      PageW := Excel.InchesToPoints(21 / 2.54);
      if WordW > PageW - BorderMargin then
      begin
        Sheet.PageSetup.Orientation := xlLandscape;
        PageW := Excel.InchesToPoints(29.7 / 2.54);
        tmp := PageW - WordW - BorderMargin;
        ftmp := tmp / WordW;
        if (tmp < 0) and (ftmp >= -0.15) then
        begin
          ftmp := 1 + ftmp;
          for i := 1 to ColSum do
            Sheet.Columns[i].ColumnWidth := Sheet.Columns[i].ColumnWidth * ftmp;
        end;
      end;
    end;
  end;
var
  Workbook: Variant;
  CursorSave: TCursor;
  ColCenter: Integer;
  FileName: String;
begin
  ColSum := DataSet.Fields.Count;
  if ColSum = 0 then
  begin
    ShowMessage(#13'    数据表的列数为0，无法导出！');
    exit;
  end;
  CursorSave := Screen.Cursor;
  Form := TForm.Create(nil);
  Form.BorderStyle := bsNone;
  Form.FormStyle := fsStayOnTop;
  Form.Width := 300;
  Form.Height := 90;
  Form.Left := (Screen.Width - Form.Width) div 2;
  Form.Top := (Screen.Height - Form.Height) div 2;
  lb := TLabel.Create(Form);
  lb.Parent := Form;
  lb.AutoSize := False;
  lb.Left := 5;
  lb.Top := 35;
  lb.Width := 290;
  lb.Height := 30;
  lb.Font.Size := 10;
  lb.Font.Color := clBlue;
  Form.Show();
  try
    Screen.Cursor := crHourGlass;
    lb.Caption := '正在创建Excel......';
    Form.Update();
    RowEnd := GetExcel();
    if RowEnd > 0 then
    begin
      try
        try
          lb.Caption := '正在打开Excel......';
          Form.Update();
          FileName := ExtractFileDir(Application.ExeName) + '\' + Caption + '_模板.xls';
          if FileExists(FileName) then
          begin
            FileName := ExtractFileDir(Application.ExeName) + '\' + Caption + '.xls';
            CopyFile(PChar(ExtractFileDir(Application.ExeName) + '\' + Caption + '_模板.xls'), PChar(FileName), False) ;
          end else
            FileName := '';
          if FileName <> '' then
          begin
            Workbook := Excel.Workbooks.Open(FileName)
          end else
          begin
            Workbook := Excel.Workbooks.Add;
            Excel.WorkSheets[1].Name := Caption;
          end;
          Excel.WorkSheets[1].Activate;
          Sheet := Excel.Workbooks[1].WorkSheets[1];
          Sheet.Cells.NumberFormatLocal := '@';
          RowIndex := RowCaption;
          ColCenter := (ColSum + 1) div 2;
          lb.Caption := '正在设置标题......';
          Form.Update();
          Sheet.Range['A1:A1'].Select;
          if Caption <> '' then
          begin
            //设置标题
            if (FileName = '') or (not RepString('%标题%', Caption)) then
            begin
              Range := Sheet.Range[RowColToStr(RowIndex, 1, RowIndex, ColSum)];
              Range.NumberFormatLocal := '@';
              Range.HorizontalAlignment := TextAlignCenter;
              Range.VerticalAlignment := TextAlignVCenter;
              Range.Characters.Font.Name := FontNameCaption;
              Range.Characters.Font.FontStyle := '加粗';
              Range.Characters.Font.Size := FontSizeCaption;
              Sheet.Cells[RowIndex, ColCenter].value := Caption;
              Range.Merge;
            end;
          end;
          if SubCaption <> '' then
          begin
            //设置子标题
            if (FileName = '') or (not RepString('%子标题%', SubCaption)) then
            begin
              RowIndex := RowIndex + 1;
              Range := Sheet.Range[RowColToStr(RowIndex, 1, RowIndex, ColSum)];
              Range.HorizontalAlignment := TextAlignCenter;
              Range.VerticalAlignment := TextAlignTop;
              Range.Characters.Font.Name := FontNameSubCaption;
              Range.Characters.Font.FontStyle := '加粗';
              Range.Characters.Font.Size := FontSizeSubCaption;
              Sheet.Cells[RowIndex, ColCenter].value := SubCaption;
              Range.Merge;  //合并
              RowIndex := RowIndex + 1;
            end;
          end;
          if (FileName = '') then
          begin
            Sheet.Rows[Format('%d:%d', [RowIndex, RowIndex])].Select;
            Excel.Selection.RowHeight := 8;
            RowIndex := RowIndex + 1;
          end;
          if LeftCaption <> '' then
          begin
            //设置左标题
            if (FileName = '') or (not RepString('%左标题%', LeftCaption)) then
            begin
              //设置左标题
              Range := Sheet.Range[RowColToStr(RowIndex, 1, RowIndex, 1)];
              Range.HorizontalAlignment := TextAlignLeft;
              Range.Characters.Font.Name := FontNameLeftCaption;
              Range.Characters.Font.FontStyle := '加粗';
              Range.Characters.Font.Size := FontSizeLeftCaption;
              Sheet.Cells[RowIndex, 1].value := LeftCaption;
            end;
          end;
          if CenterCaption <> '' then
          begin
            //设置中标题
            if (FileName = '') or (not RepString('%中标题%', CenterCaption)) then
            begin
              Range := Sheet.Range[RowColToStr(RowIndex, ColCenter, RowIndex, ColCenter)];
              Range.HorizontalAlignment := TextAlignCenter;
              Range.Characters.Font.Name := FontNameCenterCaption;
              Range.Characters.Font.FontStyle := '加粗';
              Range.Characters.Font.Size := FontSizeCenterCaption;
              Sheet.Cells[RowIndex, ColCenter].value := CenterCaption;
            end;
          end;
          if RightCaption <> '' then
          begin
            //设置右标题
            if (FileName = '') or (not RepString('%右标题%', RightCaption)) then
            begin
              Range := Sheet.Range[RowColToStr(RowIndex, ColSum, RowIndex, ColSum)];
              Range.HorizontalAlignment := TextAlignRight;
              Range.Characters.Font.Name := FontNameRightCaption;
              Range.Characters.Font.FontStyle := '加粗';
              Range.Characters.Font.Size := FontSizeRightCaption;
              Sheet.Cells[RowIndex, ColSum].value := RightCaption;
            end;
          end;
          if RowIndex <> RowCaption then
            RowIndex := RowIndex + 1;
          //设置栏目字体
          Range := Sheet.Range[RowColToStr(RowIndex, 1, RowIndex, ColSum)];
          Range.Select;
          if (FileName <> '') and RepString('%栏目%', '') then
          begin
            Range.Characters.Font.Name := RangeFind.Characters.Font.Name;
            Range.Characters.Font.Size := RangeFind.Characters.Font.Size;
            Range.HorizontalAlignment := RangeFind.HorizontalAlignment;
            Range.Characters.Font.FontStyle := RangeFind.Characters.Font.FontStyle;
            Range.Borders[1].Weight := RangeFind.Borders[1].Weight;
            Range.Borders[2].Weight := RangeFind.Borders[2].Weight;
            Range.Borders[3].Weight := RangeFind.Borders[3].Weight;
            Range.Borders[4].Weight := RangeFind.Borders[4].Weight;
          end else
          begin
            Range.Characters.Font.Name := FontNameColumns;
            Range.Characters.Font.Size := FontSizeColumns;
            Range.HorizontalAlignment := TextAlignCenter;
            Range.Characters.Font.FontStyle := '加粗';
            Range.Borders[1].Weight := 2;
            Range.Borders[2].Weight := 2;
            Range.Borders[3].Weight := 2;
            Range.Borders[4].Weight := 2;
          end;
          Sheet.PageSetup.PrintTitleRows := Format('$%d:$%d', [RowIndex, RowIndex]);
          lb.Caption := '正在设置栏目和数据区字体......';
          Form.Update();
          //设置栏目文字
          if Columns is TFields then
            SetColumns(TFields(Columns))
          else
          if Columns is TStringGrid then
            SetColumns(TStringGrid(Columns))
          else
          if Columns is TListColumns then
            SetColumns(TListColumns(Columns));
          RowIndex := RowIndex + 1;
          //设置数据字体
          Range := Sheet.Range[RowColToStr(RowIndex, 1, RowEnd, ColSum)];
          Range.Select;
          if (FileName <> '') and RepString('%数据%', '') then
          begin
            Range.Characters.Font.Name := RangeFind.Characters.Font.Name;
            Range.Characters.Font.Size := RangeFind.Characters.Font.Size;
            Range.HorizontalAlignment := RangeFind.HorizontalAlignment;
            Range.Characters.Font.FontStyle := RangeFind.Characters.Font.FontStyle;
            Range.Borders[1].Weight := RangeFind.Borders[1].Weight;
            Range.Borders[2].Weight := RangeFind.Borders[2].Weight;
            Range.Borders[3].Weight := RangeFind.Borders[3].Weight;
            Range.Borders[4].Weight := RangeFind.Borders[4].Weight;
          end else
          begin
            Range.Characters.Font.Name := FontNameData;
            Range.Characters.Font.Size := FontSizeData;
            Range.Borders[1].Weight := 2;
            Range.Borders[2].Weight := 2;
            Range.Borders[3].Weight := 2;
            Range.Borders[4].Weight := 2;
          end;
          //设置数字栏显示格式
          if FileName = '' then
            SetFormat();
          //加载数据到Excel
          lb.Caption := '正在导出数据......';
          Form.Update();
          DoDataSetToExcel();
          Sheet.Range['A1:A1'].Select;
          if FileName = '' then
          begin
            Sheet.PageSetup.LeftMargin := Excel.InchesToPoints(0.590551181102362);//Excel.InchesToPoints(0.393700787401575);
            Sheet.PageSetup.RightMargin := Sheet.PageSetup.LeftMargin;
            Sheet.PageSetup.TopMargin := Sheet.PageSetup.LeftMargin;
            Sheet.PageSetup.BottomMargin := Sheet.PageSetup.LeftMargin;
            Sheet.PageSetup.CenterHorizontally := True;
            Sheet.PageSetup.CenterVertically := True;
            Sheet.PageSetup.CenterFooter := '第 &P 页，共 &N 页';
          end;
         
          CheckPageWidth();
          case Flag of
            1: //打印预览
            begin
              Excel.Visible := True;
              Form.Hide();
              Workbook.Saved := True;
              Excel.DisplayAlerts := False;
              Sheet.PrintPreview;
              Excel.Visible := False;
              Excel.Quit;
            end;
            2: //直接打印
            begin
              Form.Hide();
              Sheet.PrintOut;
              Workbook.Saved := True;
              Excel.DisplayAlerts := False;
              Excel.Quit;
            end;
          else //打开Excel编辑
            Form.Hide();
            Excel.Visible := True;
          end;
        except
          Workbook.Saved := True;
          Excel.DisplayAlerts := False;
          Excel.Quit;
        end;
      finally
        Excel := UnAssigned;
      end;
    end;
  finally
    lb.Destroy();
    Form.Destroy();
    Screen.Cursor := CursorSave;
  end;
end;
end.
weixin_34233618
关注
  • 0
    点赞
  • 踩
  • 0
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
Delphi数据导出到EXCEL方法
云中雁012345之成长
11-04 1737
TBookMark: GetBookMark,GotoBookMark,FreeBookMark的参数，不同的数据集使
用Delphi将数据导入到Excel并控制Excel
.net成长不容易
05-14 609
<br />在日常办公中，用得最多的是Word和Excel，而Excel对数据报表的处理尤为方便（操作公式、打印格式等），如果我们将数据导入到Excel中后，再靠我们平时对Excel熟练的操作很快编辑好我们有用的数据（如领导报表等），通过对Excel的控制，我们可以自动编缉好我们想要的格式和外观。<br /><br />一、调用Excel的方法：一般情况下有两种方法调用Excel：<br />1、  直接使用Delphi自带的组件：在Form中分别放入ExcelApplication, ExcelWorkb
Delphi 导出数据至Excel的7种方法
热门推荐
crkres9527
08-22 1万+
一; delphi 快速导出excel uses ComObj,clipbrd; function ToExcel(sfilename:string; ADOQuery:TADOQuery):boolean; const xlNormal=-4143; var y : integer; tsList : TStringList; s,filename :strin
Delphi DataSet超高效率导出到Excel——60万个数据9秒导出
z_ever的博客
01-08 1万+
Excel的ADO方法导出，60万个数据9秒导出。直接用SQL语句在Excel文件中追加需要导出的数据记录，代码简单明了，操作方便，效率较高（可能是仅次于文件流导出的方式）。
delphi导出数据至Excel的几种方法及比较
时光如流水的专栏
03-07 1941
delphi导出数据至Excel的几种方法及比较      一、delphi 快速导出excel uses ComObj,clipbrd; function ToExcel(sfilename:string; ADOQuery:TADOQuery):boolean; const       xlNormal=-4143; var   
DevExpress.ExpressPivotGrid.Suite.v2.39.for.Delphi.BCB.Full.Source
10-10
5. **ExpressLibrary**：这个可能是一个基础库，包含了一系列通用的辅助函数和类，为整个组件套件提供支持，如内存管理、错误处理和事件处理等。 6. **ExpressExport Library**：这个库提供了数据导出功能，可能...
Delphi开发范例宝典目录
03-07
实例069　将数据库数据添加到TListView控件　82 实例070　用TListView控件制作导航界面　83 实例071　在TListView控件中对数据排序或统计　84 实例072　在TListView组件中绘制底纹　86 实例073　在列表视图中拖动...
EMS Advanced Data Export Component Suite 4.8.0.1 for XE3 .7z
06-14
总的来说，**EMS Advanced Data Export Component Suite 4.8.0.1 for XE3** 是Delphi开发者的一个强大工具，它简化了数据导出的过程，提高了应用的灵活性和功能性。通过这个组件，开发者能够快速构建起数据导出功能...
ReportMachine.v7.0(D5-XE10.2)_Win64可编译64位
06-06
"jcl-master.zip"可能是JEDI Code Library（JCL），这是一个强大的C++ Builder和Delphi的通用类库，提供了许多实用的函数和组件。而"jedi-master.zip"可能指的是JEDI项目集，其中包括多个子项目，旨在促进Delphi和...
Delphi中导出到Excel的程序例子： DBGridToExcel
10-03
Delphi中导出到Excel的程序例子： DBGridToExcel， 速度很快，试过 2 万条的数据导出， 没试过更多的数据导出，速度应该也会很快， 学习它绝对有用 ！！！
Delphi 导出为Excel的函数代码
10-28
DELPHI 函数，可以将查询的记录 导出到EXCEL中。
Delphi DBGrid导出Excel文件最快速的代码
09-05
Delphi DataSet导出Excel文件最快速的代码，不用外挂，直接嵌合到程序中。
delphi dbgrid导出excel单元文件绝对好用
03-25
delphi dbgrid导出excel单元文件绝对好用 调用方式 var GridtoExcel: TDBGridEhToExcel; begin GridtoExcel := TDBGridEhToExcel.Create(nil); try GridtoExcel.DBGridEh := DBGridEh1; GridtoExcel.FileName := FormatDateTime('yyyy-mm-dd',DateTimePicker1.DateTime)+ '--------'+FormatDateTime('yyyy-mm-dd',DateTimePicker2.DateTime) +'退款订单导出'; GridtoExcel.ShowProgress := True; GridtoExcel.ExportToExcel; finally GridtoExcel.Free; end; end;
RLIBWIND7_3.24b16_FORTESREPORT_
09-28
1. **RLibWinD7vcl.bpl**：这是一个动态链接库（BPL）文件，它是Fortes Report与Delphi 7集成的关键。BPL文件通常包含已编译的代码，用于扩展IDE的功能或提供运行时支持。RLibWinD7vcl.bpl包含了Fortes Report的VCL...
Delphi 导出、导入Excel的一个快速方法
lcfeng1982的专栏
02-13 6606
The quickest way is to use an array of Variant,and just pass the entire array to Excel: var     xls, wb, Range: OLEVariant;     arrData: Variant;     RowCount, ColCount, i, j: Integer; begin
Delphi编程将数据库数据快速导入Excel
xxz1314的专栏
11-26 562
在开发数据库应用程序中，经常要将类型相同的数据导出来，放到excel文件中，利用excel强大的编辑功能，对数据作进一步的加工处理。这有许多的方法，我们可以使用ole技术，在delphi中创建一个自动化对象，通过该对象来传送数据。也可以使用ado，通过与excel数据存储建立连接，使用ado这种独立于数据库后端的技术来导出数据集的数据。  　　可这两种技术都有一个共同的缺点，那就是慢，数据量少还好
Delphi class TDataSetToExcel
weixin_34259559的博客
11-14 144
Question/Problem/Abstract: See Also : Article_4724.asp - (Freeform Excel Worksheet)This class will produce an Excel Spreadsheet from a TDataSet. No OLE is required or Excel Ins...
delphi导出数据到excel
最新发布
01-22
在 Delphi 中导出数据到 Excel 可以通过使用一些内置的组件和函数来实现。首先，可以使用 TExcelApplication 组件实例化一个Excel应用程序对象，并通过该对象来实现创建工作簿、工作表，以及导出数据的操作。然后...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值