.版本 2
.支持库 iext
.程序集 窗口程序集1
.子程序 取随机文本, 文本型
.参数 长度, 整数型
.局部变量 字节数组, 字节型, , "0"
.局部变量 n, 整数型
重定义数组 (字节数组, 假, 长度)
.计次循环首 (长度, n)
.判断开始 (取随机数 (0, 1) = 0)
字节数组 [n] = 取随机数 (65, 90)
.默认
字节数组 [n] = 取随机数 (97, 122)
.判断结束
.计次循环尾 ()
返回 (到文本 (字节数组))
.子程序 __启动窗口_创建完毕
.局部变量 索引, 整数型
.局部变量 n, 整数型
置随机数种子 ()
.计次循环首 (100, n)
索引 = 超级列表框1.插入表项 (n, 到文本 (取随机数 (1, 100)), , , , )
超级列表框1.置标题 (索引, 1, 取随机文本 (取随机数 (5, 20)))
.计次循环尾 ()
.子程序 排序列表
.参数 参考列, 整数型
.局部变量 文本数组, 文本型, , "0"
.局部变量 n, 整数型
重定义数组 (文本数组, 假, 超级列表框1.取表项数 ())
.计次循环首 (超级列表框1.取表项数 (), n)
文本数组 [n] = 超级列表框1.取标题 (n - 1, 参考列)
超级列表框1.置表项数值 (n - 1, 取文本地址 (文本数组 [n], 文本数组 [n], 0))
.计次循环尾 ()
超级列表框1.发送信息 (#LVM_SORTITEMS, 0, 到整数 (&CompareFunc))
.子程序 CompareFunc, 整数型
.参数 lParam1, 整数型
.参数 lParam2, 整数型
.参数 lParamSort, 整数型
.局部变量 整数1, 整数型
.局部变量 整数2, 整数型
' lParam1 和 lParam2 是 超级列表框.置表项数值() 的值;
' 如果 lParam1 要排在 lParam2 前面,则函数需要返回一个负数;
' 如果 lParam1 要排在 lParam2 后面,则函数需要返回一个正数;
' 如果不改变两者位置则返回0。
.判断开始 (组合框_排序列.现行选中项 = 0)
' 超级列表框 第0列用数字方式排序
整数1 = 到整数 (指针到文本 (lParam1))
整数2 = 到整数 (指针到文本 (lParam2))
.判断开始 (组合框_升降序.现行选中项 = 0)
返回 (到整数 (整数1 - 整数2)) ' 升序
.默认
返回 (到整数 (整数2 - 整数1)) ' 降序
.判断结束
.判断 (组合框_排序列.现行选中项 = 1)
' 超级列表框 第1列用文本方式排序
.判断开始 (组合框_升降序.现行选中项 = 0)
返回 (lstrcmpA (lParam1, lParam2)) ' 升序
.默认
返回 (lstrcmpA (lParam2, lParam1)) ' 降序
.判断结束
.默认
.判断结束
返回 (0)
.子程序 _按钮1_被单击
排序列表 (组合框_排序列.现行选中项)