王爽《汇编语言》第四版 实验十六

建议理解并使用第一种方法，因为能简化课程设计2的设计

程序功能

安装一个 int 7ch 的中断例程，为显示输出提供如下功能子程序；

1. 清屏；

2. 设置前景色；

3. 设置背景色；

4. 向上滚动一行；

入口参数：(1)用ah传递功能号：分别是0、1、2、3；(2)对于1、2号功能，用al传递颜色值(al)从0~7取值；

程序结构

主程序（start开始）将 setscreen 放入0:200处

功能程序为 setscreen，包括 sub1, sub2, sub3, sub4 四个子功能程序

程序难点

由于 table 在编译后的地址偏移量会与start保持一致，当它被放入 0:200h 后，table的值不会相对变化，即table的偏移地址是相对于安装程序而不是中断例程

解决方法

方法一

在 setscreen 程序前加 org 200h，使得编译器将 setscreen 偏移量定为200h

方法一完整程序

 assume cs:code
 code segment
     start:  mov ax,0
             mov es,ax
             
             mov ax,cs
             mov ds,ax
 ​
             mov si,offset setscreen
             mov di,200h
             mov cx,offset setscend - offset setscreen
             cld 
             rep movsb       ;将子程序移动到0:200h处
             
             mov word ptr es:[4*7ch],200h
             mov word ptr es:[4*7ch+2],0 ;更新中断向量表
             
             mov ax,4c00h
             int 21h
 ​
     org 200h                    ;这里将setscreen的偏移量设置为200h
 ​
     setscreen:  
             jmp short set       ;two bytes
     
         table dw sub1,sub2,sub3,sub4
     
     set:    push bx
             cmp ah,3
             ja sret
             mov bl,ah
             mov bh,0
             add bx,bx               ;计算偏移量
             
             call word ptr table[bx] ;调用对应子程序
     
     sret:   pop bx
             iret
     
     ;清屏，将显存中当前屏幕中的字符设为空格符
     sub1:   push bx
             push cx
             push es
             
             mov bx,0b800h
             mov es,bx
             mov bx,0
             mov cx,2000
     sub1s:  mov byte ptr es:[bx],' '
             add bx,2
             loop sub1s
             
             pop es
             pop cx
             pop bx
             ret
             
     sub2:   push bx
             push cx
             push es
             
             mov bx,0b800h
             mov es,bx
             mov bx,1
             mov cx,2000
     sub2s:  and byte ptr es:[bx],11111000b
             or es:[bx],al
             add bx,2
             loop sub2s
     
             pop es
             pop cx
             pop bx
             ret
             
     sub3:   push bx
             push cx
             push es
             
             mov cl,4
             shl al,cl
             mov bx,0b800h
             mov es,bx
             mov bx,1
             mov cx,2000
     sub3s:  and byte ptr es:[bx],10001111b
             or es:[bx],al
             add bx,2
             loop sub3s
             
             pop es
             pop cx
             pop bx
             ret
             
     sub4:   push cx
             push si
             push di
             push es
             push ds
             
             mov si,0b800h
             mov es,si
             mov ds,si
             mov si,160
             mov di,0
             cld
             mov cx,24
     sub4s:  push cx
             mov cx,160
             rep movsb
             pop cx
             loop sub4s      ;向上滚动一行
             
             mov cx,80
             mov si,0
     sub4s1: mov byte ptr [160*24+si],' '
             add si,2
             loop sub4s1     ;最后一行清空
             
             pop ds
             pop es
             pop di
             pop si
             pop cx
             ret
     setscend:
             nop
 code ends
 end start

方法二

将table中内容变为相对中断例程的地址而不是安装程序的地址

table内容为：

table  dw offset sub1 - offset setscreen + 200h
       dw offset sub2 - offset setscreen + 200h
       dw offset sub3 - offset setscreen + 200h
       dw offset sub4 - offset setscreen + 200h

对应子程序的调用为：

再加一个 2 是因为 setscreen 开头 jmp short set 占两个字节

call word ptr cs:[bx + 200h + 2]

方法二完整程序

 assume cs:code
 code segment    
 setscreen:  jmp short set
     
     table dw offset sub1 - offset setscreen + 200h
           dw offset sub2 - offset setscreen + 200h
           dw offset sub3 - offset setscreen + 200h
           dw offset sub4 - offset setscreen + 200h
     
     set:    push bx
             cmp ah,3
             ja sret
             mov bl,ah
             mov bh,0
             add bx,bx               ;计算偏移量
             
             call word ptr cs:[bx+202h]  ;调用对应子程序
     
     sret:   pop bx
             iret
     
     ;清屏，将显存中当前屏幕中的字符设为空格符
     sub1:   push bx
             push cx
             push es
             
             mov bx,0b800h
             mov es,bx
             mov bx,0
             mov cx,2000
     sub1s:  mov byte ptr es:[bx],' '
             add bx,2
             loop sub1s
             
             pop es
             pop cx
             pop bx
             ret
             
     sub2:   push bx
             push cx
             push es
             
             mov bx,0b800h
             mov es,bx
             mov bx,1
             mov cx,2000
     sub2s:  and byte ptr es:[bx],11111000b
             or es:[bx],al
             add bx,2
             loop sub2s
     
             pop es
             pop cx
             pop bx
             ret
             
     sub3:   push bx
             push cx
             push es
             
             mov cl,4
             shl al,cl
             mov bx,0b800h
             mov es,bx
             mov bx,1
             mov cx,2000
     sub3s:  and byte ptr es:[bx],10001111b
             or es:[bx],al
             add bx,2
             loop sub3s
             
             pop es
             pop cx
             pop bx
             ret
             
     sub4:   push cx
             push si
             push di
             push es
             push ds
             
             mov si,0b800h
             mov es,si
             mov ds,si
             mov si,160
             mov di,0
             cld
             mov cx,24
     sub4s:  push cx
             mov cx,160
             rep movsb
             pop cx
             loop sub4s      ;向上滚动一行
             
             mov cx,80
             mov si,0
     sub4s1: mov byte ptr [160*24+si],' '
             add si,2
             loop sub4s1     ;最后一行清空
             
             pop ds
             pop es
             pop di
             pop si
             pop cx
             ret
 setscend:   nop
 ​
     start:  mov ax,0
             mov es,ax
             
             mov ax,cs
             mov ds,ax
 ​
             mov si,offset setscreen
             mov di,200h
             mov cx,offset setscend - offset setscreen
             cld 
             rep movsb       ;将子程序移动到0:200h处
             
             mov word ptr es:[4*7ch],200h
             mov word ptr es:[4*7ch+2],0 ;更新中断向量表
             
             mov ax,4c00h
             int 21h
 code ends
 end start