c语言isnumber函数的使用方法,[转载]ISNUMBER函数详解_Excel公式教程

【语法】ISNUMBER(value)

检测一个数值是否数字值，是则返回TRUE，否则返回FALSE。

Value 必需。待检测的数值，可以是任意类型的单值。

可用TYPE函数代替ISNUMBER函数，ISNUMBER(value)可写成TYPE(value)=1。

【用法】

一、参数value可以是一个单元格引用；检测该单元格的值是不是数字值。

如果单元格为空，ISNUMBER函数返回FALSE。

(一)用于数据有效性。

例如，要限制单元格A1中只能输入数字值，可先定位到单元格A1，然后打开“数据有效性”对话框，在“设置”选项卡“允许”下面的下拉菜单中选择“自定义”，在“公式”输入框中输入以下公式：

=ISNUMBER(A1)

(二)用于条件格式。

例如，当单元格A1是数字值时，显示为特定的格式，可设置以下条件格式公式：

=ISNUMBER(A1)

与自定义格式代码比较，条件格式可以给单元格指定更多的格式，比如可以指定字体颜色和背景色、字形字号、下划线、删除线、上下标、边框线等；另外，条件格式可以检测当前单元格以外的其他单元格。

(三)用于函数中的逻辑值参数

例如，以下公式，当B1、D1、F1三个单元格都输入了数字值，则返回“通过”，否则返回“请完善”：

=IF(AND(ISNUMBER(B1),ISNUMBER(D1),ISNUMBER(F1)),"通过","请完善")

二、参数value可以是一个嵌套的文本查找函数；检测该函数能否找到指定的文本。

文本查找函数(FIND、FINDB、SEARCH、SEARCHB)如果找到指定文本，将返回数字值来表示找到的位置，否则返回错误值#VALUE!。

(一)用于条件格式。如果单元格包含指定的特征文本，则以特殊格式显示。

1、单元格A1如果包含文本“海尔”，则以高亮显示。可在A1条件格式设置以下公式及高亮格式：

=ISNUMBER(FIND("海尔",A1))

其实这个公式可以简写成：

=FIND("海尔",A1)

2、单元格A1如果包含文本“海尔”或“美的”，则以粗体显示。可在A1条件格式设置以下公式及粗体格式：

=OR(ISNUMBER(FIND("海尔",A1)),ISNUMBER(FIND("美的",A1))) 或

=ISNUMBER(FIND("海尔",A1))+ISNUMBER(FIND("美的",A1))

3、把特征文本“海尔”“美的”“松下”放在单元格C1:C3，单元格A1如果包含这些文本，则以斜体显示。可在A1条件格式设置以下公式及斜体格式：

=OR(ISNUMBER(FIND(C$1:C$3,A1)))

4、把特征文本以数组常量的形式指定给一个名称，例如创建一个名称TZZ，其引用位置的公式为={"海尔","美的","松下"}。当单元格A1包含特征文本时以红色显示。可在A1条件格式设置以下公式及红色字体：

=OR(ISNUMBER(FIND(TZZ,A1)))

由于条件格式公式不能直接使用数组常量，所以这里借助了名称来间接使用数组常量。

(二)对包含特征文本的行求和。如图：

对“海尔”牌家电的销量求和，公式如下：

=SUMPRODUCT(ISNUMBER(FIND("海尔",A2:A7))*B2:B7) 或

=SUMIF(A2:A7,"*海尔*",B2:B7)

对“海尔”“三洋”牌家电的销量求和，公式如下：

=SUMPRODUCT(ISNUMBER(FIND({"海尔","三洋"},A2:A7))*B2:B7) 或

=SUM(SUMIF(A2:A7,{"*海尔*","*三洋*"},B2:B7)) 或

{=SUMPRODUCT(ISNUMBER(FIND(TRANSPOSE(D2:D3),A2:A7))*B2:B7)} 或

{=SUM(SUMIF(A2:A7,"*"&D2:D3&"*",B2:B7))}

三、参数value可以是一个嵌套的MATCH函数；检测MATCH函数能否找到指定的值。

(一)如果单元格的值在某列表中找得到，则以特殊格式显示。

如图。如果单元格A1的值在B列中找得到，则A1以红底高亮显示。可在A1条件格式设置以下公式及红色底纹：

=ISNUMBER(MATCH(A1,$B:$B,))

其实这个公式可以简写成：

=MATCH(A1,$B:$B,)

(二)对符合某些值的行求和。

如图。当A列的项目，在D列中出现时，对其B列的数字求和，公式如下：

=SUMPRODUCT(ISNUMBER(MATCH(A1:A6,D:D,))*B1:B6)