1. 物料搬运单Move Order 简介
物料搬运单是在一个组织内对物料进行移动的请求。它们用于将在仓库或工厂内移动物料的请求流程规范化,以便执行物料补充、改变物料存储地点和质量处理等事务。可以根据使用的来源类型人工或自动生成物料搬运单。
物料搬运单只限于组织内的事务处理使用,组织间的转移需要进行内部申请。
子库存转移和物料搬运单区别:
A. 物料搬运单是一个需要审批的过程,而子库存转移不需要审批.
B. 物料搬运单可以做类似杂项发放和两个子库存物料转移的操作,但无法实现物料在同一子库存中不同货位的转移,这个只有通过子库存转移实现。
2. Move Order Type
Navigate to: INV -> Setup -> Lookups
3. Move Order – Approval Workflow
Move Order的审批由三个参数控制:
Move Order Timeout Period(超时天数,空则=0)
Move Order Timeout Action(超时动作,自动审批,自动拒绝)
Planner(物料计划员,组织级的)
如果“超时天数”=0,则由“超时动作”直接决定状态,否则发通知给“物料计划员”审批。
如果“物料计划员”没有设置,则自动审批。
如果“物料计划员”= 申请人自己,则自动审批 否则,由“物料计划员”审批。
“物料计划员”及时做出审批或者拒绝超时之后,再次通知“物料计划员”审批,再次超时,则由“超时动作”直接决定状态。
Demo : 创建Move Order,审批后状态为Pengding Approval
切换到Planner用户,在Worklist里就能看到那条审批申请,这里就可以Approve
4. Move Order – Import
Create Move Order (Allocate\Transact import略)
DECLARE
l_trohdr_rec inv_move_order_pub.trohdr_rec_type;
l_trolin_tbl inv_move_order_pub.trolin_tbl_type;
x_trohdr_rec inv_move_order_pub.trohdr_rec_type;
x_trolin_tbl inv_move_order_pub.trolin_tbl_type;
x_return_status VARCHAR2(1);
x_msg_count NUMBER;
x_msg_data VARCHAR2(2000);
l_cur_mfg_org_id NUMBER := 242; --Current Inv Organization
l_user_id NUMBER := 6597; --User ID
l_index NUMBER := 1;
BEGIN
--Initialize first, or create_by will be -1
fnd_global.apps_initialize(user_id => l_user_id,
resp_id => 51686,
resp_appl_id => 401); --Inventory
-- header
l_trohdr_rec.organization_id := l_cur_mfg_org_id;
l_trohdr_rec.move_order_type := inv_globals.g_move_order_requisition;
l_trohdr_rec.header_status := inv_globals.g_to_status_incomplete;
l_trohdr_rec.from_subinventory_code := 'FGL';
l_trohdr_rec.status_date := SYSDATE;
l_trohdr_rec.db_flag := fnd_api.g_true;
l_trohdr_rec.operation := inv_globals.g_opr_create;
-- line
l_index := 1;
l_trolin_tbl(l_index).organization_id := l_cur_mfg_org_id;
l_trolin_tbl(l_index).line_number := l_index;
l_trolin_tbl(l_index).date_required := SYSDATE;
l_trolin_tbl(l_index).from_subinventory_code := 'FGL';
l_trolin_tbl(l_index).to_subinventory_code := 'RML';
l_trolin_tbl(l_index).to_locator_id := 88478; --can't be locator_code
l_trolin_tbl(l_index).inventory_item_id := 171132;
l_trolin_tbl(l_index).quantity := 12;
l_trolin_tbl(l_index).uom_code := 'CS';
l_trolin_tbl(l_index).line_status := inv_globals.g_to_status_incomplete;
l_trolin_tbl(l_index).status_date := SYSDATE;
l_trolin_tbl(l_index).transaction_type_id := inv_globals.g_type_transfer_order_subxfr;
l_trolin_tbl(l_index).db_flag := fnd_api.g_true;
l_trolin_tbl(l_index).operation := inv_globals.g_opr_create;
inv_transfer_order_pvt.process_transfer_order(p_api_version_number => 1.0,
p_init_msg_list => 'T',
x_return_status => x_return_status,
x_msg_count => x_msg_count,
x_msg_data => x_msg_data,
p_trohdr_rec => l_trohdr_rec,
p_trolin_tbl => l_trolin_tbl,
x_trohdr_rec => x_trohdr_rec,
x_trolin_tbl => x_trolin_tbl);
IF x_return_status <> fnd_api.g_ret_sts_success THEN
ROLLBACK;
fnd_msg_pub.count_and_get(p_count => x_msg_count, p_data => x_msg_data);
dbms_output.put_line('error count : ' || to_char(x_msg_count));
dbms_output.put_line(REPLACE(x_msg_data, chr(0), ' '));
FOR i IN 2 .. x_msg_count LOOP
x_msg_data := fnd_msg_pub.get;
dbms_output.put_line(REPLACE(x_msg_data, chr(0), ' '));
END LOOP;
IF (x_return_status = fnd_api.g_ret_sts_unexp_error) THEN
RAISE fnd_api.g_exc_unexpected_error;
ELSIF (x_return_status = fnd_api.g_ret_sts_error) THEN
RAISE fnd_api.g_exc_error;
END IF;
ELSE
--COMMIT;
dbms_output.put_line('Success!Move Order Number:' || x_trohdr_rec.request_number);
END IF;
END;