[Chapter 8] - [实验7]

思路：

本实验用2种思路各完成一遍。

1. 自己最先想到的思路，将源数据区视为一个整体，将目标数据区也视为一个整体，loop 21次，每次完成4+4+2个字节的传输，源及目标区域均适用idata[si]的寻址方式
2. 书中的思路，将源数据区视为3个独立的数组，将目标数据区视为21个结构，每个结构由一整行（16个单元）构成，适用于[bx].idata[si]的寻址方式

以下为代码 (CSDN不能高亮汇编代码，也是醉了）

思路1：

;实验7
assume cs:code,ds:data,es:table

data segment
	db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
	db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
	db '1993','1994','1995'
	;以上为 年份
	dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
	dd 345980,590827,803530,1183000,1843000,2759000,3753000,46749000,5937000
	;以上为 收入
	dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
	dw 11542,14430,15257,17800
	;以上为 雇员数
data ends

table segment
	;是为了申请位置。为存储最终的table,4+4+2+2，中间用空格隔开
	db 21 dup ('year summ ne ?? ')
table ends

code segment
start:
	;永远先实际关联
	mov ax,data
	mov ds,ax
	mov ax,table
	mov es,ax

	;每个loop中分别对3个数据区取值并放置到指定位置，共loop 21次
	;用si代指源中的列
	mov si,0
	;因为前2个数据区是每次向前推进4列，但最后一个雇员数据区却是推进2位，要单独记index
	;用bx标识雇员数据区的内存单元
	mov bx,0
	mov di,0
	mov cx,21
s:
	;注意，mov指令至少有1个操作数必须是寄存器，不能直接操作2个内存单元
	;年份数据区，分2次，每次移16位，由ax名字CPU会知道传16位
	mov ax,ds:[si]
	mov es:[di],ax
	mov ax,ds:[si+2]
	mov es:[di+2],ax
	
	;收入数据区，传4个cell
	mov ax,ds:[si+84]
	mov es:[di+5],ax
	mov ax,ds:[si+84+2]
	mov es:[di+7],ax
	
	;雇员数据区，传2个cell
	mov ax,ds:[bx+84+84]
	mov es:[di+10],ax

	;以下为 人均收入 的除法计算。被除数是 总收入，4字节（32位），除数是 雇员数，2字节（16位）
	;不能使用cell除cell，因为这会破坏原数据，而应该使用寄存器中转
	mov dx,ds:[si+84+2];内存中从左至右是低向高，高16位给dx
	mov ax,ds:[si+84];dx名为16位，将移2个字节,低16位给ax
	div word ptr ds:[bx+84+84];修饰的是除数
	mov es:[di+13],ax;ax为16位，将移2个字节到目标地址

	add si,4
	add bx,2
	;di+16,相当于下移一行，仍在同一列
	add di,16
	loop s

	mov ax,4c00h
	int 21h
code ends

end start

思路2：

;实验7，书中的思路
assume cs:code,ds:data,es:table

data segment
	db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
	db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
	db '1993','1994','1995'
	;以上为 年份
	dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
	dd 345980,590827,803530,1183000,1843000,2759000,3753000,46749000,5937000
	;以上为 收入
	dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
	dw 11542,14430,15257,17800
	;以上为 雇员数
data ends

table segment
	;是为了申请位置。为存储最终的table,4+4+2+2，中间用空格隔开
	db 21 dup ('year summ ne ?? ')
table ends

code segment
start:
	;永远先实际关联
	mov ax,data
	mov ds,ax
	mov ax,table
	mov es,ax

	mov si,0;source,first 2 arrays (data is 4 bits)
	mov bx,168;3rd array (data is 2 bits)
	mov di,0;destination row
	mov cx,21;
s:
	;注意，mov指令至少有1个操作数必须是寄存器，不能直接操作2个内存单元
	;年份数据区，分2次，每次移16位，由ax名字CPU会知道传16位
	;(将源数据视为3组单独的数组，将目标区域设置为每行16个单元构成的21个结构)
	mov ax,00[si];可否写成 00[si],84[si],168[si]
	mov es:[di].00[00],ax
	mov ax,00[si+2]
	mov es:[di].00[02],ax
	
	;收入数据区，传4个cell
	mov ax,84[si]
	mov es:[di].05[00],ax
	mov ax,84[si+2]
	mov es:[di].05[02],ax
	
	;雇员数据区，传2个cell
	mov ax,00[bx]
	mov es:[di].10[00],ax

	;以下为 人均收入 的除法计算。被除数是 总收入，4字节（32位），除数是 雇员数，2字节（16位）
	;不能使用cell除cell，因为这会破坏原数据，而应该使用寄存器中转
	mov ax,84[si];dx名为16位，将移2个字节,低16位给ax
	mov dx,84[si+2];内存中从左至右是低向高，高16位给dx
	div word ptr 00[bx];修饰的是除数
	mov es:[di].13[00],ax;ax为16位，将移2个字节到目标地址

	add si,4
	add bx,2
	;di加16相当于下移一行
	add di,16
	loop s

	mov ax,4c00h
	int 21h
code ends

end start