Hive优化方法汇总

1、Fetch抓取

Fetch 抓取是指，Hive 中对某些情况的查询可以不必使用 MapReduce 计算。例如：SELECT * FROM employees;在这种情况下，Hive 可以简单地读取 employee 对应的存储目录下的文件，然后输出查询结果到控制台。
在 hive-default.xml.template 文件中 hive.fetch.task.conversion 默认是 more，老版本 hive 默认是 minimal，该属性修改为 more 以后，在全局查找、字段查找、limit 查找等都不走mapreduce。

<property>
	<name>hive.fetch.task.conversion</name>
	<value>more</value>
	<description>
		Expects one of [none, minimal, more].
		Some select queries can be converted to single FETCH task minimizing
		latency.
		Currently the query should be single sourced not having any subquery
		and should not have any aggregations or distincts (which incurs RS),
		lateral views and joins.
		0. none : disable hive.fetch.task.conversion
		1. minimal : SELECT STAR, FILTER on partition columns, LIMIT only
		2. more : SELECT, FILTER, LIMIT only (support TABLESAMPLE and
		virtual columns)
	</description>
</property>

（1）把 hive.fetch.task.conversion 设置成 none，然后执行查询语句，都会执行 mapreduce程序。

hive (default)> set hive.fetch.task.conversion=none;
hive (default)> select * from emp;
hive (default)> select ename from emp;
hive (default)> select ename from emp limit 3;

（2）把 hive.fetch.task.conversion 设置成 more，然后执行查询语句，如下查询方式都不会执行 mapreduce 程序。

hive (default)> set hive.fetch.task.conversion=more;
hive (default)> select * from emp;
hive (default)> select ename from emp;
hive (default)> select ename from emp limit 3;

2、本地模式

大多数的 Hadoop Job 是需要 Hadoop 提供的完整的可扩展性来处理大数据集的。不过，有时 Hive 的输入数据量是非常小的。在这种情况下，为查询触发执行任务消耗的时间可能会比实际 job 的执行时间要多的多。对于大多数这种情况，Hive 可以通过本地模式在单台机器上处理所有的任务。对于小数据集，执行时间可以明显被缩短。

用户可以通过设置 hive.exec.mode.local.auto 的值为 true，来让 Hive 在适当的时候自动启动这个优化。

set hive.exec.mode.local.auto=true; //开启本地 mr
//设置 local mr 的最大输入数据量，当输入数据量小于这个值时采用 local mr 的方式，默认为 134217728，即 128M
set hive.exec.mode.local.auto.inputbytes.max=50000000;
//设置 local mr 的最大输入文件个数，当输入文件个数小于这个值时采用 local mr 的方式，默认为 4
set hive.exec.mode.local.auto.input.files.max=10;

3、表的优化

（1）小表大表Join（MapJoin）

将 key 相对分散，并且数据量小的表放在 join 的左边，可以使用MapJoin 让小的维度表先进内存。MapJoin 是将 Join 双方比较小的表直接分发到各个 Map 进程的内存中，在 Map 进行 Join 操 作，这样就不用进行 Reduce 步骤，从而提高了速度。

实际测试发现：新版的 hive 已经对小表 JOIN 大表和大表 JOIN 小表进行了优化。小表放在左边和右边已经没有区别。

开启 MapJoin 参数设置：
1）设置自动选择 Mapjoin

set hive.auto.convert.join = true; 默认为 true
1
2）大表小表的阈值设置（默认 25M 以下认为是小表）：

set hive.mapjoin.smalltable.filesize = 25000000;
1
注意：此处讨论的大表和小表的inner join（即join），对于小表左连接大表作为主表，所有数据都要写出去，因此此时会走 reduce，mapjoin失效。

（2）大表Join大表

1）空KEY过滤
有时 join 超时是因为某些 key 对应的数据太多，而相同 key 对应的数据都会发送到相同的 reducer 上，从而导致内存不够。此时我们应该仔细分析这些异常的 key，很多情况下，这些 key 对应的数据是异常数据，我们需要在 SQL 语句中进行过滤。
使用场景：① 非inner join；② 不需要字段为NULL的

不过滤空 id

hive (default)> insert overwrite table jointable select n.* from 
nullidtable n left join bigtable o on n.id = o.id;

过滤空 id

hive (default)> insert overwrite table jointable select n.* from 
(select * from nullidtable where id is not null) n 
left join bigtable o on n.id =o.id;

2）空Key转换
有时虽然某个 key 为空对应的数据很多，但是相应的数据不是异常数据，必须要包含在join 的结果，此时我们可以表 a 中 key 为空的字段赋一个随机的值，使得数据随机均匀地分部到不同的reducer上。

随机分布空 null 值：

insert overwrite table jointable select n.* from 
nullidtable n full join bigtable o on nvl(n.id,rand()) = o.id;

3）SMB(Sort Merge Bucket join)
对于两个都没有空Key的大表，采用按Join字段分桶后再进行Join。

创建分通表 1,桶的个数不要超过可用 CPU 的核数

create table bigtable_buck1(
id bigint,
t bigint,
uid string,
keyword string)
clustered by(id)
sorted by(id)
into 6 buckets
row format delimited fields terminated by '\t';
load data local inpath '/opt/module/data/bigtable' into table
bigtable_buck1;

创建分通表 2,桶的个数不要超过可用 CPU 的核数

create table bigtable_buck2(
id bigint,
t bigint,
uid string,
keyword string)
clustered by(id)
sorted by(id)
into 6 buckets
row format delimited fields terminated by '\t';
load data local inpath '/opt/module/data/bigtable' into table bigtable_buck2;

设置参数

set hive.optimize.bucketmapjoin = true;
set hive.optimize.bucketmapjoin.sortedmerge = true;
set hive.input.format=org.apache.hadoop.hive.ql.io.BucketizedHiveInputFormat;

分桶后Join

insert overwrite table jointable
select b.id, b.t, b.uid, b.keyword
from bigtable_buck1 s
join bigtable_buck2 b
on b.id = s.id;

（3）Group By

默认情况下，Map 阶段同一 Key 数据分发给一个 reduce，当一个 key 数据过大时就倾斜了。并不是所有的聚合操作都需要在 Reduce 端完成，很多聚合操作都可以先在 Map 端进行部分聚合，最后在Reduce 端得出最终结果。

开启 Map 端聚合参数设置：
1）是否在 Map 端进行聚合，默认为 True

set hive.map.aggr = true

2）在 Map 端进行聚合操作的条目数目

set hive.groupby.mapaggr.checkinterval = 100000

3）有数据倾斜的时候进行负载均衡（默认是 false）

set hive.groupby.skewindata = true

当选项设定为 true，生成的查询计划会有两个 MR Job。第一个 MR Job 中，Map 的输出结果会随机分布到 Reduce 中，每个 Reduce 做部分聚合操作，并输出结果，这样处理的结果是相同的 Group By Key 有可能被分发到不同的 Reduce 中，从而达到负载均衡的目的；第二个 MR Job 再根据预处理的数据结果按照 Group By Key 分布到 Reduce 中（这个过程可以保证相同的 Group By Key 被分布到同一个 Reduce 中），最后完成最终的聚合操作。

（4）Count(Distinct）去重统计

数据量小的时候无所谓，数据量大的情况下，由于 COUNT DISTINCT 操作需要用一个Reduce Task 来完成，这一个 Reduce 需要处理的数据量太大，就会导致整个 Job 很难完成，一般 COUNT DISTINCT 使用先 GROUP BY 再 COUNT 的方式替换,但是需要注意 group by 造成的数据倾斜问题。

执行去重 id 查询：

select count(distinct id) from bigtable;

采用 GROUP by 去重 id：

hive (default)> select count(id) from (select id from bigtable group by id) a;

注：虽然会多用一个 Job 来完成，但在数据量大的情况下，这个是值得的。

（5）笛卡尔积

尽量避免笛卡尔积，join 的时候不加 on 条件，或者无效的 on 条件，Hive 只能使用 1 个reducer 来完成笛卡尔积。

（6）行列过滤

列处理：在 SELECT 中，只拿需要的列，如果有分区，尽量使用分区过滤，少用 SELECT *。

行处理：在分区剪裁中，当使用外关联时，如果将副表的过滤条件写在 Where 后面，那么就会先全表关联，之后再过滤，比如：

案例实操：
1 ）先关联两张表，再用 where 条件过滤

hive (default)> select o.id from bigtable b
join bigtable o on o.id = b.id
where o.id <= 10;
Time taken: 34.406 seconds, Fetched: 100 row(s)

2 ） 通过子查询后，再关联表

hive (default)> select b.id from bigtable b
join (select id from bigtable where id <= 10) o on b.id = o.id;
Time taken: 30.058 seconds, Fetched: 100 row(s)

这种过滤在系统中一般都做了优化，所谓的“谓词下推”技术：即将外层查询块的 WHERE 子句中的谓词移入所包含的较低层查询块，从而能够提早进行数据过滤以及有可能更好地利用索引。但对于较复杂的语句存在可能导致这个优化失效，所以我们最好先手动去过滤。

（7）分区

分区表实际上就是对应一个 HDFS 文件系统上的独立的文件夹，该文件夹下是该分区所有的数据文件。Hive 中的分区就是分目录，把一个大的数据集根据业务需要分割成小的数据集。在查询时通过 WHERE 子句中的表达式选择查询所需要的指定的分区，这样的查询效率会提高很多。

创建分区表：

create table dept_partition(
deptno int, dname string, loc string
partitioned by (day string)
row format delimited fields terminated by '\t';

加载数据：

hive  (default)>  load data local inpath
'/opt/module/hive/datas/dept_20200401.log' into table dept_partition
partition(day='20200401');
hive  (default)>  load data local inpath
'/opt/module/hive/datas/dept_20200402.log'  into  table  dept_partition
partition(day='20200402');

单分区查询：

hive (default)> select * from dept_partition where day='20200401';

（8）分桶

分区提供一个隔离数据和优化查询的便利方式。不过，并非所有的数据集都可形成合理的分区。对于一张表或者分区，Hive 可以进一步组织成桶，也就是更为细粒度的数据范围划分。

分桶将整个数据内容安装某列属性值得hash值进行区分，如按照name属性分为3个桶，就是对name属性值的hash值对3取摸，按照取模结果对数据分桶。如取模结果为0的数据记录存放到一个文件，取模为1的数据存放到一个文件，取模为2的数据存放到一个文件。

分桶是将数据集分解成更容易管理的若干部分的另一个技术。

分区针对的是数据的存储路径；分桶针对的是数据文件。

创建分桶表：

create table stu_buck(id int, name string)
clustered by(id)
into 4 buckets
row format delimited fields terminated by '\t';

4、合理设置Map和Reduce数

1 ）通常情况下，作业会通过 input 的目录产生一个或者多个 map 任务。主要的决定因素有：input 的文件总个数，input 的文件大小，集群设置的文件块大小。
2 ）是不是 map 数越多越好？
答案是否定的。如果一个任务有很多小文件（远远小于块大小 128m），则每个小文件也会被当做一个块，用一个 map 任务来完成，而一个 map 任务启动和初始化的时间远远大于逻辑处理的时间，就会造成很大的资源浪费。而且，同时可执行的 map 数是受限的。
3 ）是不是保证每个 map 处理接近 128m 的文件块，就高枕无忧了？
答案也是不一定。比如有一个 127m 的文件，正常会用一个 map 去完成，但这个文件只有一个或者两个小字段，却有几千万的记录，如果 map 处理的逻辑比较复杂，用一个 map任务去做，肯定也比较耗时。

（1）复杂文件增加Map数

当 input 的文件都很大，任务逻辑复杂，map 执行非常慢的时候，可以考虑增加 Map 数，来使得每个 map 处理的数据量减少，从而提高任务的执行效率。

增加 map 的方法为：根据computeSliteSize(Math.max(minSize,Math.min(maxSize,blocksize)))=blocksize=128M
公式，调整 maxSize 最大值。让 maxSize 最大值低于 blocksize 就可以增加 map 的个数。

（2）小文件进行合并

1 ）在 map 执行前合并小文件，减少 map 数：CombineHiveInputFormat 具有对小文件进行合并的功能（系统默认的格式）。HiveInputFormat 没有对小文件合并功能。

set hive.input.format=org.apache.hadoop.hive.ql.io.CombineHiveInputFormat;

2 ）在 Map-Reduce 的任务结束时合并小文件的设置：在 map-only 任务结束时合并小文件，默认 true

SET hive.merge.mapfiles = true;

在 map-reduce 任务结束时合并小文件，默认 false

SET hive.merge.mapredfiles = true;

合并文件的大小，默认 256M

SET hive.merge.size.per.task = 268435456;

当输出文件的平均大小小于该值时，启动一个独立的 map-reduce 任务进行文件 merge

SET hive.merge.smallfiles.avgsize = 16777216;

（3）合理设置Reduce数

调整 reduce 个数方法一：
1）每个 Reduce 处理的数据量默认是 256MB

hive.exec.reducers.bytes.per.reducer=256000000

2）每个任务最大的 reduce 数，默认为 1009

hive.exec.reducers.max=1009

3）计算 reducer 数的公式

N=min(参数 2，总输入数据量/参数 1)

调整 reduce 个数方法二：
在 hadoop 的 mapred-default.xml 文件中修改设置每个 job 的 Reduce 个数

set mapreduce.job.reduces = 15;

注：set mapreduce.job.reduces =-1时是走的第一个计算方法。

reduce 个数并不是越多越好
（1）过多的启动和初始化 reduce 也会消耗时间和资源；
（2）另外，有多少个 reduce，就会有多少个输出文件，如果生成了很多个小文件，那么如果这些小文件作为下一个任务的输入，则也会出现小文件过多的问题；

在设置 reduce 个数的时候也需要考虑这两个原则：处理大数据量利用合适的 reduce 数；使单个 reduce 任务处理数据量大小要合适；

5、并行执行

Hive 会将一个查询转化成一个或者多个阶段。这样的阶段可以是 MapReduce 阶段、抽样阶段、合并阶段、limit 阶段。或者 Hive 执行过程中可能需要的其他阶段。默认情况下，Hive 一次只会执行一个阶段。不过，某个特定的 job 可能包含众多的阶段，而这些阶段可能并非完全互相依赖的，也就是说有些阶段是可以并行执行的，这样可能使得整个 job 的执行时间缩短。不过，如果有更多的阶段可以并行执行，那么 job 可能就越快完成。

通过设置参数 hive.exec.parallel 值为 true，就可以开启并发执行。不过，在共享集群中，需要注意下，如果 job 中并行阶段增多，那么集群利用率就会增加。

set hive.exec.parallel=true; //打开任务并行执行
set hive.exec.parallel.thread.number=16; //同一个 sql 允许最大并行度，默认为8。

当然，得是在系统资源比较空闲的时候才有优势，否则，没资源，并行也起不来。

6、严格模式

Hive 可以通过设置防止一些危险操作：

（1） 分区表不使用分区过滤

将 hive.strict.checks.no.partition.filter 设置为 true 时，对于分区表，除非 where 语句中含有分区字段过滤条件来限制范围，否则不允许执行。换句话说，就是用户不允许扫描所有分区。进行这个限制的原因是，通常分区表都拥有非常大的数据集，而且数据增加迅速。没有进行分区限制的查询可能会消耗令人不可接受的巨大资源来处理这个表。

（2） 使用 order by 没有 limit 过滤

将 hive.strict.checks.orderby.no.limit 设置为 true 时，对于使用了 order by 语句的查询，要求必须使用 limit 语句。因为 order by 为了执行排序过程会将所有的结果数据分发到同一个Reducer 中进行处理，强制要求用户增加这个 LIMIT 语句限制发送到Reducer的数量，防止 Reducer 额外执行很长一段时间。

（3） 笛卡尔积

将 hive.strict.checks.cartesian.product 设置为 true 时，会限制笛卡尔积的查询。对关系型数据库非常了解的用户可能期望在 执行 JOIN 查询的时候不使用 ON 语句而是使用 where 语句，这样关系数据库的执行优化器就可以高效地将 WHERE 语句转化成那个 ON 语句。不幸的是，Hive 并不会执行这种优化，因此，如果表足够大，那么这个查询就会出现不可控的情况。

7、JVM重用

默认情况下，每个 Task 任务都需要启动一个 JVM 来运行，如果 Task 任务计算的数据量很小，我们可以让同一个 Job 的多个 Task 运行在一个 JVM 中，不必为每个 Task 都开启一个 JVM。主要针对小文件。

开启 uber 模式，在 mapred-site.xml 中添加如下配置：

<!-- 开启 uber 模式，默认关闭 -->
<property>
	<name>mapreduce.job.ubertask.enable</name>
	<value>true</value>
</property>

8、压缩

Map输出阶段压缩：
开启 map 输出阶段压缩可以减少 job 中 map 和 Reduce task 间数据传输量。
（1）开启 hive 中间传输数据压缩功能

hive (default)>set hive.exec.compress.intermediate=true;

（2）开启 mapreduce 中 map 输出压缩功能

hive (default)>set mapreduce.map.output.compress=true;

（3）设置 mapreduce 中 map 输出数据的压缩方式

hive (default)>set mapreduce.map.output.compress.codec= 
org.apache.hadoop.io.compress.SnappyCodec;

————————————————
版权声明：本文为CSDN博主「南洲.」的原创文章，遵循CC 4.0 BY-SA版权协议，转载请附上原文出处链接及本声明。
原文链接：https://blog.csdn.net/zhou4411781/article/details/120049657