服务器文件备份到本地方法,备份服务器文件到本地

该楼层疑似违规已被系统折叠 隐藏此楼查看此楼

@echo off & title 备份目录

color 0a & cd /d %~dp0

::1.压缩前一天备份保存的主目录

::2.删除旧压缩备份

::3.要备份的文件保存到备份目录

::====请设置以下信息=================

::设置要备份的主目录、登录信息

set SrcDir=\\172.16.30.230\信息部

set SrcUser=xxb

set SrcPwd=kyss@750

::设置备份保存主目录、登录名、密码

set SavDir=F:\信息部共享备份

::设置备份前是否清空保存目录，是 = 1 ，否 = 0

set DelIt=1

::设置是否压缩前一天的备份，是 = 1 ，否 = 0

set RarBack=1

::设置压缩文件备份保存路径、文件名、WINRAR程序路径

set RarDir=F:\信息部共享备份压缩包

set RarName=信息部

set RarPath=C:\Program Files\WinRAR\Rar.exe

::设置压缩备份保存天数

set DelRar=1

::====请设置以上信息=================

::登录共享服务器

net use %SrcDir% %SrcPwd% /user:%SrcUser%

::取日期、时间变量值

set yy=%date:~0,4%

set mm=%date:~5,2%

set dd=%date:~8,2%

set hh=%time:~0,2%

set mn=%time:~3,2%

set RarTime=%yy%-%mm%-%dd%-%hh%%mn%

echo, & echo 日期变量取值完成。

::压缩备份文件

if exist "%SavDir%" (

if %RarBack% equ 1 (

echo, & echo 正在压缩目录 "%SavDir%"，请稍等...

"%RarPath%" a -as -r "%RarDir%\%RarName%%RarTime%.rar" "%SavDir%"

echo, & echo 压缩完成。

)

)

echo, & echo 正在删除%RarDir%的旧文件，请稍等...

Forfiles /p %RarDir% /s /d -%DelRar% /m *.* /c "cmd /c del /q /f @path"

echo, & echo 删除完成。

::清空备份保存目录

if exist "%SavDir%" (

if %DelIt% equ 1 (

echo 正在清空备份保存目录 "%SavDir%"，请稍等...

rd /s /q "%SavDir%"

)

)

echo, & echo 正在备份目录 "%SrcDir%"，请稍等...

xcopy /s/e/h/d/y "%SrcDir%" "%SavDir%\"

echo, & echo 备份完成。

::断开共享服务器

net use %SrcDir% /d /y

c:

cd Program Files

del 文件备份及压缩20190218.bat

pause

exit