实验内容
改写 bootsect.s 主要完成如下功能：
- bootsect.s 能在屏幕上打印一段提示信息“XXX is booting…”，其中 XXX 是你给自己的操作系统起的名字，例如 LZJos、Sunix 等（可以上论坛上秀秀谁的 OS 名字最帅，也可以显示一个特色 logo，以表示自己操作系统的与众不同。）
改写 setup.s 主要完成如下功能：
- bootsect.s 能完成 setup.s 的载入，并跳转到 setup.s 开始地址执行。而 setup.s 向屏幕输出一行"Now we are in SETUP"。
- setup.s 能获取至少一个基本的硬件参数（如内存参数、显卡参数、硬盘参数等），将其存放在内存的特定地址，并输出到屏幕上。
- setup.s 不再加载 Linux 内核，保持上述信息显示在屏幕上即可。
基础知识
引导程序有BIOS加载并运行。引导程序运行的时候操作系统还不存在，整台计算机的资源目前都有BIOS掌控，能利用的功能就是BIOS中断。
首先介绍一下Linux操作系统的启动费部分：
1、当电源通电后，80x86结构的CPU地址将自动进入实模式，并将地址0XFFFF0开始自动执行程序代码，这个地址通常是ROM-BIOS中的地址。
PC机的BIOS将执行某些系统的检测，并在物理地址0处初始化中断向量。此后，他将可启动设备的第一个扇区读入内存地址0x7c00,并且跳转到这个地方。Linux最前面的代码（boot/bootsect.s）它将由BIOS读入到内存绝对地址0x7c00处，当这个程序执行的时候会把自己移动到0x9000处，并且把setup.s的代码读入到0x90200处，内核处system的代码读入到0x10000处。如下图所示。
system模块的长度不会超过0x80000字节大小（512kb），所以bootsect程序把system模块读入物理地址0x10000开始位置处时并不会覆盖在0x90000处开始的bootset和setup模块。后面的setup程序会把system模块移动到物理内存起始的位置，这样system模块的代码的起始地址就是实际的物理地址。下图显示出linux系统启动时的位置。
之所以不直接把系统模块加载到物理地址0x0000开始处，而要在setup中在进行移动，因为setup程序需要bios中断来获取机器的参数。BIOS中断的中断向量表会初始化在物理地址为0处。
实验步骤
bootsect.s显示
1、解压缩进入boot目录，我们第一个小的实验就是要修改bootsect.s中的代码
修改bootsect.s的代码如下：
! 首先读入光标位置
mov ah,#0x03
xor bh,bh
int 0x10
! 显示字符串 “Hello OS world, my name is ZY”
! 要显示的字符串长度
mov cx,#35 ！这里要改一下字符串的个数
mov bx,#0x0007
mov bp,#msg1
! es:bp 是显示字符串的地址
! 相比与 linux-0.11 中的代码，需要增加对 es 的处理，因为原代码中在输出之前已经处理了 es
mov ax,#0x07c0
mov es,ax
mov ax,#0x1301
int 0x10
! 设置一个无限循环
inf_loop:
jmp inf_loop
! msg1 处放置字符串
msg1:
!统计要显示的字符串的个数
! 换行 + 回车
.byte 13,10
.ascii "Hello OS world, my name is ZY"//29个加上换行和回车就是35个。
! 两对换行 + 回车
.byte 13,10,13,10
! boot_flag 必须在最后两个字节
.org 510
! 设置引导扇区标记 0xAA55
! 必须有它，才能引导
boot_flag:
.word 0xAA55
2、进行编译
进入 boot/目录下：执行如下两个命令，执行之后如果没有多余的显示说明成功
as86 -0 -a -o bootsect.o bootsect.s
ld86 -0 -s -o bootsect bootsect.o
使用命令 ls -l查看文件的大小
发现bootset目标文件是544个字节。而第一个扇区是512的字节，所以我们要对bootsect进行裁剪，造成多了32个字节的原因是ld86产生的是Minix可执行文件，包含Minix可执行文件头部，具体结构如下
struct exec {
unsigned char a_magic[2]; //执行文件魔数
unsigned char a_flags;
unsigned char a_cpu; //CPU标识号
unsigned char a_hdrlen; //头部长度，32字节或48字节
unsigned char a_unused;
unsigned short a_version;
long a_text; long a_data; long a_bss; //代码段长度、数据段长度、堆长度
long a_entry; //执行入口地址
long a_total; //分配的内存总量
long a_syms; //符号表大小
};
算一算：6 char（6 字节）+ 1 short（2 字节） + 6 long（24 字节）= 32，正好是 32 个字节，去掉这 32 个字节后就可以放入引导扇区了
执行如下命令对目标文件进行裁剪：
d bs=1 if=bootsect of=Image skip=32
生成的 Image 就是去掉文件头的 bootsect。
３、将刚刚生成的 Image 复制到 linux-0.11 目录下
cp ./Image ../Image
4、回到oslab目录执行
./run
## setup.s显示
1、首先需要编写setup.s程序，然后显示信息是“Now we are in SETUP”，修改setup.s如下
entry _start
-start:
! 首先读入光标位置
mov ah,#0x03
xor bh,bh
int 0x10
! 显示字符串 “Hello OS world, my name is ZY”
! 要显示的字符串长度
mov cx,#28 ！这里要改一下字符串的个数
mov bx,#0x0007
mov bp,#msg2
! es:bp 是显示字符串的地址
! 相比与 linux-0.11 中的代码，需要增加对 es 的处理，因为原代码中在输出之前已经处理了 es
mov ax,#cs
mov es,ax
mov ax,#0x1301
int 0x10
! 设置一个无限循环
inf_loop:
jmp inf_loop
! msg2 处放置字符串
msg2:
!统计要显示的字符串的个数
! 换行 + 回车
.byte 13,10
.ascii "Now we are in SETUP zY"//22个加上换行和回车就是28个。
! 两对换行 + 回车
.byte 13,10,13,10
! boot_flag 必须在最后两个字节
.org 510
! 设置引导扇区标记 0xAA55
! 必须有它，才能引导
boot_flag:
.word 0xAA55
2、接下来编写bootset.s代码
SETUPLEN=2
SETUPSEG=0x07e0
entry _start
_start:
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#35!显示字符的个数
mov bx,#0x0007
mov bp,#msg1 ！显示字符串
mov ax,#0x07c0
mov es,ax
mov ax,#0x1301
int 0x10
load_setup:！读入setup
！设置驱动器和磁头(drive 0, head 0): 软盘 0 磁头
mov dx,#0x0000
! 设置扇区号和磁道(sector 2, track 0): 0 磁头、0 磁道、2 扇区
mov cx,#0x0002
! 设置读入的内存地址：BOOTSEG+address = 512，偏移512字节
mov bx,#0x0200
! 设置读入的扇区个数(service 2, nr of sectors)，
! SETUPLEN是读入的扇区个数，Linux 0.11 设置的是 4，
! 我们不需要那么多，我们设置为 2（因此还需要添加变量 SETUPLEN=2）
mov ax,#0x0200+SETUPLEN
! 应用 0x13 号 BIOS 中断读入 2 个 setup.s扇区
int 0x13
! 读入成功，跳转到 ok_load_setup: ok - continue
jnc ok_load_setup
! 软驱、软盘有问题才会执行到这里。
mov dx,#0x0000
mov ax,#0x0000
int 0x13
! 重新循环，再次尝试读取
jmp load_setup
! 接下来要干什么？当然是跳到 setup 执行。
! 要注意：我们没有将 bootsect 移到 0x9000，因此跳转后的段地址应该是 0x7ce0
! 即我们要设置 SETUPSEG=0x07e0
ok_load_setup:
jmpi 0,SETUPSEG
msg1:
.byte 13,10
.ascii "Hello OS world, my name is ZY"
.byte 13,10,13,10
.org 510
boot_flag:
.word 0xAA55
3、编译
修改完成之后进入Linux-0,1目录执行
make BootImage
出现错误
有 Error！这是因为 make 根据 Makefile 的指引执行了 tools/build.c，它是为生成整个内核的镜像文件而设计的，没考虑我们只需要 bootsect.s 和 setup.s 的情况。它在向我们要 “系统” 的核心代码。为完成实验，接下来给它打个小补丁。
4、修改build.c
在toolS目录下修改build.c
注释掉相应的代码
编译
$ cd ~/oslab/linux-0.11
$ make BootImage
$ ../run
setup 显示系统的参数
etup.s 将获得硬件参数放在内存的 0x90000 处。原版 setup.s 中已经完成了光标位置、内存大小、显存大小、显卡参数、第一和第二硬盘参数的保存。
用 ah=#0x03 调用 0x10 中断可以读出光标的位置，用 ah=#0x88 调用 0x15 中断可以读出内存的大小。
有些硬件参数的获取要稍微复杂一些，如磁盘参数表。在 PC 机中 BIOS 设定的中断向量表中 int 0x41 的中断向量位置(4*0x41 = 0x0000:0x0104)存放的并不是中断程序的地址，而是第一个硬盘的基本参数表。
第二个硬盘的基本参数表入口地址存于 int 0x46 中断向量位置处。每个硬盘参数表有 16 个字节大小。
所以获得磁盘参数的方法就是复制数据。
下面是将硬件参数取出来放在内存 0x90000 的关键代码。
mov ax,#INITSEG
! 设置 ds = 0x9000
mov ds,ax
mov ah,#0x03
! 读入光标位置
xor bh,bh
! 调用 0x10 中断
int 0x10
! 将光标位置写入 0x90000.
mov [0],dx
! 读入内存大小位置
mov ah,#0x88
int 0x15
mov [2],ax
! 从 0x41 处拷贝 16 个字节（磁盘参数表）
mov ax,#0x0000
mov ds,ax !将数据段移动到0x0000的地方 也就是ram的开始位置
!LDS DI,[BX]指令的功能是把BX所指的32位地址指针的段地址送入DS,偏移地址送入DI.
!再回过头看lds si ，[4*0x41]；将4*0x41和4*0x41+1内存地址的内容复制到si寄存器，将4*0x41+2和4*0x41+3内存地址的内容复制
!到ds寄存器。实际上最终的硬盘参数表的地址为DS：SI=0x9fc0:0x003d!这也是为什么将system复制到0x10000地址处的原因。
!在0x9fc03地址处存放的就是硬盘参数，占用16字节。这块内容后面分析调试技巧的时候会专门再确认。
lds si,[4*0x41]
mov ax,#INITSEG
mov es,ax
mov di,#0x0004
mov cx,#0x10
! 重复16次
rep
movsb
! 以 16 进制方式打印栈顶的16位数
print_hex:
! 4 个十六进制数字
mov cx,#4
! 将(bp)所指的值放入 dx 中，如果 bp 是指向栈顶的话
mov dx,(bp)
print_digit:
! 循环以使低 4 比特用上 !! 取 dx 的高 4 比特移到低 4 比特处。
rol dx,#4
! ah = 请求的功能值，al = 半字节(4 个比特)掩码。
mov ax,#0xe0f
! 取 dl 的低 4 比特值。
and al,dl
! 给 al 数字加上十六进制 0x30
add al,#0x30
cmp al,#0x3a
! 是一个不大于十的数字
jl outp
! 是a～f，要多加 7
add al,#0x07
outp:
int 0x10
loop print_digit
ret
! 这里用到了一个 loop 指令;
! 每次执行 loop 指令，cx 减 1，然后判断 cx 是否等于 0。
! 如果不为 0 则转移到 loop 指令后的标号处，实现循环；
! 如果为0顺序执行。
!
! 另外还有一个非常相似的指令：rep 指令，
! 每次执行 rep 指令，cx 减 1，然后判断 cx 是否等于 0。
！ 如果不为 0 则继续执行 rep 指令后的串操作指令，直到 cx 为 0，实现重复。
! 打印回车换行
print_nl:
! CR
mov ax,#0xe0d
int 0x10
! LF
mov al,#0xa
int 0x10
ret
修改setup.s文件如下：
INITSEG = 0x9000
entry _start
_start:
! Print "NOW we are in SETUP"
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#25
mov bx,#0x0007
mov bp,#msg2
mov ax,cs
mov es,ax
mov ax,#0x1301
int 0x10
mov ax,cs
mov es,ax
! init ss:sp
mov ax,#INITSEG
mov ss,ax
mov sp,#0xFF00
! Get Params
mov ax,#INITSEG
mov ds,ax
mov ah,#0x03
xor bh,bh
int 0x10
mov [0],dx
mov ah,#0x88
int 0x15
mov [2],ax
mov ax,#0x0000
mov ds,ax
lds si,[4*0x41]
mov ax,#INITSEG
mov es,ax
mov di,#0x0004
mov cx,#0x10
rep
movsb
! Be Ready to Print
mov ax,cs
mov es,ax
mov ax,#INITSEG
mov ds,ax
! Cursor Position
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#18
mov bx,#0x0007
mov bp,#msg_cursor
mov ax,#0x1301
int 0x10
mov dx,[0]
call print_hex
! Memory Size
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#14
mov bx,#0x0007
mov bp,#msg_memory
mov ax,#0x1301
int 0x10
mov dx,[2]
call print_hex
! Add KB
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#2
mov bx,#0x0007
mov bp,#msg_kb
mov ax,#0x1301
int 0x10
! Cyles
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#7
mov bx,#0x0007
mov bp,#msg_cyles
mov ax,#0x1301
int 0x10
mov dx,[4]
call print_hex
! Heads
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#8
mov bx,#0x0007
mov bp,#msg_heads
mov ax,#0x1301
int 0x10
mov dx,[6]
call print_hex
! Secotrs
mov ah,#0x03
xor bh,bh
int 0x10
mov cx,#10
mov bx,#0x0007
mov bp,#msg_sectors
mov ax,#0x1301
int 0x10
mov dx,[12]
call print_hex
inf_loop:
jmp inf_loop
print_hex:
mov cx,#4
print_digit:
rol dx,#4
mov ax,#0xe0f
and al,dl
add al,#0x30
cmp al,#0x3a
jl outp
add al,#0x07
outp:
int 0x10
loop print_digit
ret
print_nl:
mov ax,#0xe0d ! CR
int 0x10
mov al,#0xa ! LF
int 0x10
ret
msg2:
.byte 13,10
.ascii "NOW we are in SETUP"
.byte 13,10,13,10
msg_cursor:
.byte 13,10
.ascii "Cursor position:"
msg_memory:
.byte 13,10
.ascii "Memory Size:"
msg_cyles:
.byte 13,10
.ascii "Cyls:"
msg_heads:
.byte 13,10
.ascii "Heads:"
msg_sectors:
.byte 13,10
.ascii "Sectors:"
msg_kb:
.ascii "KB"
.org 510
boot_flag:
.word 0xAA55
执行
$ cd ~/oslab/linux-0.11
$ make BootImage
$ ../run
扫一扫
4492
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
