ABAP BAPI_GOODSMVT_CREATE MIGO使用汇总

你不是你、

已于 2024-03-13 13:56:15 修改

阅读量509

点赞数 10

分类专栏： ABAP 文章标签：开发语言

于 2024-03-13 13:55:18 首次发布

本文链接：https://blog.csdn.net/weixin_42510881/article/details/136670265

版权

ABAP 专栏收录该内容

6 篇文章 0 订阅

订阅专栏

文章目录

一、GM_CODE
二、封装BAPI_GOODSMVT_CREATE
二、调用场景

提示：以下是本篇文章正文内容，下面案例可供参考

一、GM_CODE

GM_CODE	TCODE
01	MB01
02	MB31
03	MB1A
04	MB1B
05	MB1C
06	MB11
07	MB04

二、封装BAPI_GOODSMVT_CREATE

抬头数据结构
行项目1
行项目2
行项目3

FUNCTION z_mm_goodsmvt_create.
*"----------------------------------------------------------------------
*"*"本地接口：
*"  IMPORTING
*"     REFERENCE(IS_HEADER) TYPE  ZMMS019_HEADER
*"     REFERENCE(IV_GM_CODE) TYPE  GM_CODE
*"     REFERENCE(IV_BWART) TYPE  BWART
*"     REFERENCE(IV_TEST) TYPE  BAPI2017_GM_GEN-TESTRUN DEFAULT SPACE
*"     REFERENCE(IV_COMMIT) TYPE  CHAR1 DEFAULT 'X'
*"  EXPORTING
*"     REFERENCE(ES_RET_DOC) TYPE  BAPI2017_GM_HEAD_RET
*"     REFERENCE(ES_MESSAGE) TYPE  ZBCS_DATA_STATUS
*"  TABLES
*"      IT_ITEM STRUCTURE  ZMMS019_ITEM
*"      ET_RETURN STRUCTURE  BAPIRET2 OPTIONAL
*"      IT_EXTENSIONIN STRUCTURE  BAPIPAREX OPTIONAL
*"----------------------------------------------------------------------

  DATA:ls_goodsmvt_header  TYPE bapi2017_gm_head_01,
       lv_goodsmvt_code    TYPE bapi2017_gm_code,
       ls_goodsmvt_item    TYPE bapi2017_gm_item_create,
       ls_item             TYPE zmms019_item,
       lt_goodsmvt_item    TYPE tab_bapi_goodsmvt_item,
       ls_return           TYPE bapiret2,
       lv_message          TYPE zbcs_data_status,
       ls_goodsmvt_headret TYPE bapi2017_gm_head_ret.

  MOVE-CORRESPONDING is_header TO ls_goodsmvt_header.

  IF ls_goodsmvt_header-pstng_date IS INITIAL .   "检查过账时间.
    ls_goodsmvt_header-pstng_date = sy-datum.
  ENDIF .

  IF ls_goodsmvt_header-doc_date IS INITIAL .   "检查文档创建时间
    ls_goodsmvt_header-doc_date =  sy-datum.
  ENDIF.

  lv_goodsmvt_code-gm_code  =  iv_gm_code.

  LOOP AT it_item INTO ls_item.
    MOVE-CORRESPONDING ls_item TO ls_goodsmvt_item.
    IF ls_goodsmvt_item-move_type IS INITIAL.
      ls_goodsmvt_item-move_type  = iv_bwart.              "移动类型.
    ENDIF.
    APPEND ls_goodsmvt_item TO lt_goodsmvt_item.
    CLEAR ls_goodsmvt_item.
  ENDLOOP.
  
  CALL FUNCTION 'BAPI_GOODSMVT_CREATE'
    EXPORTING
      goodsmvt_header  = ls_goodsmvt_header
      goodsmvt_code    = lv_goodsmvt_code
      testrun          = iv_test
    IMPORTING
      goodsmvt_headret = ls_goodsmvt_headret
    TABLES
      goodsmvt_item    = lt_goodsmvt_item
      extensionin      = it_extensionin
      return           = et_return.

  LOOP AT et_return INTO ls_return WHERE type CA zif_bc_cons=>cns_aex.
    lv_message-status = zif_bc_cons=>cns_e.
    CONCATENATE lv_message-msgtxt ls_return-message INTO lv_message-msgtxt.
  ENDLOOP.
  
  IF lv_message-status = zif_bc_cons=>cns_e OR iv_test = zif_bc_cons=>cns_x .
    CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
    es_message = lv_message.
  ELSE.
    IF iv_commit = zif_bc_cons=>cns_x .
      CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
        EXPORTING
          wait = zif_bc_cons=>cns_x.    "X
      es_message-status = zif_bc_cons=>cns_s.              "'S'.
      MESSAGE s026(zmm_msg001) INTO  es_message-msgtxt . "'过账成功'.
      es_ret_doc = ls_goodsmvt_headret .
    ENDIF.
  ENDIF.
ENDFUNCTION.

二、调用场景

1.采购入库（101）、采购退货（161）

  CONSTANTS: CNS_GM_CODE_01 TYPE C LENGTH 2 VALUE '01' .

  DATA: LS_RETURN_STATUS TYPE ZBCS_DATA_STATUS .

  DATA:LS_DOC    TYPE BAPI2017_GM_HEAD_RET,
       LS_HEADER TYPE ZMMS019_HEADER,
       LS_ITEM   TYPE ZMMS019_ITEM,
       LT_ITEM   TYPE TABLE OF ZMMS019_ITEM.

  DATA: LT_RETURN TYPE STANDARD TABLE OF BAPIRET2,
        LS_RETURN TYPE BAPIRET2.
  
    LS_ITEM-PO_NUMBER     = LS_ITS_DATA-EBELN."采购订单
    LS_ITEM-PO_ITEM       = LS_ITS_DATA-EBELP."订单行项目
    LS_ITEM-DELIV_NUMB_TO_SEARCH    = LS_ITS_DATA-VBELN ."交货单
    LS_ITEM-DELIV_ITEM_TO_SEARCH    = LS_ITS_DATA-POSNR ."交货行项目
    LS_ITEM-MATERIAL      = LS_ITS_DATA-MATNR ."物料
    LS_ITEM-PLANT         = LS_ITS_DATA-WERKS ."工厂
    LS_ITEM-STGE_LOC      = LS_ITS_DATA-LGORT ."库存地点
    LS_ITEM-BATCH         = LS_ITS_DATA-CHARG ."批次
    LS_ITEM-ENTRY_QNT     = LS_ITS_DATA-SHL ."数量
    LS_ITEM-ENTRY_UOM     = LS_ITS_DATA-MEINS ."单位
    LS_ITEM-ENTRY_UOM_ISO = LS_ITS_DATA-MEINS ."单位
    LS_ITEM-MOVE_TYPE     = CNS_BWART_101."移动类型
    LS_ITEM-MVT_IND       = ZIF_BC_CONS=>CNS_B."移动标识  B采购收货  F生产收货
    LS_ITEM-SPEC_STOCK    = LS_ITS_DATA-SOBKZ."特殊库存标识
    LS_ITEM-PROD_DATE     = LS_ITS_DATA-SCRQ."制造日期
    LS_ITEM-PO_PR_QNT     = LS_ITS_DATA-JJSL."计价数量
    LS_ITEM-ORDERPR_UN    =  LS_ITS_DATA-BPRME."计价单位
    APPEND LS_ITEM TO LT_ITEM.    

    LS_HEADER-PSTNG_DATE = SY-DATUM . "过账日期
    LS_HEADER-DOC_DATE   = SY-DATUM . "凭证日期
    LS_HEADER-PR_UNAME   = SY-UNAME . "用户名
    LS_HEADER-REF_DOC_NO = LS_ITS_DATA-EBELN.  "凭证编号  

	  CALL FUNCTION 'Z_MM_GOODSMVT_CREATE'
	    EXPORTING
	      IS_HEADER  = LS_HEADER
	      IV_GM_CODE = CNS_GM_CODE_01
	      IV_BWART   = CNS_BWART_101 "采购退货仅修改CNS_BWART_161
	      IV_TEST    = UV_TEST
	    IMPORTING
	      ES_RET_DOC = LS_DOC
	      ES_MESSAGE = CS_RETURN
	    TABLES
	      IT_ITEM    = LT_ITEM
	      ET_RETURN  = LT_RETURN.

2.库存转移（311、411）

  CONSTANTS: CNS_GM_CODE_04 TYPE C LENGTH 2 VALUE '04' .

  DATA: LS_RETURN_STATUS TYPE ZBCS_DATA_STATUS .

  DATA:LS_DOC    TYPE BAPI2017_GM_HEAD_RET,
       LS_HEADER TYPE ZMMS019_HEADER,
       LS_ITEM   TYPE ZMMS019_ITEM,
       LT_ITEM   TYPE TABLE OF ZMMS019_ITEM.

  DATA: LT_RETURN TYPE STANDARD TABLE OF BAPIRET2,
        LS_RETURN TYPE BAPIRET2.
    
    LS_HEADER-PSTNG_DATE = SY-DATUM.
    LS_HEADER-DOC_DATE = SY-DATUM.    
  
    LS_ITEM-RESERV_NO     = LS_ITS_DATA-RSNUM."预留单号
    LS_ITEM-RES_ITEM      = LS_ITS_DATA-RSPOS."预留单行项
    LS_ITEM-MATERIAL      = LS_ITS_DATA-MATNR ."物料
    LS_ITEM-PLANT         = LS_ITS_DATA-WERKS ."工厂
    LS_ITEM-STGE_LOC      = LS_ITS_DATA-LGORT ."库存地点
    LS_ITEM-BATCH         = LS_ITS_DATA-CHARG ."批次
    LS_ITEM-ENTRY_QNT     = LS_ITS_DATA-SHL ."数量
    LS_ITEM-ENTRY_UOM     = LS_ITS_DATA-MEINS ."单位
    LS_ITEM-MOVE_TYPE     = CNS_BWART_311."移动类型
    LS_ITEM-SPEC_STOCK    = LS_ITS_DATA-SOBKZ."特殊库存标识
    LS_ITEM-CUSTOMER      = LS_ITS_DATA-KUNNR."客户编号
    LS_ITEM-MOVE_PLANT    = LS_ITS_DATA-UMWRK."收货工厂/发货工厂
    LS_ITEM-MOVE_STLOC    = LS_ITS_DATA-UMLGO."收货/发货库存地点
    LS_ITEM-MOVE_BATCH    = LS_ITS_DATA-CHARG.   "收货/发货批次
    APPEND LS_ITEM TO LT_ITEM.      

	  CALL FUNCTION 'Z_MM_GOODSMVT_CREATE'
	    EXPORTING
	      IS_HEADER  = LS_HEADER
	      IV_GM_CODE = CNS_GM_CODE_04
	      IV_BWART   = CNS_BWART_101
	      IV_TEST    = UV_TEST
	    IMPORTING
	      ES_RET_DOC = LS_DOC
	      ES_MESSAGE = CS_RETURN
	    TABLES
	      IT_ITEM    = LT_ITEM
	      ET_RETURN  = LT_RETURN.

3.成本中心领料（Z01）

  CONSTANTS: CNS_GM_CODE_03 TYPE C LENGTH 2 VALUE '03' .

  DATA: LS_RETURN_STATUS TYPE ZBCS_DATA_STATUS .

  DATA:LS_DOC    TYPE BAPI2017_GM_HEAD_RET,
       LS_HEADER TYPE ZMMS019_HEADER,
       LS_ITEM   TYPE ZMMS019_ITEM,
       LT_ITEM   TYPE TABLE OF ZMMS019_ITEM.

  DATA: LT_RETURN TYPE STANDARD TABLE OF BAPIRET2,
        LS_RETURN TYPE BAPIRET2.
    
    LS_HEADER-PSTNG_DATE = SY-DATUM.
    LS_HEADER-DOC_DATE = SY-DATUM.    
  
    LS_ITEM-RESERV_NO     = LS_ITS_DATA-RSNUM."预留单号
    LS_ITEM-RES_ITEM      = LS_ITS_DATA-RSPOS."预留单行项
    LS_ITEM-MATERIAL      = LS_ITS_DATA-MATNR ."物料
    LS_ITEM-PLANT         = LS_ITS_DATA-WERKS ."工厂
    LS_ITEM-STGE_LOC      = LS_ITS_DATA-LGORT ."库存地点
    LS_ITEM-BATCH         = LS_ITS_DATA-CHARG ."批次
    LS_ITEM-ENTRY_QNT     = LS_ITS_DATA-SHL ."数量
    LS_ITEM-ENTRY_UOM     = LS_ITS_DATA-MEINS ."单位
    LS_ITEM-MOVE_TYPE     = CNS_BWART_Z01."移动类型
    LS_ITEM-SPEC_STOCK    = LS_ITS_DATA-SOBKZ."特殊库存标识
    LS_ITEM-CUSTOMER      = LS_ITS_DATA-KUNNR."客户编号
    LS_ITEM-MOVE_PLANT    = LS_ITS_DATA-UMWRK."收货工厂/发货工厂
    LS_ITEM-MOVE_STLOC    = LS_ITS_DATA-UMLGO."收货/发货库存地点
    LS_ITEM-COSTCENTER    = LS_ITS_DATA-KOSTL ."成本中心
    APPEND LS_ITEM TO LT_ITEM.      

	  CALL FUNCTION 'Z_MM_GOODSMVT_CREATE'
	    EXPORTING
	      IS_HEADER  = LS_HEADER
	      IV_GM_CODE = CNS_GM_CODE_03
	      IV_BWART   = CNS_BWART_Z01
	      IV_TEST    = UV_TEST
	    IMPORTING
	      ES_RET_DOC = LS_DOC
	      ES_MESSAGE = CS_RETURN
	    TABLES
	      IT_ITEM    = LT_ITEM
	      ET_RETURN  = LT_RETURN.

4.工单发料（261）、工单退料（262）

  CONSTANTS: CNS_GM_CODE_03 TYPE C LENGTH 2 VALUE '03' .
  CONSTANTS:CNS_STRUC TYPE TE_STRUC VALUE 'ZSMM_BAPI_XMSEG'.

  DATA: LS_RETURN_STATUS TYPE ZBCS_DATA_STATUS .

  DATA:LS_DOC    TYPE BAPI2017_GM_HEAD_RET,
       LS_HEADER TYPE ZMMS019_HEADER,
       LS_ITEM   TYPE ZMMS019_ITEM,
       LT_ITEM   TYPE TABLE OF ZMMS019_ITEM.

  DATA: LT_RETURN TYPE STANDARD TABLE OF BAPIRET2,
        LS_RETURN TYPE BAPIRET2.
    
    LS_HEADER-PSTNG_DATE = SY-DATUM.
    LS_HEADER-DOC_DATE   = SY-DATUM.    
    LS_HEADER-PR_UNAME   = SY-UNAME."用户名
    LS_HEADER-REF_DOC_NO = LS_ITS_DATA-AUFNR.  "凭证编号
  
  	IF GV_TECO = ABAP_FALSE."是否TECO
    	LS_ITEM-RESERV_NO     = LS_ITS_DATA-RSNUM."预留单号
    	LS_ITEM-RES_ITEM      = LS_ITS_DATA-RSPOS."预留单行项
    ENDIF.
    LS_ITEM-ORDERID       = LS_ITS_DATA-AUFNR."生产订单号
    LS_ITEM-MATERIAL      = LS_ITS_DATA-MATNR ."物料
    LS_ITEM-PLANT         = LS_ITS_DATA-WERKS ."工厂
    LS_ITEM-STGE_LOC      = LS_ITS_DATA-LGORT ."库存地点
    LS_ITEM-BATCH         = LS_ITS_DATA-CHARG ."批次
    LS_ITEM-ENTRY_QNT     = LS_ITS_DATA-SHL ."数量
    LS_ITEM-MOVE_TYPE     = CNS_BWART_261."移动类型
    LS_ITEM-XSTOB         = ZIF_BC_CONS=>CNS_X."非常重要，不然还是以移动类型261过账（262只增加此行）
    LS_ITEM-SPEC_STOCK    = LS_ITS_DATA-SOBKZ."特殊库存标识
    CASE LS_ITEM-SPEC_STOCK.
      WHEN ZIF_BC_CONS=>CNS_B.
        LS_ITEM-CUSTOMER = LS_ITS_DATA-KUNNR."客户的帐户编号
      WHEN ZIF_BC_CONS=>CNS_K.
        CLEAR: LS_ITEM-SPEC_STOCK . "特殊库存K 清空
      WHEN ZIF_BC_CONS=>CNS_E.
        LS_ITEM-SALES_ORD	= LS_ITS_DATA-VBELN."销售订单数
        LS_ITEM-S_ORD_ITEM  = LS_ITS_DATA-KDPOS."销售订单中的项目编号
    ENDCASE.
    APPEND LS_ITEM TO LT_ITEM.      
	
	CLEAR:LS_IMSEG.
    LS_IMSEG-LINE_ID = LV_LINE_ID.
    LS_IMSEG-ZZCXBH  = LS_ITS_DATA-ZCXBH."产线
    LS_IMSEG-ZZBZ    = LS_ITS_DATA-ZBZ  ."班组
    LS_IMSEG-ZZBC    = LS_ITS_DATA-ZBC  ."班次
    LS_IMSEG-ZZSCRQ  = LS_ITS_DATA-SCRQ. "生产日期

    CLEAR:LS_EXTENSIONIN.
    LS_EXTENSIONIN-STRUCTURE = CNS_STRUC.
    LS_EXTENSIONIN-VALUEPART1 = LS_IMSEG.
    APPEND LS_EXTENSIONIN TO LT_EXTENSIONIN.

	  CALL FUNCTION 'Z_MM_GOODSMVT_CREATE'
	    EXPORTING
	      IS_HEADER  = LS_HEADER
	      IV_GM_CODE = CNS_GM_CODE_03
	      IV_BWART   = CNS_BWART_261
	      IV_TEST    = UV_TEST
	    IMPORTING
	      ES_RET_DOC = LS_DOC
	      ES_MESSAGE = CS_RETURN
	    TABLES
	      IT_ITEM    = LT_ITEM
	      ET_RETURN  = LT_RETURN
          IT_EXTENSIONIN = LT_EXTENSIONIN.

5.报工入库（101）

  CONSTANTS: CNS_GM_CODE_02 TYPE C LENGTH 2 VALUE '02' ,
             CNS_STRUC TYPE TE_STRUC VALUE 'ZSMM_BAPI_XMSEG',
             CNS_MVT_IND_F  TYPE KZBEW VALUE 'F'.

  DATA: LS_RETURN_STATUS TYPE ZBCS_DATA_STATUS .

  DATA:LS_DOC    TYPE BAPI2017_GM_HEAD_RET,
       LS_HEADER TYPE ZMMS019_HEADER,
       LS_ITEM   TYPE ZMMS019_ITEM,
       LT_ITEM   TYPE TABLE OF ZMMS019_ITEM.

  DATA: LT_RETURN TYPE STANDARD TABLE OF BAPIRET2,
        LS_RETURN TYPE BAPIRET2.
    
    LS_HEADER-PSTNG_DATE = SY-DATUM.
    LS_HEADER-DOC_DATE   = SY-DATUM.    
    LS_HEADER-PR_UNAME   = SY-UNAME."用户名
    LS_HEADER-REF_DOC_NO = LS_ITS_DATA-AUFNR.  "凭证编号
  
    LS_ITEM-ORDERID       = LS_ITS_DATA-AUFNR."生产订单号
    LS_ITEM-MATERIAL      = LS_ITS_DATA-MATNR ."物料
    LS_ITEM-PLANT         = LS_ITS_DATA-WERKS ."工厂
    LS_ITEM-STGE_LOC      = LS_ITS_DATA-LGORT ."库存地点
    LS_ITEM-BATCH         = LS_ITS_DATA-CHARG ."批次
    LS_ITEM-ENTRY_QNT     = LS_ITS_DATA-SHL ."数量
    LS_ITEM-ENTRY_UOM     = LS_ITS_DATA-MEINS."单位
    LS_ITEM-MOVE_TYPE     = CNS_BWART_261."移动类型
    LS_ITEM-MVT_IND       = CNS_MVT_IND_F."移动标识  B采购收货  F生产收货
    LS_ITEM-SPEC_STOCK    = LS_ITS_DATA-SOBKZ."特殊库存标识
    CASE LS_ITEM-SPEC_STOCK.
      WHEN ZIF_BC_CONS=>CNS_E.
        LS_ITEM-SALES_ORD	= LS_ITS_DATA-VBELN."销售订单数
        LS_ITEM-S_ORD_ITEM  = LS_ITS_DATA-KDPOS."销售订单中的项目编号
    ENDCASE.
    APPEND LS_ITEM TO LT_ITEM.      
	
	CLEAR:LS_IMSEG.
    LS_IMSEG-LINE_ID = LV_LINE_ID.
    LS_IMSEG-ZZCXBH  = LS_ITS_DATA-ZCXBH."产线
    LS_IMSEG-ZZBZ    = LS_ITS_DATA-ZBZ  ."班组
    LS_IMSEG-ZZBC    = LS_ITS_DATA-ZBC  ."班次
    LS_IMSEG-ZZSCRQ  = LS_ITS_DATA-SCRQ. "生产日期

    CLEAR:LS_EXTENSIONIN.
    LS_EXTENSIONIN-STRUCTURE = CNS_STRUC.
    LS_EXTENSIONIN-VALUEPART1 = LS_IMSEG.
    APPEND LS_EXTENSIONIN TO LT_EXTENSIONIN.

	  CALL FUNCTION 'Z_MM_GOODSMVT_CREATE'
	    EXPORTING
	      IS_HEADER  = LS_HEADER
	      IV_GM_CODE = CNS_GM_CODE_02
	      IV_BWART   = CNS_BWART_101
	      IV_TEST    = UV_TEST
	    IMPORTING
	      ES_RET_DOC = LS_DOC
	      ES_MESSAGE = CS_RETURN
	    TABLES
	      IT_ITEM    = LT_ITEM
	      ET_RETURN  = LT_RETURN
          IT_EXTENSIONIN = LT_EXTENSIONIN.

6.委外发料（541）

  CONSTANTS: CNS_GM_CODE_04 TYPE C LENGTH 2 VALUE '04' .

  DATA: LS_RETURN_STATUS TYPE ZBCS_DATA_STATUS .

  DATA:LS_DOC    TYPE BAPI2017_GM_HEAD_RET,
       LS_HEADER TYPE ZMMS019_HEADER,
       LS_ITEM   TYPE ZMMS019_ITEM,
       LT_ITEM   TYPE TABLE OF ZMMS019_ITEM.

  DATA: LT_RETURN TYPE STANDARD TABLE OF BAPIRET2,
        LS_RETURN TYPE BAPIRET2.
    
    LS_HEADER-PSTNG_DATE = SY-DATUM.
    LS_HEADER-DOC_DATE = SY-DATUM.    
  
    LS_ITEM-MATERIAL      = LS_ITS_DATA-MATNR ."物料
    LS_ITEM-PLANT         = LS_ITS_DATA-WERKS ."工厂
    LS_ITEM-STGE_LOC      = LS_ITS_DATA-LGORT ."库存地点
    LS_ITEM-BATCH         = LS_ITS_DATA-CHARG ."批次
    LS_ITEM-ENTRY_QNT     = LS_ITS_DATA-SHL ."数量
    LS_ITEM-ENTRY_UOM     = LS_ITS_DATA-MEINS ."单位
    LS_ITEM-MOVE_TYPE     = CNS_BWART_541."移动类型
    LS_ITEM-PO_NUMBER     = LS_ITS_DATA-EBELN."采购订单号
    LS_ITEM-PO_ITEM       = LS_ITS_DATA-EBELP."订单行项
    LS_ITEM-VENDOR        = LS_ITS_DATA-LIFNR."供应商
    APPEND LS_ITEM TO LT_ITEM.      

	  CALL FUNCTION 'Z_MM_GOODSMVT_CREATE'
	    EXPORTING
	      IS_HEADER  = LS_HEADER
	      IV_GM_CODE = CNS_GM_CODE_04
	      IV_BWART   = CNS_BWART_541
	      IV_TEST    = UV_TEST
	    IMPORTING
	      ES_RET_DOC = LS_DOC
	      ES_MESSAGE = CS_RETURN
	    TABLES
	      IT_ITEM    = LT_ITEM
	      ET_RETURN  = LT_RETURN.

7.委外收货（543）

  CONSTANTS: CNS_GM_CODE_01 TYPE C LENGTH 2 VALUE '01' .

  DATA: LS_RETURN_STATUS TYPE ZBCS_DATA_STATUS .

  DATA:LS_DOC    TYPE BAPI2017_GM_HEAD_RET,
       LS_HEADER TYPE ZMMS019_HEADER,
       LS_ITEM   TYPE ZMMS019_ITEM,
       LT_ITEM   TYPE TABLE OF ZMMS019_ITEM.

  DATA: LT_RETURN TYPE STANDARD TABLE OF BAPIRET2,
        LS_RETURN TYPE BAPIRET2.
  
    LS_ITEM-PO_NUMBER     = LS_ITS_DATA-EBELN."采购订单
    LS_ITEM-PO_ITEM       = LS_ITS_DATA-EBELP."订单行项目
    LS_ITEM-MATERIAL      = LS_ITS_DATA-MATNR ."物料
    LS_ITEM-PLANT         = LS_ITS_DATA-WERKS ."工厂
    LS_ITEM-STGE_LOC      = LS_ITS_DATA-LGORT ."库存地点
    LS_ITEM-BATCH         = LS_ITS_DATA-CHARG ."批次
    LS_ITEM-ENTRY_QNT     = LS_ITS_DATA-SHL ."数量
    LS_ITEM-ENTRY_UOM     = LS_ITS_DATA-MEINS ."单位
    LS_ITEM-ENTRY_UOM_ISO = LS_ITS_DATA-MEINS ."单位
    LS_ITEM-MOVE_TYPE     = CNS_BWART_543."移动类型
    LS_ITEM-MVT_IND       = ZIF_BC_CONS=>CNS_B.
    LS_ITEM-PROD_DATE     = LS_ITS_DATA-SCRQ."制造日期
    LS_ITEM-PO_PR_QNT     = LS_ITS_DATA-JJSL."计价数量
    LS_ITEM-ORDERPR_UN    =  LS_ITS_DATA-BPRME."计价单位
    APPEND LS_ITEM TO LT_ITEM.    

    LS_HEADER-PSTNG_DATE = SY-DATUM . "过账日期
    LS_HEADER-DOC_DATE   = SY-DATUM . "凭证日期
    LS_HEADER-PR_UNAME   = SY-UNAME . "用户名
    LS_HEADER-REF_DOC_NO = LS_ITS_DATA-EBELN.  "凭证编号  

	  CALL FUNCTION 'Z_MM_GOODSMVT_CREATE'
	    EXPORTING
	      IS_HEADER  = LS_HEADER
	      IV_GM_CODE = CNS_GM_CODE_01
	      IV_BWART   = CNS_BWART_543
	      IV_TEST    = UV_TEST
	    IMPORTING
	      ES_RET_DOC = LS_DOC
	      ES_MESSAGE = CS_RETURN
	    TABLES
	      IT_ITEM    = LT_ITEM
	      ET_RETURN  = LT_RETURN.