AutoHotkey常用脚本

概述

本文详细介绍了在工作中如何使用AutoHotkey编写常用快捷键脚本，包括按键语法、弹出快捷键提示、打开应用、复制文件路径、文本转换（大写、小写、驼峰式）以及窗口操作（置顶和取消置顶）等。

AutoHotkey 常用按键语法

 # ：WIN
 ! ：ALT
 ^ ：CTRL
 + ：SHIFT

常用快捷键

弹出快捷键提示

; 弹出快捷键提示
#!h:: ; WIN + ALT + H
{
  ; 帮助菜单
  MsgBox "
  (
    Notepad++：`t ALT + F9
    翻译软件:`t`t ALT + F10
    有道翻译:`t`t ALT + F11
    复制文件路径：`t CTRL + SHIFT + C
    文本转大写：`t WIN + ALT + Z
    文本转小写：`t WIN + ALT + X
    文本转驼峰：`t WIN + ALT + C
    置顶：`t`t WIN+ALT+T
    取消置顶：`t`t SHIFT+WIN+ALT+T
  )" , "AutoHotKey 快捷键"
  return
}

定义快捷键打开应用

/*
 * 打开notepad++
 * 快捷键：ALT + F9
 */
!F9::Run("E:\Software\Notepad++\notepad++.exe")

/*
 * 打开翻译软件
 * 快捷键：ALT + F10
 */
!F10::Run("`"C:\Program Files (x86)\Microsoft\Edge\Application\msedge_proxy.exe`" --profile-directory=Default --app-id=njekhmblbjhoamfegokofpacdcifbdgf --app-url=https://isfive.gitee.io/vite-programer/ --app-launch-source=4")

/*
 * 打开有道翻译软件
 * 快捷键：ALT + F11
 */
!F11::Run("`"C:\Program Files (x86)\Microsoft\Edge\Application\msedge_proxy.exe`"  --profile-directory=Default --app-id=lknjjlgmmnjgpbkjkoiefcpdokkeiijm --app-url=https://fanyi.youdao.com/indexLLM.html#/ --app-launch-source=4")

复制文件路径到剪贴板

/*
 * 复制文件路径到剪贴板
 * 快捷键：Ctrl + Shift + C
 */
^+c::
{
  Send("^c")
  Sleep(300)
  A_Clipboard := A_Clipboard
  ToolTip(A_Clipboard)
  Sleep(300)
  ToolTip()
  return
}

转换选中文本

选中文本大写

/*
 * 选中文本大写
 * 快捷键：WIN+ALT+Z
 */

#!z::
{
  ; 清空剪贴板
  A_Clipboard := ""
  Send("^c")
  Errorlevel := !ClipWait(2)
  if ErrorLevel
  {
      MsgBox("请选中文本，转换成大写！")
      return
  }
  str := A_Clipboard
  A_Clipboard:=StrUpper(str)
  Send("^v")
  return
}

选中文本小写

/*
 * 选中文本小写
 * 快捷键：WIN+ALT+X
 */
#!x::
{
  ; 清空剪贴板
  A_Clipboard := ""
  Send("^c")
  Errorlevel := !ClipWait(2)
  if ErrorLevel
  {
      MsgBox("请选中文本，转换成小写.")
      return
  }
  str := A_Clipboard
  A_Clipboard:=StrLower(str)
  Send("^v")
  return
}

选中文本驼峰

/*
 * 选中文本驼峰
 * 快捷键：WIN+ALT+C
 */
#!c::
{
  ; 获取并保存当前选中的文本
  A_Clipboard := ""  ; 清空剪贴板
  Send("^c")   ; 复制选中内容到剪贴板
  Errorlevel := !ClipWait(2)
  if ErrorLevel
  {
      MsgBox("请选中文本.")
      return
  }
  ; 从剪贴板获取文本
  SelectedText := A_Clipboard
  MsgBox(SelectedText)
  ; 将选中内容转换为驼峰形式
  CamelCaseText := CamelCase(SelectedText)

  ; 将转换后的文本放回剪贴板
  A_Clipboard := CamelCaseText

  ; 粘贴转换后的文本
  Send("^v")
  return
}

; 定义一个函数，将字符串转换为 camelCase 格式
CamelCase(str) {
    str := RegExReplace(str, "[_-]", " ")  ;
    MsgBox(str)
    str := StrLower(str)  ; 将字符串转为小写
    words := StrSplit(str, " ")  ; 将字符串按空格分割为单词数组

    ; 遍历每个单词，将其首字母大写
    result := ""
    Loop words.Length
    {
        word := words[A_Index]
        if (A_Index = 1) {
            result .= word
        } else {
            firstChar := SubStr(word, 1, 1)
            capitalizedFirstChar := StrUpper(firstChar)
            restOfWord := SubStr(word, 2)
            result .= capitalizedFirstChar . restOfWord
        }
    }

    ; 返回驼峰形式的字符串
    return result
}

窗口操作

置顶

/*
 * 置顶
 * 快捷键：WIN+ALT+T
 */
#!t::
{
  WinSetAlwaysOnTop 1, "A"  ; 设置当前活动窗口始终置顶
  ToolTip "置顶成功"
  SetTimer () => ToolTip(), 1000
  return
}

取消置顶

/*
 * 取消置顶
 * 快捷键：SHIFT+WIN+ALT+T
 */
+#!t::
{
  WinSetAlwaysOnTop 0, "A"  ; 设置当前活动窗口始终置顶
  ToolTip "取消置顶"
  SetTimer () => ToolTip(), 1000
  return
}