Windows系统IP地址自动切换

工作中，我们会经常遇到公司内部网络与家庭网络来回切换的需要。

解决方式有两种：

1. 方法一：在公司用有线连接；在家用无线连接。
2. 方式二：公司和居家都用有限连接，可以使用脚本手动切换，而不需要一步步去修改网络连接属性了。

   @echo off
   rem //设置变量 
   set NAME="以太网"
   rem //以下属性值可以根据需要更改(第一地址 IP) 
   set ADDR=xxx.xxx.xxx.xxx
   set MASK=xxx.xxx.xxx.xxx
   set GATEWAY=xxx.xxx.xxx.xxx
   set DNS1=xxx.xxx.xxx.xxx
   set DNS2=xxx.xxx.xxx.xxx
   rem //以上属性依次为IP地址、子网掩码、网关、首选DNS、备用DNS
   
   rem //以下为第二地址 IP 
   set HOME_DNS1=xxx.xxx.xxx.xxx
   set HOME_DNS2=xxx.xxx.xxx.xxx
   
   
   echo 当前可用操作有：
   echo 1 设置公司静态IP，静态DNS
   echo 2 设置本地动态IP，静态DNS
   echo 3 设置本地动态IP，动态DNS
   echo 4 退出
   echo 请选择后回车：
   set /p operate=
   if %operate%==1 goto 1
   if %operate%==2 goto 2
   if %operate%==3 goto 3
   if %operate%==4 goto 4
   
   
   :1
   echo 正在设置公司静态IP，静态DNS，请稍等...
   rem //可以根据你的需要更改 
   echo IP地址 = %ADDR%
   echo 掩码 = %MASK%
   echo 网关 = %GATEWAY%
   netsh interface ipv4 set address %NAME% static %ADDR% %MASK% %GATEWAY% 
   echo 首选DNS = %DNS1% 
   netsh interface ipv4 set dns %NAME% static %DNS1%
   echo 备用DNS = %DNS2% 
   if "%DNS2%"=="" (echo DNS2为空) else (netsh interface ipv4 add dns %NAME% %DNS2%) 
   echo 静态IP已设置！
   pause
   goto 4
   
   :2
   echo 正在本地动态IP，静态DNS，请稍等...
   echo 正在从DHCP自动获取IP地址...
   netsh interface ip set address %NAME% dhcp
   echo 动态IP已设置！
   echo 首选DNS = %HOME_DNS1% 
   netsh interface ipv4 set dns %NAME% static %HOME_DNS1%
   echo 备用DNS = %HOME_DNS2% 
   if "%DNS2%"=="" (echo DNS2为空) else (netsh interface ipv4 add dns %NAME% %HOME_DNS2%) 
   echo 静态DNS已设置！
   pause
   goto 4
   
   :3
   echo 正在设置本地动态IP，动态DNS，请稍等...
   echo 正在从DHCP自动获取IP地址...
   netsh interface ip set address %NAME% dhcp
   echo 动态IP已设置！
   echo 正在从DHCP自动获取DNS地址...
   netsh interface ip set dns %NAME% dhcp 
   echo 动态DNS已设置！
   pause
   goto 4
   
   
   :4
   echo 再见！
   exit

   复制以上脚本，在桌面新建文本文档，粘贴脚本，保存，并将文件后缀改.bat，双击脚本，根据需求，输入对应数字，回车即可
   

---

以上，请参考！