JAVA王思聪吃热狗程序_易语言制作王校长吃热狗游戏的源码

王校长吃热狗游戏

.版本 2

.支持库 iext2

.支持库 OPenGL

.支持库 spec

.支持库 EThread

.程序集 窗口程序集_启动窗口

.程序集变量 人物标识, 整数型

.程序集变量 热狗标识, 整数型, , "0"

.程序集变量 死亡, 逻辑型

.程序集变量 得分, 整数型

.子程序 _开始按钮_被单击

动画物体2.图片 ＝ #人物

人物标识 ＝ 动画框1.创建物体 (动画物体2, 取鼠标水平位置 () － _启动窗口.左边 － 25, 取鼠标垂直位置 () － _启动窗口.顶边 － 26, 真, )

得分 ＝ 0

显示光标 (假)

开始按钮.可视 ＝ 假

死亡 ＝ 假

开始游戏 ()

.子程序 开始游戏

.局部变量 热狗, 整数型

.局部变量 移动速度, 整数型

.局部变量 新增速度, 整数型

.局部变量 i, 整数型

动画物体1.图片 ＝ #热狗

移动速度 ＝ 50

新增速度 ＝ 500

.判断循环首 (死亡 ＝ 假)

热狗 ＝ 动画框1.创建物体 (动画物体1, 取随机数 (24, 368), 38, 真, )

动画框1.置角度 (热狗, 180)

.如果真 (得分 ％ 20 ＝ 0 且 移动速度 ＞ 10 且 新增速度 ＞ 200)

移动速度 ＝ 移动速度 － 1

新增速度 ＝ 新增速度 － 20

.如果真结束

动画框1.自动前进 (热狗, 5, 移动速度, , , 真, 1, 真, { 0 }, )

延迟 (新增速度)

.判断循环尾 ()

.子程序 _动画框1_鼠标位置被移动, 逻辑型

.参数 横向位置, 整数型

.参数 纵向位置, 整数型

.参数 功能键状态, 整数型

动画框1.置物体位置 (人物标识, 取鼠标水平位置 () － _启动窗口.左边 － 25, 取鼠标垂直位置 () － _启动窗口.顶边 － 26, 真)

.子程序 _动画框1_碰撞到物体

.参数 碰撞物体标识值, 整数型

.参数 碰撞前横坐标, 整数型

.参数 碰撞前纵坐标, 整数型

.参数 被碰撞物体标识值, 整数型

.如果真 (被碰撞物体标识值 ＞ 得分 ＋ 1 或 碰撞物体标识值 ＞ 得分 ＋ 1)

得分 ＝ 得分 ＋ 1

启动线程 (&显示成功图, , )

_启动窗口.标题 ＝ “王校长吃热狗 得分：” ＋ 到文本 (得分)

.如果真结束

.子程序 显示成功图

动画框1.置图片 (人物标识, #成功, )

延迟 (200)

动画框1.置图片 (人物标识, #人物, )

.子程序 __启动窗口_可否被关闭, 逻辑型

结束 ()

.子程序 _动画框1_碰撞到边界, 逻辑型

.参数 物体标识值, 整数型

.参数 碰撞前横坐标, 整数型

.参数 碰撞前纵坐标, 整数型

.参数 边界类型, 整数型

.如果真 (物体标识值 ≠ 人物标识 且 边界类型 ＝ 8)

显示光标 (真)

死亡 ＝ 真

动画框1.销毁所有物体 ()

信息框 (“游戏结束，得分：” ＋ 到文本 (得分), 0, , )

开始按钮.可视 ＝ 真

得分 ＝ 0

_启动窗口.标题 ＝ “王校长吃热狗”

.如果真结束

运行结果：

总结

以上就是这篇文章的全部内容了，希望本文的内容对大家的学习或者工作具有一定的参考学习价值，谢谢大家对脚本之家的支持。如果你想了解更多相关内容请查看下面相关链接