做为一位系统集成工程师，尤其在新项目部署时，需要和一堆硬件设备打交道——服务器，存储，网络设备，操作系统都会有自己的IP地址段，而这时候只能通过笔记本直连进行调试配置，使用Windows界面来设置IP操作太繁琐，会浪费大量的APMi_f27.gif，正好趁着新年第一天上班，研究了下如何通过脚本配置ip。


(本文调试环境为win7简体中文旗舰版)


核心命令：

netsh interface ip set address 网络适配器名称 static IP MASK GATEWAY

netsh interface ip set address 本地连接 static 192.168.0.50 255.255.255.0 192.168.0.1


批处理脚本：（基于百度文库文章微调）

@echo off
cls
color 0A
echo IP地址更改小工具
set IP=192.168.70.180
set MASK=255.255.255.0
set GATEWAY=0.0.0.0
set NAME="本地连接"

echo.
echo 自动更改IP      请按 1
echo.
echo 更改IP          请按 2
echo.
echo 添加IP          请按 3
echo.
echo 恢复自动获取    请按 4

set /p KEY= [您的选择是：]
if %KEY% == 1 goto Default
if %KEY% == 2 goto Static
if %KEY% == 3 goto Add
if %KEY% == 4 goto DHCP
 
:Static
ECHO 您选择了手工修改设置。
ECHO.
echo 默认IP地址是%IP%，回车输入默认地址
set /p IP= [请输入IP地址:]
echo.
echo 默认MASK是%MASK%，回车输入默认值
set /p MASK= [请输入 子网掩码 地址:]
echo.
echo 默认GATEWAY是%GATEWAY%，回车输入默认值
set /p GATEWAY= [请输入 网关 地址:]
echo.
echo 正在自动更改IP......
netsh interface ip set address %NAME% static %IP% %MASK% %GATEWAY%
echo IP地址/子网掩码/网关设置完成
pause
goto :eof

:Default
echo 正在自动更改IP......
netsh interface ip set address %NAME% static %IP% %MASK% %GATEWAY%
echo IP地址/子网掩码/网关设置完成
pause
goto :eof

:Add
ECHO 您选择了添加IP设置。
ECHO.
echo 默认IP地址是%IP%，回车输入默认地址
set /p IP= [请输入IP地址:]
echo.
echo 默认MASK是%MASK%，回车输入默认值
set /p MASK= [请输入 子网掩码 地址:]
echo.
echo 正在添加IP......
netsh interface ip add address %NAME% %IP% %MASK%
echo IP地址/子网掩码/网关设置完成
pause
goto :eof

:DHCP
echo 正在改为自动获取....
netsh interface ip set address %NAME% source=dhcp
netsh interface ip set dns %NAME% source=dhcp
pause
goto :eof


1、习惯开着cmd的同学可以把bat文件放到c:\windows\system32下，这样在任何路径都可以调用了。

2、注意，在本地连接网口down的情况下，从静态ip变为DHCP看不出效果，插上网线就生效了