数据权限过滤_Power BI Desktop通过权限表 动态控制数据权限

目录

• 数据准备
• 两种权限控制方式
  • 在角色管理中输入DAX表达式
  • 新建度量值控制权限

一、数据准备

权限表：(一层部门中写ALL表示该用户能看到所有一层部门的数据，二层部门写ALL表示该用户能看到所有二层部门的数据)

部门信息表：

要达到的效果是根据用户的权限表给用户展示相对应部门的数据

二、两种权限控制方式

在角色管理中输入DAX表达式

建模 -> 管理角色 -> 创建 -> 选择要进行数据权限控制的表 -> 书写权限代码 -> 保存

VAR First_Dept = CALCULATETABLE(
VALUES('权限表'[一层部门]),'权限表'[用户名]=USERPRINCIPALNAME())
/* 表示将权限表中当前用户所对应的一层部门数据赋值给变量First_Dept */

VAR Second_Dept = CALCULATETABLE(
VALUES('权限表'[二层部门]),'权限表'[用户名]=USERPRINCIPALNAME()) 
/* 表示将权限表中当前用户所对应的二层部门数据赋值给变量Second_Dept */

RETURN 
OR(OR(
AND("ALL" IN First_Dept,"ALL" IN Second_Dept),
AND('部门信息表'[一层部门名称] IN First_Dept,"ALL" IN Second_Dept)),
AND('部门信息表'[一层部门名称] IN First_Dept,'部门信息表'[二层部门名称] IN Second_Dept)
)
/*
这里返回值有三种情况，满足任意一种即可返回相对应的数据：
1、权限表中一层部门="ALL"并且二层部门="ALL"，则返回部门信息表中的所有数据
2、权限表中一层部门="部门名称"并且二层部门="ALL"，则返回部门信息表中一层部门名称="部门名称"的数据
3、权限表中一层部门="部门名称"并且二层部门="部门名称"，则返回部门信息表中这两个条件过滤后的数据
*/

然后进行测试：

建模 -> 通过以下身份查看 -> 勾选其他用户并输入用户名 同时勾选"权限控制"角色 -> 确定

我们再检查下其他用户的数据查看是否正确

因为部门信息表中没有公关部的数据，所以以Jack身份查看表为空。

新建度量值控制权限

在部门信息表中新建两个度量值

一层部门权限 = 
VAR First_Dept = SELECTEDVALUE('部门信息表'[一层部门名称])
VAR Items = CALCULATETABLE(VALUES('权限表'[一层部门]),
                            FILTER('权限表','权限表'[用户名]=USERNAME()))
RETURN OR("ALL" IN Items,First_Dept IN Items)

二层部门权限 = 
VAR Second_Dept = SELECTEDVALUE('部门信息表'[二层部门名称])
VAR Items = CALCULATETABLE(VALUES('权限表'[二层部门]),
                            FILTER('权限表','权限表'[用户名]=USERNAME()))
RETURN OR("ALL" IN Items,Second_Dept IN Items)

然后也是需要创建一个角色：建模 -> 管理角色 -> 创建 -> 选择要进行数据权限控制的表 -> 书写权限代码 -> 保存

[一层部门权限] = True()
&&
[二层部门权限] = True()

然后再对用户进行权限测试。