汇编程序:用子程序实现求幂

【任务】
  编制一个子程序,求y=x4,自变量 x 为字节,应变量y可以在一个字内存放而不溢出
  (1)版本1:子程序的参数由寄存器dl提供,返回结果在ax中;
  (2)版本2:子程序不变,主程序中提供如下数据区,在主程序中,循环调用子程序,完成y=x4的求解,并将结果存入在相应的数据区:

data segment
     x db 1,2,3,4,5,6,7,8
     y dw 0,0,0,0,0,0,0,0
data ends

  (3)版本3:数据区不变,子程序完成全部8个数据的求解任务,主程序只调用一次子程序即可。数据x的起始偏移地址由si提供,存放结果的y的偏移地址,由di提供,在调用前,由主程序为子程序提供si、di值。
  (4)版本4:将上面的程序按多文件的方式存放。

【参考解答】
  (1)版本1:子程序的参数由寄存器dl提供,返回结果在ax中;

assume cs:codesg, ss:stacksg
stacksg segment
    db  32 dup (0)
stacksg ends
codesg segment

main proc
start: mov ax,stacksg
       mov ss,ax
       mov sp,16
       mov bl,8  ;为调用子程序准备参数
       call subp
       ;子程序调用返回后要做的处理
       mov ax,4c00h
       int 21h
main endp

;子程序功能:求y=x^4
;入口参数:x的值由bl提供
;返回值:y值由ax返回,且y值
subp proc
    push cx
    push dx  ;虽然说最后的结果不会超出1个字,但并不意味着求解过程中中间结果不会超出1个字节,故这儿还要用字的乘法
    push bx  ;重点是保护bh
    ;尽管子程序中用到了ax,但规定结果由ax返回
    mov bh, 0 ;使bx的值,与作为参数的bl相等
    mov ax, 1
    mov cx, 4
 s: mul bx    ;用连乘4次实现4次方
    loop s
    pop bx
    pop dx   ;因为不超1个字,最后结果由ax返回就行了,dx恢复
    pop cx
    ret
subp endp

codesg ends
end start

  (2)版本2:子程序不变,主程序中提供如下数据区,在主程序中,循环调用子程序,完成y=x4的求解,并将结果存入在相应的数据区:

assume cs:codesg, ss:stacksg, ds:datasg
stacksg segment
    db  32 dup (0)
stacksg ends
datasg segment
     x db 1,2,3,4,5,6,7,8
     y dw 0,0,0,0,0,0,0,0
datasg ends
codesg segment

main proc
start:
       mov ax, datasg
       mov ds, ax
       mov ax,stacksg
       mov ss,ax
       mov sp,16
       mov cx, 8
       mov si, offset x
       mov di, offset y

    c: mov bl,[si]  ;为调用子程序准备参数
       call subp
       mov [di], ax  ;子程序调用返回后要做的处理
       inc si
       inc di
       inc di
       loop c

       mov ax,4c00h
       int 21h
main endp

;子程序功能:求y=x^4
;入口参数:x的值由bl提供
;返回值:y值由ax返回,且y值
subp proc
    push cx
    push dx  ;虽然说最后的结果不会超出1个字,但并不意味着求解过程中中间结果不会超出1个字节,故这儿还要用字的乘法
    push bx  ;重点是保护bh
    ;尽管子程序中用到了ax,但规定结果由ax返回
    mov bh, 0 ;使bx的值,与作为参数的bl相等
    mov ax, 1
    mov cx, 4
 s: mul bx    ;用连乘4次实现4次方
    loop s
    pop bx
    pop dx   ;因为不超1个字,最后结果由ax返回就行了,dx恢复
    pop cx
    ret
subp endp

codesg ends
end start

  (3)版本3:数据区不变,子程序完成全部8个数据的求解任务,主程序只调用一次子程序即可。数据x的起始偏移地址由si提供,存放结果的y的偏移地址,由di提供,在调用前,由主程序为子程序提供si、di值。

assume cs:codesg, ss:stacksg, ds:datasg
stacksg segment
    db  32 dup (0)
stacksg ends
datasg segment
     x db 1,2,3,4,5,6,7,8
     y dw 0,0,0,0,0,0,0,0
datasg ends
codesg segment

main proc
start:
       mov ax, datasg
       mov ds, ax
       mov ax,stacksg
       mov ss,ax
       mov sp,16
       mov si, offset x
       mov di, offset y

       call subp

       mov ax,4c00h
       int 21h
main endp

;子程序功能:求y[i]=x[i]^4,即为8个连续存储的字节求幂
;入口参数:参数x[i]作为源参数,起始地址在si
;        存放求值结果y[i]的内存单元,起始地起码在di中
;返回值:无
subp proc
    push cx
    push dx  ;虽然说最后的结果不会超出1个字,但并不意味着求解过程中中间结果不会超出1个字节,故这儿还要用字的乘法
    push bx  ;重点是保护bh
    mov bh, 0 ;使下面要用到bx时,bx的值就是其低8位bl
    mov cx, 8 ;循环8次,处理8个数据
 c: mov bl,[si]  ;为调用子程序准备参数
    mov ax, 1
    push cx  ;保护外层循环次数
    mov cx, 4
 s: mul bx    ;用连乘4次实现4次方
    loop s
    mov [di], ax  ;子程序调用返回后要做的处理
    inc si
    inc di
    inc di
    pop cx   ;恢复外层循环次数
    loop c

    pop bx
    pop dx   ;因为不超1个字,最后结果由ax返回就行了,dx恢复
    pop cx
    ret
subp endp

codesg ends
end start

  (4)版本4:将上面的程序按多文件的方式存放。
主程序所在文件:

extrn subp:far
assume cs:codesg, ss:stacksg, ds:datasg
stacksg segment
    db  32 dup (0)
stacksg ends
datasg segment
     x db 1,2,3,4,5,6,7,8
     y dw 0,0,0,0,0,0,0,0
datasg ends
codesg segment

main proc
start:
       mov ax, datasg
       mov ds, ax
       mov ax,stacksg
       mov ss,ax
       mov sp,16
       mov si, offset x
       mov di, offset y

       call subp

       mov ax,4c00h
       int 21h
main endp

codesg ends
end start

子程序所在文件

public subp
assume cs:codesg
codesg segment
;子程序功能:求y[i]=x[i]^4,即为8个连续存储的字节求幂
;入口参数:参数x[i]作为源参数,起始地址在si
;          存放求值结果y[i]的内存单元,起始地起码在di中
;返回值:无
subp proc far
    push cx
    push dx  ;虽然说最后的结果不会超出1个字,但并不意味着求解过程中中间结果不会超出1个字节,故这儿还要用字的乘法
    push bx  ;重点是保护bh
    mov bh, 0 ;使下面要用到bx时,bx的值就是其低8位bl
    mov cx, 8 ;循环8次,处理8个数据
 c: mov bl,[si]  ;为调用子程序准备参数
    mov ax, 1
    push cx  ;保护外层循环次数
    mov cx, 4
 s: mul bx    ;用连乘4次实现4次方
    loop s
    mov [di], ax  ;子程序调用返回后要做的处理
    inc si
    inc di
    inc di
    pop cx   ;恢复外层循环次数
    loop c

    pop bx
    pop dx   ;因为不超1个字,最后结果由ax返回就行了,dx恢复
    pop cx
    ret
subp endp

codesg ends
end
发布了136 篇原创文章 · 获赞 40 · 访问量 16万+
展开阅读全文
评论将由博主筛选后显示,对所有人可见 | 还能输入1000个字符

没有更多推荐了,返回首页

©️2019 CSDN 皮肤主题: 大白 设计师: CSDN官方博客

分享到微信朋友圈

×

扫一扫,手机浏览