检测物理内存容量

最新推荐文章于 2024-04-26 16:31:32 发布
最新推荐文章于 2024-04-26 16:31:32 发布
阅读量812 收藏 1
点赞数
分类专栏： 操作系统 # 操作系统真象还原 文章标签： linux java 运维
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_42888638/article/details/128588133
版权

文章目录

前言

本博客记录《操作系统真象还原》第五章实验操作~

实验环境：ubuntu18.04+VMware ， Bochs下载安装

实验内容：三种检测内存的方法。

实验原理：

Linux中有很多种方式获取内存容量，如果一种方法失败，就会试用其他方法。本实验效仿 Linux 这种获取思想，在实模式下也用这三种方法检测完内存容量后再进入保护模式。如果一种方法获取失败，尝试另一种方法，若三种方法都失败了，由于无法获取内存信息，后续程序无法加载，只好将机器挂起，停止运行。

获取内存容量本质上是调用 BIOS 中断 0x15 的 3 个子功能。子功能号要存放到寄存器 EAX 或 AX 中，例如：

  • EAX=0xE820：遍历主机上全部内存。
  • AX=0xE801： 分别检测低 15MB 和 16MB～4GB 的内存，最大支持 4GB。
  • AH=0x88：最多检测出 64MB 内存，实际内存超过此容量也按照 64MB 返回。

BIOS 中断是实模式下的方法，因此在实模式下用这三种方法检测完内存容量后再进入保护模式。

BIOS获取内存的原理：BIOS 中断可以返回已安装的硬件信息。由于 BIOS 及其中断是一组软件，它要访问硬件要依靠硬件提供的接口。所以，获取内存信息，其内部是通过连续调用硬件的应用程序接口（Application Program Interface，API）来获取内存信息的。

前置知识

BIOS 中断 0x15 子功能 0xe820 获取内存

0xE820 子功能是最灵活的内存获取方式。该方法能够获取系统的内存布局。

由于系统内存各部分的类型属性不同，BIOS 就按照类型属性来划分这片系统内存，所以这种查询呈迭代式，每次 BIOS 只返回一种类型的内存信息，直到将所有内存类型返回完毕。

内存信息包括多个属性字段，所以用地址范围描述符(Address Range Descriptor Structure ，ARDS)进行描述。

在这里插入图片描述

BIOS 中断 是一段函数例程，需要为其提供参数进行调用。

如下图所示：

下图参考自获取内存_一步步编写操作系统 33 利用bios中断0x15子功能0xe820获取内存

在这里插入图片描述

根据上图中的说明，此中断的调用步骤是：

  1. 填写好“调用前输入”中列出的寄存器。
  2. 执行中断调用 int 0x15。
  3. 在CF位为0的情况下，“返回后输出”中对应的寄存器便会有对应的结果。

同样获取内存容量的方法还有以下2种：

利用BIOS 中断 0x15 子功能 0xe820 获取内存

利用 BIOS 中断 0x15 子功能 0x88 获取内存

具体细节操作查看《操作系统真象还原》

代码说明

loader.S

   %include "boot.inc"
   section loader vstart=LOADER_BASE_ADDR
   LOADER_STACK_TOP equ LOADER_BASE_ADDR
   
;构建gdt及其内部的描述符
   GDT_BASE:   dd    0x00000000 
	       dd    0x00000000

   CODE_DESC:  dd    0x0000FFFF 
	       dd    DESC_CODE_HIGH4

   DATA_STACK_DESC:  dd    0x0000FFFF
		     dd    DESC_DATA_HIGH4

   VIDEO_DESC: dd    0x80000007	       ; limit=(0xbffff-0xb8000)/4k=0x7
	       dd    DESC_VIDEO_HIGH4  ; 此时dpl为0

   GDT_SIZE   equ   $ - GDT_BASE
   GDT_LIMIT   equ   GDT_SIZE -	1 
   times 60 dq 0					 ; 此处预留60个描述符的空位(slot)
   SELECTOR_CODE equ (0x0001<<3) + TI_GDT + RPL0         ; 相当于(CODE_DESC - GDT_BASE)/8 + TI_GDT + RPL0
   SELECTOR_DATA equ (0x0002<<3) + TI_GDT + RPL0	 ; 同上
   SELECTOR_VIDEO equ (0x0003<<3) + TI_GDT + RPL0	 ; 同上 

   ; total_mem_bytes用于保存内存容量,以字节为单位,此位置比较好记。
   ; 当前偏移loader.bin文件头0x200字节,loader.bin的加载地址是0x900,
   ; 故total_mem_bytes内存中的地址是0xb00.将来在内核中咱们会引用此地址
   total_mem_bytes dd 0					 
   ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

   ;以下是定义gdt的指针，前2字节是gdt界限，后4字节是gdt起始地址
   gdt_ptr  dw  GDT_LIMIT 
	    dd  GDT_BASE

   ;人工对齐:total_mem_bytes4字节+gdt_ptr6字节+ards_buf244字节+ards_nr2,共256字节
   ards_buf times 244 db 0
   ards_nr dw 0		      ;用于记录ards结构体数量

   loader_start:
   
;-------  int 15h eax = 0000E820h ,edx = 534D4150h ('SMAP') 获取内存布局  -------

   xor ebx, ebx		      ;第一次调用时，ebx值要为0
   mov edx, 0x534d4150	      ;edx只赋值一次，循环体中不会改变
   mov di, ards_buf	      ;ards结构缓冲区
.e820_mem_get_loop:	      ;循环获取每个ARDS内存范围描述结构
   mov eax, 0x0000e820	      ;执行int 0x15后,eax值变为0x534d4150,所以每次执行int前都要更新为子功能号。
   mov ecx, 20		      ;ARDS地址范围描述符结构大小是20字节
   int 0x15
   jc .e820_failed_so_try_e801   ;若cf位为1则有错误发生，尝试0xe801子功能
   add di, cx		      ;使di增加20字节指向缓冲区中新的ARDS结构位置
   inc word [ards_nr]	      ;记录ARDS数量
   cmp ebx, 0		      ;若ebx为0且cf不为1,这说明ards全部返回，当前已是最后一个
   jnz .e820_mem_get_loop

;在所有ards结构中，找出(base_add_low + length_low)的最大值，即内存的容量。
   mov cx, [ards_nr]	      ;遍历每一个ARDS结构体,循环次数是ARDS的数量
   mov ebx, ards_buf 
   xor edx, edx		      ;edx为最大的内存容量,在此先清0
.find_max_mem_area:	      ;无须判断type是否为1,最大的内存块一定是可被使用
   mov eax, [ebx]	      ;base_add_low
   add eax, [ebx+8]	      ;length_low
   add ebx, 20		      ;指向缓冲区中下一个ARDS结构
   cmp edx, eax		      ;冒泡排序，找出最大,edx寄存器始终是最大的内存容量
   jge .next_ards
   mov edx, eax		      ;edx为总内存大小
.next_ards:
   loop .find_max_mem_area
   jmp .mem_get_ok

;------  int 15h ax = E801h 获取内存大小,最大支持4G  ------
; 返回后, ax cx 值一样,以KB为单位,bx dx值一样,以64KB为单位
; 在ax和cx寄存器中为低16M,在bx和dx寄存器中为16MB到4G。
.e820_failed_so_try_e801:
   mov ax,0xe801
   int 0x15
   jc .e801_failed_so_try88   ;若当前e801方法失败,就尝试0x88方法

;1 先算出低15M的内存,ax和cx中是以KB为单位的内存数量,将其转换为以byte为单位
   mov cx,0x400	     ;cx和ax值一样,cx用做乘数
   mul cx 
   shl edx,16
   and eax,0x0000FFFF
   or edx,eax
   add edx, 0x100000 ;ax只是15MB,故要加1MB
   mov esi,edx	     ;先把低15MB的内存容量存入esi寄存器备份

;2 再将16MB以上的内存转换为byte为单位,寄存器bx和dx中是以64KB为单位的内存数量
   xor eax,eax
   mov ax,bx		
   mov ecx, 0x10000	;0x10000十进制为64KB
   mul ecx		;32位乘法,默认的被乘数是eax,积为64位,高32位存入edx,低32位存入eax.
   add esi,eax		;由于此方法只能测出4G以内的内存,故32位eax足够了,edx肯定为0,只加eax便可
   mov edx,esi		;edx为总内存大小
   jmp .mem_get_ok

;-----------------  int 15h ah = 0x88 获取内存大小,只能获取64M之内  ----------
.e801_failed_so_try88: 
   ;int 15后，ax存入的是以kb为单位的内存容量
   mov  ah, 0x88
   int  0x15
   jc .error_hlt
   and eax,0x0000FFFF
      
   ;16位乘法，被乘数是ax,积为32位.积的高16位在dx中，积的低16位在ax中
   mov cx, 0x400     ;0x400等于1024,将ax中的内存容量换为以byte为单位
   mul cx
   shl edx, 16	     ;把dx移到高16位
   or edx, eax	     ;把积的低16位组合到edx,为32位的积
   add edx,0x100000  ;0x88子功能只会返回1MB以上的内存,故实际内存大小要加上1MB

.mem_get_ok:
   mov [total_mem_bytes], edx	 ;将内存换为byte单位后存入total_mem_bytes处。


;-----------------   准备进入保护模式   -------------------
;1 打开A20
;2 加载gdt
;3 将cr0的pe位置1

   ;-----------------  打开A20  ----------------
   in al,0x92
   or al,0000_0010B
   out 0x92,al

   ;-----------------  加载GDT  ----------------
   lgdt [gdt_ptr]

   ;-----------------  cr0第0位置1  ----------------
   mov eax, cr0
   or eax, 0x00000001
   mov cr0, eax

   jmp dword SELECTOR_CODE:p_mode_start	     ; 刷新流水线，避免分支预测的影响,这种cpu优化策略，最怕jmp跳转，
					     ; 这将导致之前做的预测失效，从而起到了刷新的作用。
.error_hlt:		      ;出错则挂起
   hlt

[bits 32]
p_mode_start:
   mov ax, SELECTOR_DATA
   mov ds, ax
   mov es, ax
   mov ss, ax
   mov esp,LOADER_STACK_TOP
   mov ax, SELECTOR_VIDEO
   mov gs, ax

   mov byte [gs:160], 'P'

   jmp $

代码说明

  1. 第 28 行定义了 4 字节的变量 total_mem_bytes，此变量用于存储获取到的内存容量。total_mem_bytes 定义的上方解释了total_mem_bytes 的地址是 0xb00 的原因。理由：它前
    面有 4 个段描述符的定义，还有预留 60 个段描述槽位 times 60 dq 0。因此偏移量是(4+60)*8=512=0x200 字节，本程序的加载地址是 0x900，0x900+0x200=0xb00。因此 0xb00 是变量 total_mem_bytes 加载到内存中的地址。
  2. 35～37 行是提前定义的缓冲区，为的是存储 BIOS 0x15 中断 0xe820 子功能返回的 ARDS (Address Range Descriptor Structure)结构。
  3. 第 41～69 行用的子功能 0xe820 方法。
  4. 第 56～69 行是找出最大的内存块。
  5. 第 71～95 行是利用子功能 0xe801 探测内存容量。
  6. 第 88～95 行是计算 16MB 之上的内存容量，结果存放在寄存器 BX 和 DX，单位是 64KB，需要转换成字节。
  7. 第 98～110 行是用子功能 0x88 方法探测内存容量。

bochsrc.disk

这里为了和书本中输出保持一致，因此将bochsrc.disk中megs设置为32

在这里插入图片描述

mbr.S

【注意】：mbr和原先的哪个文件存在出入

;主引导程序 
;------------------------------------------------------------
%include "boot.inc"
SECTION MBR vstart=0x7c00         
   mov ax,cs      
   mov ds,ax
   mov es,ax
   mov ss,ax
   mov fs,ax
   mov sp,0x7c00
   mov ax,0xb800
   mov gs,ax

; 清屏
;利用0x06号功能，上卷全部行，则可清屏。
; -----------------------------------------------------------
;INT 0x10   功能号:0x06	   功能描述:上卷窗口
;------------------------------------------------------
;输入：
;AH 功能号= 0x06
;AL = 上卷的行数(如果为0,表示全部)
;BH = 上卷行属性
;(CL,CH) = 窗口左上角的(X,Y)位置
;(DL,DH) = 窗口右下角的(X,Y)位置
;无返回值：
   mov     ax, 0600h
   mov     bx, 0700h
   mov     cx, 0                   ; 左上角: (0, 0)
   mov     dx, 184fh		   ; 右下角: (80,25),
				   ; 因为VGA文本模式中，一行只能容纳80个字符,共25行。
				   ; 下标从0开始，所以0x18=24,0x4f=79
   int     10h                     ; int 10h

   ; 输出字符串:MBR
   mov byte [gs:0x00],'1'
   mov byte [gs:0x01],0xA4

   mov byte [gs:0x02],' '
   mov byte [gs:0x03],0xA4

   mov byte [gs:0x04],'M'
   mov byte [gs:0x05],0xA4	   ;A表示绿色背景闪烁，4表示前景色为红色

   mov byte [gs:0x06],'B'
   mov byte [gs:0x07],0xA4

   mov byte [gs:0x08],'R'
   mov byte [gs:0x09],0xA4
	 
   mov eax,LOADER_START_SECTOR	 ; 起始扇区lba地址
   mov bx,LOADER_BASE_ADDR       ; 写入的地址
   mov cx,4			 ; 待读入的扇区数
   call rd_disk_m_16		 ; 以下读取程序的起始部分（一个扇区）
  
   jmp LOADER_BASE_ADDR + 0x300
       
;-------------------------------------------------------------------------------
;功能:读取硬盘n个扇区
rd_disk_m_16:	   
;-------------------------------------------------------------------------------
				       ; eax=LBA扇区号
				       ; ebx=将数据写入的内存地址
				       ; ecx=读入的扇区数
      mov esi,eax	  ;备份eax
      mov di,cx		  ;备份cx
;读写硬盘:
;第1步：设置要读取的扇区数
      mov dx,0x1f2
      mov al,cl
      out dx,al            ;读取的扇区数

      mov eax,esi	   ;恢复ax

;第2步：将LBA地址存入0x1f3 ~ 0x1f6

      ;LBA地址7~0位写入端口0x1f3
      mov dx,0x1f3                       
      out dx,al                          

      ;LBA地址15~8位写入端口0x1f4
      mov cl,8
      shr eax,cl
      mov dx,0x1f4
      out dx,al

      ;LBA地址23~16位写入端口0x1f5
      shr eax,cl
      mov dx,0x1f5
      out dx,al

      shr eax,cl
      and al,0x0f	   ;lba第24~27位
      or al,0xe0	   ; 设置7～4位为1110,表示lba模式
      mov dx,0x1f6
      out dx,al

;第3步：向0x1f7端口写入读命令，0x20 
      mov dx,0x1f7
      mov al,0x20                        
      out dx,al

;第4步：检测硬盘状态
  .not_ready:
      ;同一端口，写时表示写入命令字，读时表示读入硬盘状态
      nop
      in al,dx
      and al,0x88	   ;第4位为1表示硬盘控制器已准备好数据传输，第7位为1表示硬盘忙
      cmp al,0x08
      jnz .not_ready	   ;若未准备好，继续等。

;第5步：从0x1f0端口读数据
      mov ax, di
      mov dx, 256
      mul dx
      mov cx, ax	   ; di为要读取的扇区数，一个扇区有512字节，每次读入一个字，
			   ; 共需di*512/2次，所以di*256
      mov dx, 0x1f0
  .go_on_read:
      in ax,dx
      mov [bx],ax
      add bx,2		  
      loop .go_on_read
      ret

   times 510-($-$$) db 0
   db 0x55,0xaa

实验操作

创建mbr.S和loader.S文件并编译

(base) user@ubuntu:/home/cooiboi/bochs/boot$ sudo vim loader.S
(base) user@ubuntu:/home/cooiboi/bochs/boot$ sudo vim  mbr.S
(base) user@ubuntu:/home/cooiboi/bochs/boot$ cd ..
(base) user@ubuntu:/home/cooiboi/bochs$ sudo nasm -I include/ -o boot/loader.bin boot/loader.S
(base) user@ubuntu:/home/cooiboi/bochs$ sudo nasm -I include/ -o boot/mbr.bin boot/mbr.S

将mbr和load分别写入磁盘中

sudo dd if=/home/cooiboi/bochs/boot/mbr.bin of=/home/cooiboi/bochs/boot/hd60M.img bs=512 count=1 conv=notrunc
sudo dd if=/home/cooiboi/bochs/boot/loader.bin of=/home/cooiboi/bochs/boot/hd60M.img bs=512 count=2 seek=2 conv=notrunc

(base) user@ubuntu:/home/cooiboi/bochs/boot$ sudo dd if=/home/cooiboi/bochs/boot/mbr.bin of=/home/cooiboi/bochs/boot/hd60M.img bs=512 count=1 conv=notrunc
1+0 records in
1+0 records out
512 bytes copied, 0.000133292 s, 3.8 MB/s
(base) user@ubuntu:/home/cooiboi/bochs/boot$ sudo dd if=/home/cooiboi/bochs/boot/loader.bin of=/home/cooiboi/bochs/boot/hd60M.img bs=512 count=2 seek=2 conv=notrunc
1+1 records in
1+1 records out
1000 bytes (1.0 kB) copied, 0.00834544 s, 120 kB/s

启动Bochs

sudo bin/bochs -f boot/bochsrc.disk

(base) user@ubuntu:/home/cooiboi/bochs$ sudo bin/bochs -f boot/bochsrc.disk

输出6和c
在这里插入图片描述
在这里插入图片描述

输入Ctrl+C组合键中断bochs运行。

接着再输入命令xp 0xb00+回车，显示结果。

🆗 32M为0x02000000。

在这里插入图片描述

参考资料

pengege666
关注
  • 0
    点赞
  • 踩
  • 1
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
APP性能测试--内存测试
Onfire22的博客
03-24 8543
一、内存占用对于智能手机而言，内存大小是固定的；因此，如果单个app的内存占用越小，手机上可以安装运行的app就越多；或者说app的内存占用越小，在手机上运行就会越流畅。所以说，内存占用的大小，也是考量app性能的一个重要指标。二、测试项空负荷————app已经在后台运行，但是用户没有使用；back静置后台home静置后台放在应用主页面中负荷————app在前台运行，用户进行了少量操作；满负荷——...
操作系统真相还原
Destiny_159的博客
10-14 1667
操作系统真相还原 1、部署工作环境 1.2 Bochs下载安装 下载 下载地址：https://sourceforge.net/projects/bochs/files/bochs/2.7/ 解压： crescentp@crescentp:~/bochs$ tar zxvf bochs-2.7.tar.gz 编译 ./configure --prefix=/os/bochs --enable-debugger --enable-disasm --enable-iodebug --enable-x86-d
内存测试_内存检测工具大全
热门推荐
qq1327798176的博客
01-25 4万+
测试内存，往往不局限于一种软件，因为每种工具都有自己的局限性。灵活运用多种工具，是为了实现最大的测试效果，提升产品质量 1、《HCI MemTest》 https://hcidesign.com/memtest/ HCI MemTest恐怕是世界上用户最多的内存测试软件 它之所以如此出名，我认为有以下几点原因： ①它是当年少数可以在Windows操作系统中运行的内存检测软件之一（传统...
【实战记录】手游内存优化（内存泄露检测）
zien的博客
05-26 1281
记录自己一个项目检测内存的整个过程
如何进行内存容量测试？
伤心的辣条
06-13 4743
内存(Memory)是计算机重要的基础组成部分之一，也被称为随机存储器(Random Access Memory，RAM)，是指计算机能够直接访问的存储器，用于存储计算机程序和数据等信息。通常情况下，在计算机运行时，应用程序和操作系统都需要占用内存空间，因此扩充计算机内存容量是提高计算机性能和运行效率的重要手段。随着计算机发展的不断推进，内存容量对于计算机的运行速度和效率变得更为重要。通过上述介绍的三种内存测试方法，用户可以快速准确地获得计算机内存容量大小信息，从而更好地管理计算机系统和优化运行状态。
三种内存测试软件的使用说明
weixin_34293911的博客
05-19 2531
(1)微软内存检测工具现在的系统盘一般都带有“微软内存检测工具”。程序加载后，即会开始扫描RAM。扫描界面如下图:WindowsMemoryDiagnostic工具启动时默认为“Standard”（标准）模式，此模式包括6项不同的连续内存测试，每项测试都使用一种独特的算法来扫描不同类型的错误。在程序运行时，屏幕会显示每个单独测试的结果，列出它的进度以及正在扫描的内...
计算机器内存数量+引入和显示ARDS成员
weixin_30321449的博客
09-16 78
【1】README 1.1） 本代码在于读取内存中多个 内存段的地址范围描述符结构体（ARDS），有多少个内存段可以用； 1.2） source code and images in the blog from orange’s implemention of a os 1.3） the comments towards code are built by my...
第5章 保护模式进阶，向内核迈进
weixin_43917399的博客
04-06 261
尽管 TLB 对开发人员不可见，但依然有两种方法可以间接更新 TLB ，一个是针对 TLB 中所有条目的方法一一重新加载 CR3 ，比如将 CR3 寄存器的数据读出来后再写入 CR3 ，这会使整个 TLB 失效。另一个方法是针对 TLB 中某个条目的更新。处理器提供了指令 invlpg (invalidate page ），它用于在 TLB 中刷新， 某个虚拟地址对应的条目，处理器是用虚拟地址来检索 TLB 的，因此很自然地，指令 invlpg 的操作数也是虚拟地址，其指令格式为 invlpg m。
C语言插入一个变量检测一段代码占用内存空间
weixin_42607969的博客
01-14 209
在 C 语言中，可以使用 sizeof 关键字来检测一个变量占用的内存空间。例如，可以使用以下代码检测一个整型变量占用的内存空间： int x; printf("Size of x: %ld bytes\n", sizeof(x)); ...
获取物理内存容量(下)
qq_52484093的博客
11-02 286
我们这节课BIOS提供的(int 0x15)号中断的高级功能(eax = 0xE820)，遍历主机上所有的内存范围(内存地址段)，获取各个内存范围的详细信息 int 0x15 进阶版功能 中断参数 eax = 0xE820 (固定值) edx = 0x534D4150 (固定值) ebx --> 初始参数必须为0，终止标志 ecx --> ARDS 结构体大小 (20字节) es : di --> ARDS 结构体数组 (每个元素占用20字节) 地址范围描述结构 (Ad
内存虚拟物理硬盘(VSuite Ramdisk专业版) 4.5.7219.1638中文特别版
10-01
它采用独特的软件算法，高效率地将内存虚拟成物理硬盘，使得对硬盘文件的数据读写转化为对内存的数据访问，极大的提高数据访问速度，从而突破硬盘瓶颈，飞速提升计算机性能。另一方面它大大减少了对物理硬盘的访问...
VC 检测内存使用状态.rar
07-10
VC 检测内存使用状态，检测电脑的总物理内存、虚拟内存总数、剩余内存容量、可用虚拟内存字节数等，如演示截图所示的程序运行效果，该源码在VC 6.0环境下，可直接编译运行。
Ram Stress Test _专业内存检测工具
08-25
Ram Stress Test是美国Ultra-X公司旗下的一个专业记忆体测试程式，是专门给系统生产厂商出机前用的...　程序执行后，第一选项是测试物理内存中基本内存地址（），第二项是扩展内存地址，第三项是测试你CPU的L2 cache。
内存虚拟硬盘软件
10-08
VSuiteRamdisk是RomexSoftware开发的一款可以利用内存虚拟一个完全等效的物理硬盘。可以极大的提高读写文件的速度，并减少实际硬盘的访问，从而延长硬盘寿命。它还可以识别操作系统识别不到的内存，通过虚拟成硬盘的...
R.S.T (RAM STRESS TEST)内存检测
01-02
　程序执行后，第一选项是测试物理内存中基本内存地址（），第二项是扩展内存地址，第三项是测 试你CPU的L2 cache。 ☆　可以测试SD及DDR内存。 ☆　闪动数字——0123456789ABCDEF0123456789ABCDEF 0123456789...
Linux多进程(五) 进程池 C++实现
最新发布
Lyajpunov的博客
04-26 578
进程池是一种并发编程模式，用于管理和重用多个处理任务的进程。它通常用于需要频繁创建和销毁进程的情况，以避免因此产生的开销。减少进程创建销毁的开销：避免频繁创建和销毁进程所带来的系统资源开销。提高系统响应速度：由于进程已经初始化并且一直保持在内存中，可以立即分配执行任务，减少了任务等待时间。控制资源使用：通过限制进程池中的进程数量，可以控制系统资源的使用情况，避免资源过度消耗。
Linux——web服务配置
Xinan_____的博客
04-23 1049
GET：请求获取指定资源的表示形式。使用GET方法，客户端请求服务器发送某个资源。POST：向指定资源提交数据，用于处理表单提交、文件上传等操作。PUT：向指定资源位置上传其最新内容，用于更新资源。DELETE：请求服务器删除指定资源。HEAD：请求获取与实体相对应的头部信息，用于获取资源的元数据。OPTIONS：请求查询服务器支持的HTTP方法。TRACE：请求服务器回显收到的请求消息，用于测试或诊断。200 OK：请求成功。：永久重定向，请求的资源已经被分配了新的。
linux18：进程等待
m0_73919066的博客
04-20 1097
1：子进程创建的目的是要完成父进程指派的某个任务，当子进程运行完毕退出时，父进程需要通过进程等待的方式，回收子进程资源，获取子进程退出信息（子进程有无异常？没有异常结果是否正确？检查退出码查看错误原因）2：父进程如果一直不回收，就可能造成子进程‘僵尸进程’的问题，子进程一直得不到父进程的回收，进而造成内存泄漏。3：子进程一旦变成僵尸状态，那就刀枪不入，“杀人不眨眼”的kill -9 也无能为力杀死一个已经死去的进程。只能通过进程等待将他进行回收。
Linux之C编程入门
qwertf123的博客
04-21 846
Linux之C编程入门
我的物理内存使用率只有百分之58 为什么还会一直占用swap呢
07-12
如果你的物理内存使用率只有百分之58，但swap占用率一直保持百分之百，可能有几个可能的原因： 1. 内存泄漏：某些应用程序可能存在内存泄漏问题，导致它们在运行过程中不断占用内存而不释放。即使物理内存还有空闲，这些应用程序可能会将数据频繁地交换到swap空间中，导致swap占用率高。 2. 内存不足：尽管物理内存使用率只有百分之58，但是系统仍然认为物理内存不足以满足当前的内存需求，并且将数据交换到swap空间中。这可能是因为某些应用程序需要大量的内存，或者系统配置了较小的swap空间。 3. 错误的swap设置：如果swap空间设置得过大，系统可能会倾向于使用swap而不是物理内存。这可能导致swap占用率一直保持百分之百。你可以检查swap空间的设置，并根据服务器的实际情况进行调整。 为了解决这个问题，你可以采取以下步骤： 1. 检查系统中是否存在内存泄漏的应用程序，并修复或更新它们。 2. 确保物理内存大小适合服务器的需求。如果物理内存确实不足，考虑增加物理内存容量。 3. 检查swap空间的设置，确保设置合理。如果swap空间过大，可以适当减小它。 最好的解决方法是综合考虑物理内存和swap空间的使用情况，并根据实际需求进行调整，以优化服务器的性能和内存管理。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值