vb登录php代码,VB自动登陆网络站点详解

URL

帐号

密码

其它参数

SOHU邮箱

http://login.sohu.com/chkpwd.php

UserName

Password

网易通行证

http://reg4.163.com/CheckUser.jsp

username

password

CSDN通行证

http://www.csdn.net/member/logon.asp

login_name

password

cookietime=0&

x=42&y=10

表格中的参数就是按照前面介绍的方法得到的，在程序中将要用到。

先说明一点， WebBrowser也是可以直接POST数据给Web服务器的，我将在第四部分给出代码。这里先看看Inet与WebBrowser相互配合的效果。

新建一个工程，部件中勾选中“Microsoft Internet Transfer Controls 6.0”、“Microsoft Internet Controls”，依次添加Inet1、WebBrowser1、Text1、Text2、Combo1在窗体上，可以把WebBrowser1适当拉大一点，将各控件位置安排好(可以参考运行后的图片)，下面是代码：

Dim URL1(2) As String:  Dim URL2(2) As String

Dim C1(2) As String: Dim C2(2) As String: Dim C3(2) As String

Private Sub Form_Load()

Text1.Text = ""

Text2.Text = ""

Text2.PasswordChar = "*"

Combo1.AddItem "SOHU邮箱", 0

Combo1.AddItem "网易通行证", 1

Combo1.AddItem "CSDN通行证", 2

Combo1.AddItem "请选择一个登陆", 3

Combo1.Text = Combo1.List(3)

URL1(0) = "http://login.sohu.com/chkpwd.php": URL2(0) = "http://www34.mail.sohu.com/control/entry"

URL1(1) = "http://reg4.163.com/CheckUser.jsp": URL2(1) = "http://reg4.163.com/Main.jsp?"

URL1(2) = "http://www.csdn.net/member/logon.asp": URL2(2) = "http://www.csdn.net/Member/Passport.asp"

C1(0) = "UserName": C2(0) = "Password": C3(0) = ""

C1(1) = "username": C2(1) = "password": C3(1) = ""

C1(2) = "login_name": C2(2) = "password": C3(2) = "cookietime=0&x=42&y=10"

End Sub

Private Sub Form_Resize()

If Me.WindowState <> 1 Then

WebBrowser1.Left = 10

WebBrowser1.Width = Me.Width - 120

WebBrowser1.Height = Me.Height - 800

End If

End Sub

Private Sub Text2_KeyUp(KeyCode As Integer, Shift As Integer)

If KeyCode <> 13 Then Exit Sub

If Combo1.ListIndex = 3 Then MsgBox "请选择一个登陆": Exit Sub

If Text1.Text = "" Then MsgBox "请输入用户名": Exit Sub

If Text2.Text = "" Then MsgBox "请输入密码": Exit Sub

Dim strFormData As String

strFormData = C1(Combo1.ListIndex) + "=" + Text1.Text + "&" + C2(Combo1.ListIndex) + "=" + Text2.Text + "&" + C3(Combo1.ListIndex)

Inet1.Execute URL1(Combo1.ListIndex), "Post", strFormData, "Content-Type: application/x-www-form-urlencoded "

Do Until Inet1.StillExecuting = False '这里阻塞前面的Inet1，确保登陆成功之后再取页面，你可以将此Do取消了试一次。

DoEvents

Loop

If Combo1.ListIndex = 1 Then

WebBrowser1.Navigate URL2(Combo1.ListIndex) + C1(Combo1.ListIndex) + "=" + Text1.Text

Else

WebBrowser1.Navigate URL2(Combo1.ListIndex)

End If

End Sub

大家可以挑选一个自己已经注册过的站点看看效果。

点击查看大图

可以看到，登陆成功之后， Inet与WebBrowser是可以保持住同一个Session对话的！不过当我们在WebBrowser中显示出来的页面上点击了一个连接之后，请求却不能成功(请读者自己试一下，在登陆成功的站点中任意点击一个与用户相关的连接，弹出来的将是一个“你没有登陆”的页面)。为什么？

因为我们现在点击的连接还是使用IE(操作系统默认的浏览器)打开的，而IE请求页面的时候使用的是服务器新发送过来的Session，这个新的Session与你在WebBrowser中使用的Session也就是身份ID不一样，至少服务器是这么认为的，它以为是另一个没有登陆的用户。所以说Session的作用范围不是对整个客户机的，通过实际的代码可以很好的理解这一点。(可以利用这一点，使用代码在一台电脑上实现两个以上的用户同时登陆，甚至还能对同一主题进行无缝发言。)

所以接下来我们要使页面继续停在WebBrowser中显示。因为很显然，既然WebBrowser与Inet是可以保持住同一个Session对话的，那么WebBrowser与WebBrowser内部自然也是可以的！

要添加的代码很简单——

Private Sub WebBrowser1_NewWindow2(ppDisp As Object, Cancel As Boolean)

Dim frm2 As New Form2

frm2.WebBrowser1.RegisterAsBrowser = True

Set ppDisp = frm2.WebBrowser1.Object

frm2.Show

End Sub

然后在工程中添加一个Form2，上面再放一个WebBrowser1，调整好位置，Form2的代码窗口添加上以下代码：

Private Sub Form_Load()

WebBrowser1.Silent = True

End Sub

Private Sub Form_Resize()

If Me.WindowState <> 1 Then

WebBrowser1.Left = 10

WebBrowser1.Width = Me.Width - 120

WebBrowser1.Height = Me.Height - 600

End If

End Sub

Private Sub WebBrowser1_NewWindow2(ppDisp As Object, Cancel As Boolean)’这里为了避免在Form1中同样发生的事情。

Dim frm2 As New Form2

frm2.WebBrowser1.RegisterAsBrowser = True

Set ppDisp = frm2.WebBrowser1.Object

frm2.Show

End Sub

利用Inet发送登陆请求，WebBrowser浏览实际页面，的确是个很不错的构思，在登陆站点相对教少的情况下应该是没有什么问题的。但是这也会使事情变得更加复杂。除了不能缺少的POST地址(URL1)、帐号参数(C1)、密码参数(C2)、其它参数(C3)之外，还必须要有供WebBrowser请求浏览的页面地址参数(URL2)。 虽然只是多了一个参数，但却添加了很多麻烦(比如网易邮箱的请求页面是根据用户的帐号名自动生成的，不固定)。只有利用WebBrowser直接POST数据才能避免第四个参数。但是浏览器的界面以及功能却是一个比较麻烦的问题(除非你不嫌麻烦，自己再动手写一个)。

使用Internet Explorer对象可以使POST请求在IE中产生，从而脱离程序，远离了美化界面的工作。程序甚至可以隐藏或退出，免去了WebBrowser带来的烦恼，当然也不需要第四个参数。

下面我们还是以登陆CSDN为例，给出实际的代码，您可以根据前面文章中提供的参数换成你注册过的站点：

建新工程，在工程中“引用”Internet Explorer对象，点“浏览”，在系统文件夹下找到Shdocvw.dll(这个文件是IE自带的)，Form1中添加Command1，以下是代码——

Dim g_oIE As InternetExplorer

Private Sub Command1_Click()

Dim vPost As Variant

Dim vHeaders As Variant

Set g_oIE = New InternetExplorer

g_oIE.Visible = True

ReDim aByte(0) As Byte

cPostData = "login_name=帐号&password=密码&cookietime=0"

PackBytes aByte(), cPostData

vPost = aByte

vHeaders = "Content-Type: application/x-www-form-urlencoded" + Chr(10) + Chr(13)

g_oIE.Navigate "http://www.csdn.net/member/logon.asp", , , vPost, vHeaders

End Sub

Private Sub PackBytes(ByteArray() As Byte, ByVal PostData As String)

iNewBytes = Len(PostData) - 1

If iNewBytes < 0 Then Exit Sub

ReDim ByteArray(iNewBytes)

For i = 0 To iNewBytes

ch = Mid(PostData, i + 1, 1)

If ch = Space(1) Then

ch = "+"

End If

ByteArray(i) = Asc(ch)

Next

End Sub

(请输入自己的帐号及密码试运行。这种方法的好处是显而易见的，你可以按这个方法将前面的代码改造一下。)

PackBytes函数将Post出去的数据转化为一个ASCII数组，另外vHeaders的值必须以“+ Chr(10) + Chr(13)”结束。

代码没有什么好解释的，现在已经进入到Shdocvw.dll这个“库”中去了，而前面所说的WebBrowser及Internet Explorer都是这个库中所包含的“类”。大家可以打开对象浏览器看看它们互相之间的关系。

本来这一部分内容也应该放在第二章，但一方面为了醒目，另一方面，这种方法实际上与Internet Explorer对象有很大的联系及相似性，所以特意将之放在Internet Explorer对象之后介绍。

现在我们要用到的也是WebBrowser的“Navigate”方法，其函数原型如下所示：

Sub Navigate(URL As String, [Flags], [TargetFrameName], [PostData], [Headers])

大家不妨与第三章中Internet Explorer对象的“Navigate”方法比较一下，一模一样，原来是同一个接口！！

新建一个工程，部件中勾选中 “Microsoft Internet Controls”，添加一个WebBrowser1、一个Command1在窗体上，可以把WebBrowser1适当拉大一点，Form1中添加以下代码：

Private Sub Command1_Click()

ReDim aByte(0) As Byte ' Array of bytes to hold data to post

cPostData = "login_name=帐号&password=密码&cookietime=0&x=42&y=10"

PackBytes aByte(), cPostData

Dim vPost As Variant

vPost = aByte ' Assign the byte array to a VARIANT

Dim vHeaders As Variant

vHeaders = "Content-Type: application/x-www-form-urlencoded" + Chr(10) + Chr(13)

WebBrowser1.Navigate "http://www.csdn.net/member/logon.asp", , , vPost, vHeaders

End Sub

Private Sub PackBytes(ByteArray() As Byte, ByVal PostData As String)

iNewBytes = Len(PostData) - 1   ' Get rid of the null termination

If iNewBytes < 0 Then

Exit Sub

End If

ReDim ByteArray(iNewBytes)

For i = 0 To iNewBytes

ch = Mid(PostData, i + 1, 1)

If ch = Space(1) Then

ch = "+"

End If

Debug.Print ch, Asc(ch)

ByteArray(i) = Asc(ch)

Next

End Sub

(请参考第三章中的代码。)

通过这四篇文章的介绍，我想读者一定不光是对VB登陆Web服务器有了更深的认识，而且同时对HTTP协议、Cookie、Session也加深了理解！

全文完！！！

注：本系列文章，请勿用于商业用途，有转载或发表行为的请务必事先与本人联系wshk_18@163.com