如何创建xsl文件 xml_EXCEL知识分享 I 连载如何快速创建XML文件

转自：Excel之家ExcelHome

XML文件本质上是文本文件，因此使用创建文本文件的方式就可以创建XML文件。此外，在VBA中也可以使用XML DOM对象创建XML文件，示例代码如下。

#001 Sub CreateXML()

#002 Dim objXMLDOM As Object

#003 Dim objNode As Object

#004 Dim objVer As Object

#005 Set objXMLDOM = CreateObject("Microsoft.XMLDOM")

#006 Set objVer = objXMLDOM.createProcessingInstruction("xml", _

"version=" & Chr(34) & "1.0" & Chr(34))

#007 objXMLDOM.appendChild objVer

#008 Set objNode = objXMLDOM.createElement("Test")

#009 objNode.appendChild objXMLDOM.createTextNode(vbCrLf)

#010 objXMLDOM.appendChild objNode

#011 CreateNode objNode, "FirstName", "张"

#012 CreateNode objNode, "LastName", "三"

#013 CreateNode objNode, "NikName", "张三"

#014 CreateNode objNode, "Level", "版主"

#015 objXMLDOM.Save ThisWorkbook.Path & "umber.xml"

#016 Set objXMLDOM = Nothing

#017 Set objNode = Nothing

#018 Set objVer = Nothing

#019 End Sub

#020 Sub CreateNode(objNode As Object, _

strName As String, strValue As String)

#021 Dim objNewNode As Object

#022 With objNode

#023 .appendChild .OwnerDocument.createTextNode(Space$(4))

#024 Set objNewNode = .OwnerDocument.createElement(strName)

#025 objNewNode.Text = strValue

#026 .appendChild objNewNode

#027 .appendChild .OwnerDocument.createTextNode(vbCrLf)

#028 End With

#029 Set objNewNode = Nothing

#030 End Sub

代码解析：

第5行代码采用后期绑定的方式，使用CreateObject函数创建对Microsoft.XMLDOM对象的引用。除此之外，也可以使用前期绑定的方式引用【Microsoft XML,V6.0】库，具体操作步骤如下。

在Visual Basic编辑器中依次单击菜单【工具】→【引用】打开【引用 - VBAProject】对话框，在【可使用的引用】列表框中定位并勾选【Microsoft XML， v6.0】的复选框，如图所示。

引用Microsoft XML库

第6行代码使用CreateProcessingInstruction方法建立新的处理指令，该指令包含了指定的目标和数据。其中“xml”表示目标或处理指令的字符串，“version=***”表示处理指令的数据。尽管新的处理指令被建立，但并没有添加到文件树中。

第7行代码使用appendChild方法将第6行代码的处理指令插入到文件树中。AppendChild方法表示加上一个节点作为指定节点最后的子节点。

第8行代码使用createElement方法创建名为“Test”的新元素，也可以使用CreateNode方法来创建该元素，示例代码如下。

Set objNode = xmldoc.CreateNode(1, "Test", "")

CreateNode方法建立一个指定型态、名称及命名空间的新节点，其语法格式如下。

xmlDocument.createNode(type, name, nameSpaceURI)

其中参数type代表将被建立的节点型态，参数name代表新节点的名称，参数nameSpaceURI则指定定义命名空间URI字符串。

第9行代码使用createTextNode方法创建新的text节点，并指定代表该节点的字符串，使用appendChild方法将该节点插入到文件树中。

第10行代码使用appendChild方法将新创建的元素Test加入到文件树中。

第11行到第14行代码调用CreateNode过程创建“Test”元素下的节点。

第15行代码使用Save方法保存XML DOM对象到指定的XML文档。

第20行到第30行代码为CreateNode过程，该过程在指定元素下创建新的节点并为节点赋值。

运行CreateXML过程，将在指定的目录下创建名为“number.xml”的文档。使用记事本程序打开该文档，结果如下图所示。

XML文档的文本内容

在IE浏览器中打开“number.xml”文档，单击“”前面的“−”符号可以折叠所有的标签，单击“”前面的“+”符号可以展开隐藏的标签，如下图所示。

XML文件在Internet Explorer中的显示效果

代码扩展：

使用Workbooks对象的OpenXML方法可以打开XML文件，其语法格式如下。

Workbooks.OpenXML(Filename,[Stylesheets],[LoadOption])

其中参数Filename是必需的，其值代表要打开的文件名。

参数Stylesheets是可选的，其值指定XSLT(XSL转换)样式表的处理指令。XSL是eXtensible Style Language的缩写，是XML的样式表语言。XML用于承载数据，XSL则用于设置数据的显示格式。XSL是一个较为复杂的主题，感兴趣的读者可以自行学习相关资料。

参数LoadOption是可选的，指定打开XML数据文件的方式。其值可以为xlXmlLoadOption常量之一。

此外，使用VBA代码也能够将工作表另存为XML文件，只需设置SaveAs方法的参数FileFormat为xlXMLSpreadsheet常量即可，示例代码如下。

ActiveSheet.SaveAs ThisWorkbook.Path & "excelxml.xml", xlXMLSpreadsheet

利用SaveAs方法保存示例文件为XML文件，使用记事本程序打开XML文件，结果如下图所示。

使用SaveAs方法将工作簿保存为XML文件

除了将整个工作簿保存为XML文件，也可以仅保存指定的单元格范围为XML文件。保存当前工作表A1：B3单元格区域到代码所在工作簿路径下的rangexml.xml文件。示例代码如下。

#001 Sub SaveRangetoXML()

#002 Dim strContent As String

#003 strContent = Range("A1:B3").Value(xlRangeValueXMLSpreadsheet)

#004 Open ThisWorkbook.Path & "angexml.xml" For Binary As #1

#005 Put #1, , strContent

#006 Close #1

#007 End Sub