FPGA学习.4——VGA显示驱动设计

最新推荐文章于 2024-05-18 14:39:20 发布
最新推荐文章于 2024-05-18 14:39:20 发布
阅读量1.8k 收藏 16
点赞数 4
分类专栏： FPGA科普 文章标签： fpga fpga/cpld 嵌入式
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_43550752/article/details/113500569
版权

前言

图像显示设备在日常生活中随处可见，例如家庭电视机、计算机显示屏幕等，这些设备之所以能够显示我们需要的数据图像信息，归功于视频传输接口。常见的视频传输接口有三种：VGA接口、DVI接口和HDMI接口，目前的显示设备都配有这三种视频传输接口。

三类视频接口的发展历程为VGA→DVI→HDMI。其中VGA接口出现最早，只能传输模拟图像信号； 随后出现的DVI接口又分为三类：DVI-A、DVI-D、DVI-I，分别可传输纯模拟图像信号、纯数字图像信号和兼容模拟、数字图像信号；最后的HDMI在传输数字图像信号的基础上又可以传输音频信号。

VGA，英文全称“Video Graphics Array”，译为视频图形阵列，是一种使用模拟信号进行视频传输的标准协议，由IBM公司于1987年推出，因其分辨率高、显示速度快、颜色丰富等优点，广泛应用于彩色显示器领域。由于VGA接口体积较大，与追求小巧便携的笔记本电脑背道而驰，在笔记本电脑领域，VGA接口已被逐渐淘汰，但对于体积较大的台式机，这种情况并未发生，虽然VGA标准在当前个人电脑市场中已经过时，但因其在显示标准中的重要性和良好的兼容性，VGA仍然是最多制造商所共同支持的一个标准，个人电脑在加载自己独特驱动程序之前，都必须支持VGA的标准。

VGA接口及引脚定义

在最初的应用中，VGA接口常用于计算机与VGA显示器之间的图像传输，在台式计算机、旧式笔记本电脑和VGA显示器上一般会有标准的VGA接口。

表格 28‑1   VGA引脚定义

引脚

定义

引脚

定义

1

红基色(RED)

9

保留(各厂家定义不同)

2

绿基色(GREEN)

10

数字地(GND)

3

蓝基色(BLUE)

11

地址码0(ID BIT0)

4

地址码2(ID BIT2)

12

地址码1(ID BIT1)

5

自测试(各厂家定义不同)

13

行同步(HSYNC)

6

红色地(RGND)

14

场同步(VSYNC)

7

绿色地(GGND)

15

地址码3(ID BIT3)

8

蓝色地(BGND)

 

 

VGA使用工业界通用的RGB色彩模式作为色彩显示标准，这种色彩显示标准是根据三原色中红色、绿色、蓝色所占比例多少及三原色之间的相互叠加得到各式各样的颜色。引脚1红基色(RED)、引脚2绿基色(GREEN)、引脚3蓝基色(BLUE)就是VGA接口中负责传输三原色的传输通道。要注意的是，这3个引脚传输的是模拟信号。

VGA显示原理

VGA显示器显示图像，并不是直接让图像在显示器上显示出来，而是采用扫描的方式，将构成图像的像素点，在行同步信号和场同步信号的同步下，按照从上到下、由左到右的顺序扫描到显示屏上。

结合VGA显示器扫描方式示意图，我们简要说明一下VGA显示器的扫描规律。

  1. 在行、场同步信号的同步作用下，扫描坐标定位到左上角第一个像素点坐标；
  2. 自左上角(第一行)第一个像素点坐标，逐个像素点向右扫描(图中第一个水平方向箭头)；
  3. 扫描到第一行最后一个数据，一行图像扫描完成，进行图像消隐，扫描坐标自第一行行尾转移到第二行行首(图中第一条虚线)；
  4. 重复若干次扫描至最后一行行尾，一帧图像扫描完成，进行图像消隐，扫描坐标跳转回到左上角第一行行首(图中对角线箭头)，开始下一帧图像的扫描。

在扫描的过程中会对每一个像素点进行单独赋值，使每个像素点显示对应色彩信息，当一帧图像扫描结束后，开始下一帧图像的扫描，循环往复，当扫描速度足够快，加之人眼的视觉暂留特性，我们会看到一幅完整的图片，而不是一个个闪烁的像素点。这就是VGA显示的原理。

VGA时序标准

为了适应匹配不同厂家的VGA显示器，VGA视频传输接口有自己的一套VGA时序标准，只有遵循VGA的时序标准，才能正确的进行图像信息的显示。

VGA时序标准图

行同步时序图

图中Video代表传输的图像信息，HSync表示行同步信号。HSync自上升沿起到下一个上升沿止为一个完整周期，我们称之为行扫描周期。

一个完整的行扫描周期，包含6部分：Sync（同步）、Back Porch（后沿）、Left Border（左边框）、“Addressable” Video（有效图像）、Right Border（右边框）、Front Porch（前沿），这6部分的基本单位是pixel（像素），即一个像素时钟周期。

在一个完整的行扫描周期中，Video图像信息在HSync行同步信号的同步下完成一行图像的扫描显示，Video图像信息只有在“Addressable” Video（有效图像）阶段，图像信息有效，其他阶段图像信息无效。

HSync行同步信号在Sync（同步）阶段，维持高电平，其他阶段均保持低电平，在下一个行扫描周期的Sync（同步）阶段，HSync行扫描信号会再次拉高，其他阶段拉低，周而复始。

场同步时序图

理解了行同步时序，场同步时序就更容易理解了，两者相类似，如上图所示，图中Video代表传输的图像信息，VSync表示场同步信号，VSync自上升沿起到下一个上升沿止为一个完整周期，我们称之为场扫描周期。

一个完整的场扫描周期，也包含6部分：Sync（同步）、Back Porch（后沿）、Top Border（上边框）、“Addressable” Video（有效图像）、Bottom Border（底边框）、Front Porch（前沿），与行同步信号不同的是，这6部分的基本单位是line（行），即一个完整的行扫描周期。

综上所述，将行同步时序图与场同步时序图结合起来就构成了VGA时序图

图中的红色区域表示在一个完整的行扫描周期中，Video图像信息只在此区域有效，黄色区域表示在一个完整的场扫描周期中，Video图像信息只在此区域有效，两者相交的橙色区域，就是VGA图像的最终显示区域。

VGA显示模式及相关参数

行同步时序可分为6个阶段，对于这6个阶段的参数是有严格定义的，参数配置不正确，VGA不能正常显示。VGA显示器可支持多种分辨率，不同分辨率对应个阶段的参数是不同的，常用VGA分辨率时序参数如下

行扫描周期  *  场扫描周期  *  刷新频率  =  时钟频率

 

一个简单的VGA显示电路如下：

一个简单的彩条显示如下:

上代码

顶层：

module  vga_colorbar
(
    input   wire            sys_clk     ,   //输入工作时钟,频率50MHz
    input   wire            sys_rst_n   ,   //输入复位信号,低电平有效

    output  wire            hsync       ,   //输出行同步信号
    output  wire            vsync       ,   //输出场同步信号
    output  wire    [15:0]  rgb             //输出像素信息
);

//********************************************************************//
//****************** Parameter and Internal Signal *******************//
//********************************************************************//
//wire define
wire            vga_clk ;   //VGA工作时钟,频率25MHz
wire            locked  ;   //PLL locked信号
wire            rst_n   ;   //VGA模块复位信号
wire    [9:0]   pix_x   ;   //VGA有效显示区域X轴坐标
wire    [9:0]   pix_y   ;   //VGA有效显示区域Y轴坐标
wire    [15:0]  pix_data;   //VGA像素点色彩信息

//rst_n:VGA模块复位信号
assign  rst_n = (sys_rst_n & locked);

//********************************************************************//
//*************************** Instantiation **************************//
//********************************************************************//

//------------- clk_gen_inst -------------
clk_gen clk_gen_inst
(
    .RESET      (~sys_rst_n ),  //输入复位信号,高电平有效,1bit
    .CLK_IN1    (sys_clk    ),  //输入50MHz晶振时钟,1bit

    .CLK_OUT1   (vga_clk    ),  //输出VGA工作时钟,频率25Mhz,1bit
    .LOCKED     (locked     )   //输出pll locked信号,1bit
);

//------------- vga_ctrl_inst -------------
vga_ctrl  vga_ctrl_inst
(
    .vga_clk    (vga_clk    ),  //输入工作时钟,频率25MHz,1bit
    .sys_rst_n  (rst_n      ),  //输入复位信号,低电平有效,1bit
    .pix_data   (pix_data   ),  //输入像素点色彩信息,16bit

    .pix_x      (pix_x      ),  //输出VGA有效显示区域像素点X轴坐标,10bit
    .pix_y      (pix_y      ),  //输出VGA有效显示区域像素点Y轴坐标,10bit
    .hsync      (hsync      ),  //输出行同步信号,1bit
    .vsync      (vsync      ),  //输出场同步信号,1bit
    .rgb        (rgb        )   //输出像素点色彩信息,16bit
);

//------------- vga_pic_inst -------------
vga_pic vga_pic_inst
(
    .vga_clk    (vga_clk    ),  //输入工作时钟,频率25MHz,1bit
    .sys_rst_n  (rst_n      ),  //输入复位信号,低电平有效,1bit
    .pix_x      (pix_x      ),  //输入VGA有效显示区域像素点X轴坐标,10bit
    .pix_y      (pix_y      ),  //输入VGA有效显示区域像素点Y轴坐标,10bit

    .pix_data   (pix_data   )   //输出像素点色彩信息,16bit

);

endmodule

VGA控制器：

module  vga_ctrl
(
    input   wire            vga_clk     ,   //输入工作时钟,频率25MHz
    input   wire            sys_rst_n   ,   //输入复位信号,低电平有效
    input   wire    [15:0]  pix_data    ,   //输入像素点色彩信息

    output  wire    [9:0]   pix_x       ,   //输出VGA有效显示区域像素点X轴坐标
    output  wire    [9:0]   pix_y       ,   //输出VGA有效显示区域像素点Y轴坐标
    output  wire            hsync       ,   //输出行同步信号
    output  wire            vsync       ,   //输出场同步信号
    output  wire    [15:0]  rgb             //输出像素点色彩信息
);

//********************************************************************//
//****************** Parameter and Internal Signal *******************//
//********************************************************************//
//parameter define
parameter H_SYNC    =   10'd96  ,   //行同步
          H_BACK    =   10'd40  ,   //行时序后沿
          H_LEFT    =   10'd8   ,   //行时序左边框
          H_VALID   =   10'd640 ,   //行有效数据
          H_RIGHT   =   10'd8   ,   //行时序右边框
          H_FRONT   =   10'd8   ,   //行时序前沿
          H_TOTAL   =   10'd800 ;   //行扫描周期
parameter V_SYNC    =   10'd2   ,   //场同步
          V_BACK    =   10'd25  ,   //场时序后沿
          V_TOP     =   10'd8   ,   //场时序上边框
          V_VALID   =   10'd480 ,   //场有效数据
          V_BOTTOM  =   10'd8   ,   //场时序下边框
          V_FRONT   =   10'd2   ,   //场时序前沿
          V_TOTAL   =   10'd525 ;   //场扫描周期

//wire  define
wire            rgb_valid       ;   //VGA有效显示区域
wire            pix_data_req    ;   //像素点色彩信息请求信号

//reg   define
reg     [9:0]   cnt_h           ;   //行同步信号计数器
reg     [9:0]   cnt_v           ;   //场同步信号计数器

//********************************************************************//
//***************************** Main Code ****************************//
//********************************************************************//

//cnt_h:行同步信号计数器
always@(posedge vga_clk or  negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        cnt_h   <=  10'd0   ;
    else    if(cnt_h == H_TOTAL - 1'd1)
        cnt_h   <=  10'd0   ;
    else
        cnt_h   <=  cnt_h + 1'd1   ;

//hsync:行同步信号
assign  hsync = (cnt_h  <=  H_SYNC - 1'd1) ? 1'b1 : 1'b0  ;

//cnt_v:场同步信号计数器
always@(posedge vga_clk or  negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        cnt_v   <=  10'd0 ;
    else    if((cnt_v == V_TOTAL - 1'd1) &&  (cnt_h == H_TOTAL-1'd1))
        cnt_v   <=  10'd0 ;
    else    if(cnt_h == H_TOTAL - 1'd1)
        cnt_v   <=  cnt_v + 1'd1 ;
    else
        cnt_v   <=  cnt_v ;

//vsync:场同步信号
assign  vsync = (cnt_v  <=  V_SYNC - 1'd1) ? 1'b1 : 1'b0  ;

//rgb_valid:VGA有效显示区域
assign  rgb_valid = (((cnt_h >= H_SYNC + H_BACK + H_LEFT)
                    && (cnt_h < H_SYNC + H_BACK + H_LEFT + H_VALID))
                    &&((cnt_v >= V_SYNC + V_BACK + V_TOP)
                    && (cnt_v < V_SYNC + V_BACK + V_TOP + V_VALID)))
                    ? 1'b1 : 1'b0;

//pix_data_req:像素点色彩信息请求信号,超前rgb_valid信号一个时钟周期
assign  pix_data_req = (((cnt_h >= H_SYNC + H_BACK + H_LEFT - 1'b1)
                    && (cnt_h < H_SYNC + H_BACK + H_LEFT + H_VALID - 1'b1))
                    &&((cnt_v >= V_SYNC + V_BACK + V_TOP)
                    && (cnt_v < V_SYNC + V_BACK + V_TOP + V_VALID)))
                    ? 1'b1 : 1'b0;

//pix_x,pix_y:VGA有效显示区域像素点坐标
assign  pix_x = (pix_data_req == 1'b1)
                ? (cnt_h - (H_SYNC + H_BACK + H_LEFT - 1'b1)) : 10'h3ff;
assign  pix_y = (pix_data_req == 1'b1)
                ? (cnt_v - (V_SYNC + V_BACK + V_TOP)) : 10'h3ff;

//rgb:输出像素点色彩信息
assign  rgb = (rgb_valid == 1'b1) ? pix_data : 16'b0 ;

endmodule

彩条图像生成：

module  vga_pic
(
    input   wire            vga_clk     ,   //输入工作时钟,频率25MHz
    input   wire            sys_rst_n   ,   //输入复位信号,低电平有效
    input   wire    [9:0]   pix_x       ,   //输入VGA有效显示区域像素点X轴坐标
    input   wire    [9:0]   pix_y       ,   //输入VGA有效显示区域像素点Y轴坐标

    output  reg     [15:0]  pix_data        //输出像素点色彩信息
);

//********************************************************************//
//****************** Parameter and Internal Signal *******************//
//********************************************************************//
//parameter define
parameter   H_VALID =   10'd640 ,   //行有效数据
            V_VALID =   10'd480 ;   //场有效数据

parameter   RED     =   16'hF800,   //红色
            ORANGE  =   16'hFC00,   //橙色
            YELLOW  =   16'hFFE0,   //黄色
            GREEN   =   16'h07E0,   //绿色
            CYAN    =   16'h07FF,   //青色
            BLUE    =   16'h001F,   //蓝色
            PURPPLE =   16'hF81F,   //紫色
            BLACK   =   16'h0000,   //黑色
            WHITE   =   16'hFFFF,   //白色
            GRAY    =   16'hD69A;   //灰色

//********************************************************************//
//***************************** Main Code ****************************//
//********************************************************************//

//pix_data:输出像素点色彩信息,根据当前像素点坐标指定当前像素点颜色数据
always@(posedge vga_clk or negedge sys_rst_n)
    if(sys_rst_n == 1'b0)
        pix_data    <= 16'd0;
    else    if((pix_x >= 0) && (pix_x < (H_VALID/10)*1))
        pix_data    <=  RED;
    else    if((pix_x >= (H_VALID/10)*1) && (pix_x < (H_VALID/10)*2))
        pix_data    <=  ORANGE;
    else    if((pix_x >= (H_VALID/10)*2) && (pix_x < (H_VALID/10)*3))
        pix_data    <=  YELLOW;
    else    if((pix_x >= (H_VALID/10)*3) && (pix_x < (H_VALID/10)*4))
        pix_data    <=  GREEN;
    else    if((pix_x >= (H_VALID/10)*4) && (pix_x < (H_VALID/10)*5))
        pix_data    <=  CYAN;
    else    if((pix_x >= (H_VALID/10)*5) && (pix_x < (H_VALID/10)*6))
        pix_data    <=  BLUE;
    else    if((pix_x >= (H_VALID/10)*6) && (pix_x < (H_VALID/10)*7))
        pix_data    <=  PURPPLE;
    else    if((pix_x >= (H_VALID/10)*7) && (pix_x < (H_VALID/10)*8))
        pix_data    <=  BLACK;
    else    if((pix_x >= (H_VALID/10)*8) && (pix_x < (H_VALID/10)*9))
        pix_data    <=  WHITE;
    else    if((pix_x >= (H_VALID/10)*9) && (pix_x < H_VALID))
        pix_data    <=  GRAY;
    else
        pix_data    <=  BLACK;

endmodule

显示结果：

 

 

 

基于FPGA的饭桶
关注
  • 4
    点赞
  • 踩
  • 16
    收藏
    觉得还不错? 一键收藏
  • 1
    评论
专栏目录
VGA显示器驱动设计与验证
ziyouruf的博客
04-01 1100
这里利用verilog语言编写一个VGA显示驱动控制器，使用FPGA开发板驱动VGA显示器进行一个十种颜色等宽彩条的显示，VGA的显示模式为640x480@60，640表示在一个完整的行扫描周期中，有效显示图像每一行有640个像素点，480表示每一帧图像有480行，60表示在该显示模式下，VGA显示器每秒刷新60次，即每秒显示60帧图像。在该模式下，行扫描周期为800，场扫描周期为525，其时钟为25.175MHz。时钟频率=行x场x帧。
01_VGA 显示器驱动设计与验证
HeElLose的博客
06-26 333
01_VGA 显示器驱动设计与验证
【FPGA】VGA显示文字、彩条、图片——基于DE2-115
最新发布
weixin_68811361的博客
05-18 1103
通过Verilog编程，在至少2种显示模式下（640*480@60Hz,1024*768@75Hz）分别实现以下VGA显示，并对照VGA协议信号做时序分析：1）屏幕上显示彩色条纹；2）显示自定义的汉字字符（姓名-学号）；3）输出一幅彩色图像。
进阶项目（7）VGA显示程序设计讲解
aoze8939的博客
09-14 1015
写在前面的话 可能大家觉得之前设计都是各种看波形，比较的单一、乏味。那么本节的内容，一定可以带给大家全新的感受，现代电子技术中，图像处理技术可谓是发展迅猛，其带给大家独特的视觉感受也总是那么的赏心悦目。这里，梦翼师兄和大家一起敲开图像世界的大门，让我们一起为之痴迷，为之陶醉。 什么是VGA？ VGA（Video Graphics Array,视频图形阵列），是IBM 于1987...
基于Verilog的VGA显示驱动
weixin_30825581的博客
12-27 322
`timescale 1ns / 1ps //////////////////////////////////////////////////////////////////////////////// module vga_ctrl( clk,rst_n, disp_ctrl, dis_data,vga_valid,rdf_rdreq, hsync,vsync,vga_r,vga_g,vga_b...
FPGA入门系列实验教程——VGA彩色信号显示.zip-综合文档
05-19
《FPGA入门系列实验教程——VGA彩色信号显示》是一份专为初学者设计的教程，旨在引导读者深入了解FPGA（Field-Programmable Gate Array）技术，并通过实践操作掌握VGA（Video Graphics Array）彩色信号的显示方法。...
基于FPGA的VGA显示之贪吃蛇小游戏.rar
03-26
本项目——“基于FPGA的VGA显示之贪吃蛇小游戏”，巧妙地结合了FPGA技术与经典的贪吃蛇游戏，为学习者提供了一个实践平台，深入理解数字逻辑设计、VGA显示原理以及实时交互控制。 首先，我们要了解VGA（Video ...
基于FPGA的VGA显示
08-20
【基于FPGA的VGA显示】是一个典型的数字系统设计项目，它涉及到电子工程中的关键领域——数字电路设计、现场可编程门阵列（FPGA）以及硬件描述语言Verilog。在这一主题中，我们将深入探讨这三个核心概念以及它们在...
基于FPGA的VGA驱动
11-29
在基于FPGA（Field-Programmable Gate Array）的设计中，VGA驱动通常由硬件逻辑实现，这涉及到数字电路设计、信号处理和实时系统控制等多个领域的知识。 一、VGA接口基础知识 VGA是一种模拟视频接口，最初在IBM个人...
FPGA EP4CE10实现OV5640摄像头拍摄，RGB-LCD显示（Verilog HDL实现）.zip
03-15
本项目涉及的核心技术是利用FPGA（Field-Programmable Gate Array）——EP4CE10，通过Verilog HDL（硬件描述语言）设计驱动程序，实现OV5640摄像头的数据采集，并将采集到的图像数据在RGB液晶显示器上进行实时显示。...
半定制设计之vga驱动电路设计
08-26
输入24bitRGB信号存放于片外SRAM，输出VGA驱动信号 （1）显示数据24bit构成MSB为R，LSB为B； （2）构造SRAM访问电路，设计输出驱动时序电路； （3）屏幕800*600；刷新时间33ms；时钟40MHz； （4）使用SMIC工艺库smic18_IP6M完成设计； （5）完成全部流程：设计规范文档、模块设计、代码输入、功能仿真、约束与综合、布局布线、物理验证。
【FPGA实验】VGA显示
qq_52445967的博客
06-07 891
VGA显示字符、彩色条幅与图像
VGA设计（原理说明。Verilog代码实现，仿真结果）
qq_44366923的博客
07-20 1389
VGA设计（原理说明。Verilog代码实现，仿真结果）
HSYNC(HS) VSYNC(VS) PCLK Polarity 都是什么？
weixin_44174312的博客
09-28 3608
Pixel clock，也叫RGB clock，也叫Dot clock，一般会简写为PCLK。极性(polarity):物体在相反部位或方向表现出相反的固有性质或力量，对特定事物的方向或吸引力。VSYNC: 帧同步信号,表示扫描1帧的开始，一帧也就是LCD显示的一个画面。行同步信号（HS或HSYNC）和场同步信号（VS或VSYNC）。行同步信号（HS）的作用是选择出液晶面板上有效行信号区间。场同步信号（VS）的作用是选择出液晶面板上有效场信号区间。HSYNC: 行同步信号，表示扫描1行的开始。
高速接口之VGA接口
xuhao0258的博客
07-10 5583
原理介绍 VGA（Video Graphics Array）即视频图形阵列，是IBM在1987年推出的使用模拟信号的一种视频传输标准，在当时具有分辨率高、显示速率快、颜色丰富等优点，在彩色显示器领域得到了广泛的应用。这个标准对于现今的个人电脑市场已经十分过时。即使如此，VGA仍然是最多制造商所共同支持的一个标准，个人电脑在加载自己的特殊驱动程序之前，都必须支持VGA的标准。 PCB-layout规则： 参考设计 a. 布局：一字形或L形； b. R、G 、B、Hsync和Vsync需要加粗 15mil，做包
FPGA学习笔记1——VGA显示
许海狗的博客
11-10 9199
VGA显示实验VGA时序主要包括两条信号线（HS,VS）的输出——行扫描和场扫描。VGA采用逐行扫描，每个像素对应的点扫描。行与行之间存在消隐以及显示时期，场与场之间也类似。行扫描可分为以下几个阶段：同步、消隐后肩、显示期、消隐前肩再到下个周期同步为一个循环，对应的是屏幕上的一行。场同步类似，对应为屏幕显示的一帧。标准的VGA屏幕比例为4：3（笔者找了好久没找到16:9的显示周期），有固定的帧率以及
FPGA基础设计（一）：VGA显示方法（文字、图形、波形）
热门推荐
FPGADesigner的博客
07-15 3万+
概述  VGA是一种学习FPGA最常见的基础实验。虽然现在的显示屏大多已经采用DVI和HDMI方案，但其实VGA在另一个地方还有应用，那就是大屏的LCD。目前4.3寸以上的TFT基本都是VGA接口，这样在完成一个FPGA系统设计时，选择一个VGA接口的TFT用来显示便是最简单方便的方案。  现在2017年全国大学生电子设计大赛还有不到一个月，熟练的使用VGA显示各种图形、文字、波形还是很重要的，而不
FPGA——用VGA时序显示图像 仿真
07-27
- *1* [FPGA学习——VGA显示](https://blog.csdn.net/weixin_56102526/article/details/124964347)[target="_blank" data-report-click={"spm":"1018.2226.3001.9630","extra":{"utm_source":"vip_chatgpt_common_...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值