Oracle导出blob为文件

1. 创建目录,后面导出文件会导到这里,如果是linux,就是linux的磁盘地址

create or replace directory MY_DIR as '/home/blob';

2. 导出blob为文件 (需要修改的地方已经标注出来了)

declare
  l_file     UTL_FILE.FILE_TYPE;
  l_buffer   RAW(32767);
  l_amount   BINARY_INTEGER := 32767;
  l_pos      INTEGER := 1;
  l_blob_len INTEGER;
  cursor cur is 
    /*查询需要导出的文件*/
    select rownum id,CONTENT_ as t_blob,'文件名' as t_name  from BASE_UPLOADFILEBLOB WHERE PATH_ like '%jasper' ;
  /*修改: CONTENT_是大字段,t_name是文件名称,建议使用英文,或者数据库里面查出的数据*/
  /*修改: from后面是表,where后面是条件根据自己需要配置,符合条件的都会被导出来*/
  rec number(5) := 1;

BEGIN
  DBMS_OUTPUT.ENABLE(1000000000);
  for rec in cur loop
     DBMS_OUTPUT.put_line('rec: ' || rec.id);
     l_blob_len := DBMS_LOB.GETLENGTH(rec.t_blob);
     --修改: '.jasper'是文件后缀名,如果是图片,修改成'.jpg'
     l_file     := UTL_FILE.FOPEN('MY_DIR', rec.id||'_'||rec.t_name || '.jasper', 'WB', 32767);
     --说明：重新初始化位置
     l_pos:= 1;
     WHILE l_pos < l_blob_len LOOP
        --说明：重新初始化大小
        l_amount := 32767;
        DBMS_LOB.READ(rec.t_blob, l_amount, l_pos, l_buffer);
        UTL_FILE.PUT_RAW(l_file, l_buffer, TRUE);
        l_pos := l_pos + l_amount;
     END LOOP;
     UTL_FILE.FCLOSE(l_file); 
  end loop;
END;
--where PATH_='/_MDMFILE/jasper/wlReport.jasper'