hive（二）DDL和DML（详细且易懂）！！！

最新推荐文章于 2024-07-30 09:00:34 发布

复姓独孤

最新推荐文章于 2024-07-30 09:00:34 发布

阅读量1.3k

点赞数 3

分类专栏： Bigdata # hive

本文链接：https://blog.csdn.net/weixin_45077780/article/details/107377897

版权

Bigdata 同时被 2 个专栏收录

24 篇文章 2 订阅

订阅专栏

hive

9 篇文章 0 订阅

订阅专栏

目录标题

第 4 章 DDL 数据定义
第 5 章 DML 数据操作

第 4 章 DDL 数据定义

4.1 创建数据库

1）创建一个数据库，数据库在 HDFS 上的默认存储路径是/user/hive/warehouse/*.db。
hive (default)> create database db_hive;
2）避免要创建的数据库已经存在错误，增加 if not exists 判断。（标准写法）
hive (default)> create database if not exists db_hive;
3）创建一个数据库，指定数据库在 HDFS 上存放的位置
hive (default)> create database db_hive2 location ‘/db_hive2.db’;
4)default这个库在路径下不显示库名，我们可不可以创建类似的库呢？当然可以啦！
- 首先在命令行写命令在hdfs上创建文件
- 接着创建不显示库名的库banzhang：
  create database banzhang location ‘/database/hive2’;
  
  这时没有库名显示
  我们在此库创建表看看：
  
  显示表了，不显示库名。

4.2 查询数据库

4.2.1 显示数据库

1．显示数据库
hive> show databases;
2．过滤显示查询的数据库
hive> show databases like ‘db_hive*’;
4.2.2 查看数据库详情
1．显示数据库信息
hive> desc database db_hive;

2．显示数据库详细信息，extended
hive> desc database extended db_hive;

4.2.3 切换当前数据库

hive (default)> use db_hive;

4.3 修改数据库

用户可以使用 ALTER DATABASE 命令为某个数据库的 DBPROPERTIES 设置键-值对属性值，来描述这个数据库的属性信息。数据库的其他元数据信息都是不可更改的，包括数据库名和数据库所在的目录位置。
例如：alter database db_hive set dbproperties(‘createtime’=‘20170830’);
在 hive 中查看修改结果

4.4 删除数据库

删除空库： drop database if exists 库名;
删除非空库：可以采用 cascade 命令，强制删除
- drop database 库名 cascade;

4.5创建表

1．建表语法
CREATE [EXTERNAL] TABLE [IF NOT EXISTS] table_name
[(col_name data_type [COMMENT col_comment], …)]
[COMMENT table_comment]
[PARTITIONED BY (col_name data_type [COMMENT col_comment], …)]
[CLUSTERED BY (col_name, col_name, …)
[SORTED BY (col_name [ASC|DESC], …)] INTO num_buckets BUCKETS]
[ROW FORMAT row_format]
[STORED AS file_format]
[LOCATION hdfs_path]
2．字段解释说明
（1）CREATE TABLE 创建一个指定名字的表。如果相同名字的表已经存在，则抛出异常；用户可以用 IF NOT EXISTS 选项来忽略这个异常。
（2）EXTERNAL 关键字可以让用户创建一个外部表，在建表的同时指定一个指向实际数据的路径（LOCATION），Hive 创建内部表时，会将数据移动到数据仓库指向的路径；若创建外部表，仅记录数据所在的路径，不对数据的位置做任何改变。在删除表的时候，内部表的元数据和数据会被一起删除，而外部表只删除元数据，不删除数据。
（3）COMMENT：为表和列添加注释。
（4）PARTITIONED BY 创建分区表
（5）CLUSTERED BY 创建分桶表
（6）SORTED BY 不常用
（7）ROW FORMAT
DELIMITED [FIELDS TERMINATED BY char] [COLLECTION ITEMS
TERMINATED BY char]
[MAP KEYS TERMINATED BY char] [LINES TERMINATED BY char]
| SERDE serde_name [WITH SERDEPROPERTIES (property_name=property_value,
property_name=property_value, …)]
用户在建表的时候可以自定义 SerDe 或者使用自带的 SerDe。如果没有指定 ROW
FORMAT 或者 ROW FORMAT DELIMITED，将会使用自带的 SerDe。在建表的时候，用户
还需要为表指定列，用户在指定表的列的同时也会指定自定义的 SerDe，Hive 通过 SerDe
确定表的具体的列的数据。
SerDe 是 Serialize/Deserilize 的简称，目的是用于序列化和反序列化。
（8）STORED AS 指定存储文件类型
常用的存储文件类型：SEQUENCEFILE（二进制序列文件）、TEXTFILE（文本）、
RCFILE（列式存储格式文件）
如果文件数据是纯文本，可以使用 STORED AS TEXTFILE。如果数据需要压缩，
使用 STORED AS SEQUENCEFILE。
（9）LOCATION ：指定表在 HDFS 上的存储位置。
（10）LIKE 允许用户复制现有的表结构，但是不复制数据

4.5.1 管理表

1．理论
默认创建的表都是所谓的管理表，有时也被称为内部表。因为这种表，Hive 会（或多或少地）控制着数据的生命周期。Hive 默认情况下会将这些表的数据存储在由配置项hive.metastore.warehouse.dir(例如，/user/hive/warehouse)所定义的目录的子目录下。当我们删除一个管理表时，Hive 也会删除这个表中数据。管理表不适合和其他工具共享数据。
2．案例实操
（1）普通创建表
create table if not exists student2(id int, name string) row format delimited fields terminated by ‘\t’ stored as textfile
location ‘/user/hive/warehouse/student2’;
（2）根据查询结果创建表（查询的结果会添加到新创建的表中）
create table if not exists student3 as select id, name from student;
（3）根据已经存在的表结构创建表
create table if not exists student4 like student;
（4）查询表的类型
hive (default)> desc formatted student2;

4.5.2 外部表

1．理论
因为表是外部表，所以 Hive 并非认为其完全拥有这份数据。,删除该表并不会删除掉这份数据，不过描述表的元数据信息会被删除掉。
2．管理表和外部表的使用场景
每天将收集到的网站日志定期流入 HDFS 文本文件。在外部表（原始日志表）的基础上做大量的统计分析，用到的中间表、结果表使用内部表存储，数据通过 SELECT+INSERT进入内部表。
3．案例实操
（1）分别创建部门和员工外部表，并向表中导入数据,分别是部门表数据和员工表数据。
（2）建表语句
创建部门表

create external table if not exists dept(
deptno int,
dname string,
loc int
)
row format delimited fields terminated by '\t';

创建员工表

create external table if not exists emp(
empno int,
ename string,
job string,
mgr int,
hiredate string, 
sal double, 
comm double,
deptno int)
row format delimited fields terminated by '\t';

（3）查看创建的表
在这里插入图片描述
（4）向外部表中导入数据

load data local inpath 
'/opt/module/data/dept.txt' into table dept;

load data local inpath 
'/opt/module/data/emp.txt' into table emp;

查看：
在这里插入图片描述

4.5.3 管理表与外部表的互相转换

在这里插入图片描述
修改内部表 student2 为外部表
alter table student2 set tblproperties(‘EXTERNAL’=‘TRUE’);

\修改外部表 student2 为内部表 alter table student2 set tblproperties(‘EXTERNAL’=‘FALSE’);
注意：(‘EXTERNAL’=‘TRUE’)和(‘EXTERNAL’=‘FALSE’)为固定写法，区分大小写！

4.6 分区表

分区表实际上就是对应一个 HDFS 文件系统上的独立的文件夹，该文件夹下是该分区所有的数据文件。Hive 中的分区就是分目录，把一个大的数据集根据业务需要分割成小的数据集。在查询时通过 WHERE 子句中的表达式选择查询所需要的指定的分区，这样的查询效率会提高很多。

谓词下推：优化关系 SQL 查询的一项基本技术，是将外层查询块的 WHERE子句中的谓词移入所包含的较低层查询块（例如视图），从而能够提早进行数据过滤以及有可能更好地利用索引。

4.6.1 分区表基本操作

1．引入分区表（需要根据日期对日志进行管理）

/user/hive/warehouse/log_partition/20170702/20170702.log
/user/hive/warehouse/log_partition/20170703/20170703.log
/user/hive/warehouse/log_partition/20170704/20170704.log

2．创建分区表语法

hive (default)> create table dept_partition(
deptno int, dname string, loc string
)
partitioned by (month string)
row format delimited fields terminated by '\t';

3．加载数据到分区表中

hive (default)> load data local inpath 
'/opt/module/data/dept.txt' into table dept_partition 
partition(month='201709');
hive (default)> load data local inpath 
'/opt/module/data/dept.txt' into table dept_partition 
partition(month='201708');
hive (default)> load data local inpath 
'/opt/module/data/dept.txt' into table dept_partition 
partition(month='201707’);

在这里插入图片描述

4．查询分区表中数据
单分区查询

hive (default)> select * from dept_partition where month='201709';

多分区联合查询

hive (default)> select * from dept_partition where 
month='201709'
 union
 select * from dept_partition where month='201708'
 union
 select * from dept_partition where month='201707';

结果：
在这里插入图片描述
5.增加分区
创建单个分区

hive (default)> alter table dept_partition add partition(month='201706') ;

在这里插入图片描述
同时创建多个分区（用空格隔开）

alter table dept_partition add partition(month='201705') partition(month='201704');

在这里插入图片描述
也可以手动用hdfs上传

hadoop fs -put /opt/module/data/dept.txt /user/hive/warehouse/dept_partition/month=201705

上传成功了
在这里插入图片描述
查询发现也能访问

6.删除分区
删除单个分区

hive (default)> alter table dept_partition drop partition(month='201704');

删除多个分区

hive (default)> alter table dept_partition drop partition 
(month='201705'), partition (month='201706');

注意，添加多个分区，每个分区中间是空格，删除多个分区，每个分区之间是逗号

7．查看分区表有多少分区

hive> show partitions dept_partition;

8．查看分区表结构

hive> desc formatted dept_partition;

4.6.2 分区表注意事项

1．创建二级分区表

hive (default)> create table dept_partition2(
 deptno int, dname string, loc string
 )
 partitioned by (month string, day string)
 row format delimited fields terminated by '\t';

2.正常的加载数据
（1）加载数据到二级分区表中

hive (default)> load data local inpath 
'/opt/module/data/dept.txt' into table 
dept_partition2 partition(month='201709', day='13');

（2）查询分区数据

hive (default)> select * from dept_partition2 where 
month='201709' and day='13';

二级分区实际就是两层目录，跟一级分区用起来是一样的
在这里插入图片描述
3．把数据直接上传到分区目录上，让分区表和数据产生关联的三种方式
（1）方式一：上传数据后修复

hive (default)> dfs -mkdir -p
/user/hive/warehouse/dept_partition2/month=201709/day=12;
hive (default)> dfs -put /opt/module/datas/dept.txt 
/user/hive/warehouse/dept_partition2/month=201709/day=12;

查询数据（查询不到刚上传的数据）

hive (default)> select * from dept_partition2 where 
month='201709' and day='12';

执行修复命令

hive> msck repair table dept_partition2;

再次查询数据

hive (default)> select * from dept_partition2 where 
month='201709' and day='12';

（2）方式二：上传数据后添加分区
上传数据

hive (default)> dfs -mkdir -p
/user/hive/warehouse/dept_partition2/month=201709/day=11;
hive (default)> dfs -put /opt/module/datas/dept.txt 
/user/hive/warehouse/dept_partition2/month=201709/day=11;
执行添加分区
hive (default)> alter table dept_partition2 add 
partition(month='201709',
day='11');

查询数据

hive (default)> select * from dept_partition2 where month='201709' and day='11';

（3）方式三：创建文件夹后 load 数据到分区
创建目录

hive (default)> dfs -mkdir -p
/user/hive/warehouse/dept_partition2/month=201709/day=10;

上传数据

hive (default)> load data local inpath 
'/opt/module/datas/dept.txt' into table
dept_partition2 partition(month='201709',day='10');

查询数据

hive (default)> select * from dept_partition2 where 
month='201709' and day='10';

4.7 修改表

4.7.1 重命名表

1．语法

ALTER TABLE table_name RENAME TO new_table_name

2．实操案例

hive (default)> alter table dept_partition2 rename to 
dept_partition3;

4.7.2 增加、修改和删除表分区

详见 4.6.1 分区表基本操作。

4.7.3 增加/修改/替换列信息

1．语法
更新列

ALTER TABLE table_name CHANGE [COLUMN] col_old_name col_new_name column_type [COMMENT col_comment] [FIRST|AFTER column_name]

增加和替换列

ALTER TABLE table_name ADD|REPLACE COLUMNS (col_name data_type [COMMENT col_comment], ...)

注：ADD 是代表新增一字段，字段位置在所有列后面(partition 列前)，REPLACE 则是表示替换表中所有字段。
2．实操案例
（1）查询表结构

hive> desc dept_partition;

（2）添加列

hive (default)> alter table dept_partition add columns(deptdesc string);

（3）查询表结构

hive> desc dept_partition;

在这里插入图片描述

（4）更新列

hive (default)> alter table dept_partition change column deptdesc desc int;

（5）查询表结构

hive> desc dept_partition;

在这里插入图片描述

（6）替换列

hive (default)> alter table dept_partition replace columns(deptno string, dname string, loc string);

（7）查询表结构

hive> desc dept_partition;

4.8 删除表

hive (default)> drop table dept_partition;

4.9 hive 静态分区和动态分区

hive的分区有两种：静态分区和动态分区

4.9.1 静态分区

静态分区
1、创建分区表

hive> create table stu2(
    > id int,
    > name string,
    > likes array<string>,
    > adress map<string,string>
    > )
    > partitioned by (age int,sex string)
    > row format delimited
    > fields terminated by ','
    > collection items terminated by '-'
    > map keys terminated by ':'
    > lines terminated by '\n';

2、加载数据到分区表

hive> load data local inpath '/opt/soft/stu.txt' into table stu2
    > partition (age=20,sex="male");

alter table stu2 add partition(age=10,sex='female'); 
// 

show partitions stu2;   // 查看分区

alter table stu2 drop partition(age=10,sex='female');//删除分区

这种手动指定分区加载数据，就是常说的静态分区的使用。但是在日常工作中用的比较多的是动态分区。
静态分区是在创建表的时候就指定分区或者将表已经创建之后再指定分区（使用alter关键字）

4.9.2 动态分区

1、创建目标表

hive> create table stuo1(
    > id int,
    > name string,
    > age int,
    > gender string,
    > likes array<string>,
    > address map<string,string>
    > )
    > row format delimited
    > fields terminated by ','
    > collection items terminated by '-'
    > map keys terminated by ':'
    > lines terminated by '\n';

hive> create table stuo2(
    > id int,
    > name string,
    > likes array<string>,
    > address map<string,string>
    > )
    > partitioned by (age int,gender string)
    > row format delimited
    > fields terminated by ','
    > collection items terminated by '-'
    > map keys terminated by ':'
    > lines terminated by '\n';

2、采用动态方式加载数据到目标表
加载之前先设置一下下面的参数

hive> set hive.exec.dynamic.partition=true;
hive> set hive.exec.dynamic.partition.mode=nonstrict;

开始加载

hive> insert into table stuo2 partition(age,gender)
    > select id,name,likes,address,age,gender from stuo1;

上面加载数据方式并没有指定具体的分区，只是指出了分区字段。在select最后一个字段必须跟你的分区字段，这样就会自行根据(age,gender)的value来分区。

创建动态分区表：
首先是要创建静态分区表；然后将表设置为非严格模式；再次创建动态分区表，并加载数据。
加载数据的时候，是按照静态分区的模式，将数据加载到动态分区中去。

第 5 章 DML 数据操作

5.1 数据导入

5.1.1 向表中装载数据（Load）

1．语法

hive> load data [local] inpath '/opt/module/data/student.txt' [overwrite] | into table student [partition (partcol1=val1,…)];

（1）load data:表示加载数据
（2）local:表示从本地加载数据到 hive 表；否则从 HDFS 加载数据到 hive 表
（3）inpath:表示加载数据的路径
（4）overwrite:表示覆盖表中已有数据，否则表示追加
（5）into table:表示加载到哪张表
（6）student:表示具体的表
（7）partition:表示上传到指定分区
2．实操案例
（0）创建一张表

hive (default)> create table student(id string, name string) row format delimited fields terminated by '\t';

（1）加载本地文件到 hive

hive (default)> load data local inpath '/opt/module/data/student.txt' into table default.student;

（2）加载 HDFS 文件到 hive 中
上传文件到 HDFS

hive (default)> dfs -put /opt/module/data/student.txt /user/liuyongjun/hive;

加载 HDFS 上数据

hive (default)> load data inpath '/user/liuyongjun/hive/student.txt' into table default.student;

（3）加载数据覆盖表中已有的数据
上传文件到 HDFS

hive (default)> dfs -put /opt/module/datas/student.txt /user/liuyongjun/hive;

加载数据覆盖表中已有的数据

hive (default)> load data inpath '/user/liuyongjun/hive/student.txt' overwrite into table default.student;

5.1.2 通过查询语句向表中插入数据（Insert）

1．创建一张分区表

hive (default)> create table student(id int, name string) partitioned by (month string) row format delimited fields terminated by '\t';

2．基本插入数据

hive (default)> insert into table student partition(month='201709') values(1,'wangwu');

3．基本模式插入（根据单张表查询结果）

insert into table student partition(month='201708') select id, name from student where month='201709';

在这里插入图片描述

覆盖

hive (default)> insert overwrite table student partition(month='201707') select id, name from student where month='201709';

4．多插入模式（根据多张表查询结果）

hive (default)> from student
 insert overwrite table student 
partition(month='201706')
 select id, name where month='201709'
 insert overwrite table student 
partition(month='201705')
 select id, name where month='201709';

5.1.3 查询语句中创建表并加载数据（As Select）

详见 4.5.1 章创建表。
根据查询结果创建表（查询的结果会添加到新创建的表中）

create table if not exists student3 as select id, name from student;

5.1.4 创建表时通过 Location 指定加载数据路径

1．创建表，并指定在 hdfs 上的位置

hive (default)> create table if not exists student5(
 id int, name string
 )
 row format delimited fields terminated by '\t'
 location '/user/hive/warehouse/student5';

2．上传数据到 hdfs 上

 hive (default)> dfs -put /opt/module/data/student.txt /user/hive/warehouse/student5;

3．查询数据

hive (default)> select * from student5;

5.1.5 Import 数据到指定 Hive 表中

注意：先用 export 导出后，再将数据导入。

hive (default)> import table student2 partition(month='201709') from '/user/hive/warehouse/export/student';

5.2 数据导出

5.2.1 Insert 导出

1．将查询的结果导出到本地

hive (default)> insert overwrite local directory '/opt/module/data/export/dept' select * from dept;

2．将查询的结果格式化导出到本地

hive(default)>insert overwrite local directory '/opt/module/data/export/dept1' row format delimited fields terminated by '\t' select * from dept;

3．将查询的结果导出到 HDFS 上(没有 local)

hive (default)> insert overwrite directory '/dept' row format delimited fields terminated by '\t' select * from dept;

5.2.2 Hadoop 命令导出到本地

hive (default)> dfs -get 
/user/hive/warehouse/student/month=201709/000000_0
/opt/module/data/export/student3.txt;

5.2.3 Hive Shell 命令导出

基本语法：（hive -f/-e 执行语句或者脚本 > file）

[liuyongjun@hadoop102 hive]$ bin/hive -e 'select * from 
default.student;' >
/opt/module/datas/export/student4.txt;

5.2.4 Export 导出到 HDFS 上

hive (default)> export table default.student to
'/user/hive/warehouse/export/student';

5.2.5 Sqoop 导出

后续课程专门讲。

5.3 清除表中数据（Truncate）

注意：Truncate 只能删除管理表，不能删除外部表中数据

hive (default)> truncate table student;

复姓独孤

关注

3
点赞
踩
6

收藏

觉得还不错? 一键收藏
0
评论
复制链接

分享到 QQ

分享到新浪微博

扫一扫

专栏目录