DATA: ISPFLI TYPE TABLE OF SPFLI.
DATA: GR_TABLE TYPE REF TO CL_SALV_TABLE.
* 使用CL_SALV_FUNCTIONS添加工具栏
DATA: GR_FUNCTIONS TYPE REF TO CL_SALV_FUNCTIONS.
"显示标题
DATA: GR_DISPLAY TYPE REF TO CL_SALV_DISPLAY_SETTINGS.
"列格式
DATA: GR_COLUMNS TYPE REF TO CL_SALV_COLUMNS_TABLE.
DATA: GR_COLUMN TYPE REF TO CL_SALV_COLUMN_TABLE.
"排序
DATA: GR_SORTS TYPE REF TO CL_SALV_SORTS.
"字段汇总
DATA: GR_AGG TYPE REF TO CL_SALV_AGGREGATIONS.
"字段过滤
DATA: GR_FILTER TYPE REF TO CL_SALV_FILTERS.
"增加变式保存
DATA: GR_LAYOUT TYPE REF TO CL_SALV_LAYOUT.
DATA: KEY TYPE SALV_S_LAYOUT_KEY.
"颜色
DATA: COLOR TYPE LVC_S_COLO.
START-OF-SELECTION.
SELECT * INTO TABLE ISPFLI FROM SPFLI.
CL_SALV_TABLE=>FACTORY( IMPORTING R_SALV_TABLE = GR_TABLE CHANGING T_TABLE = ISPFLI ).
"使用CL_SALV_FUNCTIONS添加工具栏
GR_FUNCTIONS = GR_TABLE->GET_FUNCTIONS( ).
GR_FUNCTIONS->SET_ALL( ABAP_TRUE ).
"添加标题
GR_DISPLAY = GR_TABLE->GET_DISPLAY_SETTINGS( ).
GR_DISPLAY->SET_STRIPED_PATTERN( CL_SALV_DISPLAY_SETTINGS=>TRUE ).
GR_DISPLAY->SET_LIST_HEADER( 'This is the heading' ).
"表格列样式
GR_COLUMNS = GR_TABLE->GET_COLUMNS( ).
* GR_COLUMN ?= GR_COLUMNS->GET_COLUMN( 'CITYTO' ).
* GR_COLUMN->SET_LONG_TEXT( 'This is long text' ).
* GR_COLUMN->SET_MEDIUM_TEXT( 'This is med text' ).
* GR_COLUMN->SET_SHORT_TEXT( 'This is sh' ).
GR_COLUMN ?= GR_COLUMNS->GET_COLUMN( 'CITYFROM' ).
COLOR-COL = '6'.
COLOR-INT = '1'.
COLOR-INV = '0'.
GR_COLUMN->SET_COLOR( COLOR ).
"排序
GR_SORTS = GR_TABLE->GET_SORTS( ).
" GR_SORTS->ADD_SORT( 'CITYTO' ).
"字段汇总
GR_SORTS->ADD_SORT( COLUMNNAME = 'CITYTO' SUBTOTAL = ABAP_TRUE ).
GR_AGG = GR_TABLE->GET_AGGREGATIONS( ).
GR_AGG->ADD_AGGREGATION( 'DISTANCE' ).
"过滤
GR_FILTER = GR_TABLE->GET_FILTERS( ).
GR_FILTER->ADD_FILTER( COLUMNNAME = 'CARRID' LOW = 'LH' ).
"增加变式保存
GR_LAYOUT = GR_TABLE->GET_LAYOUT( ).
KEY-REPORT = SY-REPID.
GR_LAYOUT->SET_KEY( KEY ).
GR_LAYOUT->SET_SAVE_RESTRICTION( CL_SALV_LAYOUT=>RESTRICT_NONE ).
GR_TABLE->DISPLAY( ).
SAP CL_SALV_TABLE 的用法学习记录
于 2024-05-08 10:24:01 首次发布