使用Batch读取注册表

最新推荐文章于 2023-11-16 15:52:05 发布

zhmhbest

最新推荐文章于 2023-11-16 15:52:05 发布

阅读量175

点赞数

分类专栏： Windows系统维护

本文链接：https://blog.csdn.net/weixin_42830080/article/details/109616762

版权

Windows系统维护专栏收录该内容

13 篇文章 0 订阅

订阅专栏

ReadRegistry

@ECHO OFF
REM ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
REM ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■

CALL :ReadFolders "Desktop"
ECHO 桌面路径：%return_value%

CALL :ReadUninstall "Google Chrome"
ECHO 谷歌浏览器：%return_value%

PAUSE

REM ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
REM ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
@GOTO :EOF
:ReadUninstall
@IF "AMD64" EQU "%PROCESSOR_ARCHITECTURE%" @(
    CALL :ReadRegistry "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\%~1" UninstallString
) ELSE @(
    CALL :ReadRegistry "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\%~1" UninstallString
)
@GOTO :EOF
REM ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■

:ReadFolders
@CALL :ReadRegistry "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" "%~1"
@GOTO :EOF
REM ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■

:ReadRegistry
@FOR /F "usebackq skip=2 delims=" %%i IN (`REG QUERY "%~1" /v "%~2"`) DO @(
    @CALL :__GetPart %%i
)
@GOTO :EOF

:__GetPart
    @SET return_value=%~3 %~4 %~5 %~6 %~7 %~8 %~9
    @CALL :__TrimR
    @GOTO :EOF

:__TrimR
    @IF "%return_value:~-1%"==" " @(
        SET "return_value=%return_value:~0,-1%"
        GOTO :__TrimR
    )
    @GOTO :EOF
REM ■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■