学习参考:CMake实践.pdf
一、CMake简介
1.特点
(1)开放源代码,使用类BSD许可发布。
(2)跨平台,并可生成native编译配置文件,在Linux/Unix平台,生成makefile,在 苹果平台,可以生成xcode,在Windows平台,可以生成MSVC的工程文件。
(3)能够管理大型项目。
(4)简化编译构建过程和编译过程。Cmake的工具链非常简单:cmake+make。
(5)高效率
(6)可扩展,可以为cmake编写特定功能的模块,扩充cmake功能。
2.缺点
(1)cmake没那么简单。
(2)cmake编写的过程实际上是编程的过程,跟以前使用autotools一样,不过你需要编写的是CMakeLists.txt(每个目录一个) ,使用的是 cmake ” 语言和语法 。
(3)cmake跟已有体系的配合并不是特别理想,比如pkgconfig,虽然有一些扩展可以使用,但并不理想。
二、从hello world开始
1.建立cmake练习目录,新建相关文件
cd /data
mkdir cmake
cd cmake
mkdir demo1
cd demo1
在demo1中新建main.c和CMakeList.txt
//main.cpp
#include<stdio.h>
int main(){
printf("Hello 28 World!\n");
return 0;
}
PROJECT (HELLO)
SET(SRC_LIST main.c)
MESSAGE(STATUS "This is BINARY dir " ${HELLO_BINARY_DIR})
MESSAGE(STATUS "This is SOURCE dir "${HELLO_SOURCE_DIR})
ADD_EXECUTABLE(hello SRC_LIST)
2.开始构建
cd /data/cmake/demo1
mkdir build
cd build
cmake ..
我们推荐采用外部构建,构建过程中生成的文件全部存在build文件夹中,避免与原文件夹中的文件混杂在一块。
build中自动生成了 CMakeFiles, CMakeCache.txt, cmake_install.cmake等文件,并且生成了 Makefile。紧接着输入make完成构建,得到可执行文件hello,使用./hello运行该可执行文件,得到输出Hello 28 World!
3.命令说明
PROJECT (HELLO)
# PROJECT指令的语法是:
# PROJECT(projectname [CXX] [C] [Java])
# 作用:定义工程的名称 支持语言的列表可以忽略
# 该指令隐式的定义了两个cmake变量
# PROJECT_BINARY_DIR 二进制文件目录,这里是/data/cmake/demo1/build
# PROJECT_SOURCE_DIR 源文件目录,这里是/data/cmake/demo1
# 上述两个变量等价于HELLO_BINARY_DIR、HELLO_SOURCE_DIR
SET(SRC_LIST main.c)
# SET指令的语法是:
# SET(VAR [VALUE] [CACHE TYPE DOCSTRING [FORCE]])
# SET指令可以用来显式的定义变量,如果有多个源文件,也可以定义成:
# SET(SRC_LIST main.c t1.c t2.c)。
MESSAGE(STATUS "This is BINARY dir " ${HELLO_BINARY_DIR})
MESSAGE(STATUS "This is SOURCE dir "${HELLO_SOURCE_DIR})
# MESSAGE指令的语法是:
# MESSAGE([SEND_ERROR | STATUS | FATAL_ERROR] "message to display" ...)
# 这个指令用于向终端输出用户定义的信息,包含了三种类型:
# SEND_ERROR:产生错误,生成过程被跳过
# SATUS:输出前缀为-的信息
# FATAL_ERROR:立即终止所有cmake过程
ADD_EXECUTABLE(hello ${SRC_LIST})
# ADD_EXECUTABLE定义了这个工程会生成一个文件名为hello的可执行文件,相关的源文件是SRC_LIST中定义的源文件列表
# 本例中也可以直接写成ADD_EXECUTABLE(hello main.c)。
# 本例使用了${}来引用变量,这是cmake的变量应用方式
# 但是,有一些例外,比如在IF控制语句,变量是直接使用变量名引用,而不需要${}。如果使用了${}去应用变量,其实IF会去判断名为${}所代表的值的变量,那当然是不存在的了。
4.基本语法规则
cmake要使用“cmake语言和语法”去构建
最简单的语法规则是:
(1)变量使用${}方式取值,但是在IF控制语句中是直接使用变量名
(2)指令(参数1 参数2...)参数使用括弧括起,参数之间使用空格或分号分开
(3)指令是大小写无关的,参数和变量是大小写相关的。推荐全部使用大写指令。
5.注意事项:cmake的语法比较灵活而且考虑到各种情况
(1) SET(SRC_LIST main.c)也可以写成SET(SRC_LIST “main.c”) ,二者没有区别,但是假设一个源文件的文件名是fu nc.c(文件名中间包含了空格)。这时候就必须使用双引号,如果写成了SET(SRC_LIST fu nc.c),就会出现错误,提示找不到fu文件和nc.c文件。这种情况,就必须写成: SET(SRC_LIST “fu nc.c”)
(2)可以忽略掉source列表中的源文件后缀,比如可以写成ADD_EXECUTABLE(t1 main),cmake会自动的在本目录查找main.c或者main.cpp等,当然,最好不要偷这个懒,以免这个目录确实存在一个main.c一个main.
(3)参数也可以使用分号来进行分割。这个例子也是合法的:ADD_EXECUTABLE(t1 main.c t1.c)可以写成ADD_EXECUTABLE(t1 main.c;t1.c).
注意在编写CMakeLists.txt时形成统一的风格即可。
6.清理工程
make clean
7.cmake不支持make distclean
官方是有明确解释的: 因为CMakeLists.txt可以执行脚本并通过脚本生成一些临时文件,但是却没有办法来跟踪这些临时文件到底是哪些。因此,没有办法提供一个可靠的make distclean方案
三、进阶版Hello World
本小节的任务是让前面的Hello World更像一个工程,我们需要做的是:
①添加一个子目录src,用来放置工程源代码;
②添加一个子目录doc,用来放置这个工程的文档hello.txt
③添加文本文件COPYRIGHT, README;
④添加一个runhello.sh脚本,用来调用hello二进制
⑤将构建后的目标文件放入构建目录的bin子目录;
⑥最终安装这些文件:将hello二进制与runhello.sh安装至/usr/bin,将doc目录的内容以及COPYRIGHT/README安装到/usr/share/doc/cmake/demo2
1.工程建立
cd /data/cmake
mkdir demo2
cp demo1/main.c /demo2
cp demo1/CMakeLists.txt /demo2
2.添加子目录src
cd demo2
mkdir src
mv main.c src
由于每个子目录都需要建立CMakeList.txt,进入src,编写CMakeList.txt如下
ADD_EXECUTABLE(hello main.c)
将demo2工程的CMakeLists.txt修改为:
PROJECT(HELLO)
ADD_SUBDIRECTORY(src bin)
建立build目录进行外部编译
madir build
cd build
cmake ..
make
构建完成后,生成的目标文件hello位于build/bin目录中。
# 语法解释
# ADD_SUBDIRECTORY指令
# ADD_SUBDIRECTORY(source_dir [binary_dir] [EXCLUDE_FROM_ALL])
# 这个指令用于向当前工程添加存放源文件的子目录,并可以指定中间二进制和目标二进制存放的位置。
# EXCLUDE_FROM_ALL参数的含义是将这个目录从编译过程中排除
# 比如,工程的example,可能就需要工程构建完成后,再进入example目录单独进行构建
# (当然,你也可以通过定义依赖来解决此类问题)。
上面的例子定义了将src子目录加入工程,并指定编译输出(包含编译中间结果)路径为bin目录。
如果不进行bin目录的指定,那么编译结果(包括中间结果)都将存放在build/src目录(这个目录跟原有的src目录对应),指定bin目录后,相当于在编译时将src重命名为bin,所有的中间结果和目标二进制都将存放在bin目录。
这里需要提一下的是SUBDIRS指令,使用方法是:SUBDIRS(dir1 dir2...),但是这个指令已经不推荐使用。它可以一次添加多个子目录,并且,即使外部编译,子目录体系仍然会被保存。如果我们在上面的例子中将ADD_SUBDIRECTORY (src bin)修改为SUBDIRS(src)。那么在build目录中将出现一个src目录,生成的目标代码hello将存放在src目录中。
3.换个地方保存目标二进制
不论是SUBDIRS还是ADD_SUBDIRECTORY指令(不论是否指定编译输出目录),我们都可以通过SET指令重新定义EXECUTABLE_OUTPUT_PATH和LIBRARY_OUTPUT_PATH变量来指定最终的目标二进制的位置(指最终生成的hello或者最终的共享库,不包含编译生成的中间文件)
SET(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
SET(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/lib)
上面两个指令分别定义了:可执行二进制的输出路径为build/bin和库的输出路径为build/lib
本节我们没有提到共享库和静态库的构建,所以暂不考虑第二条指令。
问题是,应该把这两条指令写在工程的CMakeLists.txt还是src目录下的CMakeLists.txt,把握一个简单的原则,在哪里ADD_EXECUTABLE或ADD_LIBRARY,如果需要改变目标存放路径,就在哪里加入上述的定义。
在这个例子里,当然就是指src下的CMakeLists.txt了。
4.如何安装
安装的需要有两种,一种是从代码编译后直接make install安装,一种是打包时的指定目录安装。
所以,即使最简单的手工编写的Makefile,看起来也是这个样子的:
DESTDIR=
install:
mkdir -p $(DESTDIR)/usr/bin
install -m 755 hello $(DESTDIR)/usr/bin
你可以通过: make install将hello直接安装到/usr/bin目录,也可以通过make install DESTDIR=/tmp/test将他安装在/tmp/test/usr/bin目录,打包时这个方式经常被使用。
稍微复杂一点的是还需要定义PREFIX,一般autotools工程,会运行这样的指令:
./configure –prefix=/usr
# 或者
./configure --prefix=/usr/local
来指定 PREFIX
比如上面的Makefile就可以改写成:
DESTDIR=
PREFIX=/usr
install:
mkdir -p $(DESTDIR)/$(PREFIX)/bin
install -m 755 hello $(DESTDIR)/$(PREFIX)/bin
HelloWorld安装需要引入一个新的cmake 指令 INSTALL和一个非常有用的变量CMAKE_INSTALL_PREFIX。
CMAKE_INSTALL_PREFIX变量类似于configure脚本的 -prefix,常见的使用方法看起来是这个样子:
cmake -DCMAKE_INSTALL_PREFIX=/usr
INSTALL指令用于定义安装规则,安装的内容可以包括目标二进制、动态库、静态库以及文件、目录、脚本等。
INSTALL指令包含了各种安装类型,我们需要一个个分开解释:
目标文件的安装:
INSTALL(TARGETS targets...
[[ARCHIVE|LIBRARY|RUNTIME] [DESTINATION <dir>]
[PERMISSIONS permissions...]
[CONFIGURATIONS [Debug|Release|...] ]
[COMPONENT <component>]
[OPTIONAL]
] [...])
参数中的TARGETS后面跟的就是我们通过ADD_EXECUTABLE或者ADD_LIBRARY定义的目标文件,可能是可执行二进制、动态库、静态库。
目标类型也就相对应的有三种,ARCHIVE特指静态库,LIBRARY特指动态库,RUNTIME特指可执行目标二进制。
DESTINATION定义了安装的路径,如果路径以/开头,那么指的是绝对路径,这时候 CMAKE_INSTALL_PREFIX其实就无效了。如果你希望使用CMAKE_INSTALL_PREFIX来定义安装路径,就要写成相对路径,即不要以/开头,那么安装后的路径就是 ${CMAKE_INSTALL_PREFIX}/<DESTINATION 定义的路径>
举个简单的例子:
INSTALL(TARGETS myrun mylib mystaticlib
RUNTIME DESTINATION bin
LIBRARY DESTINATION lib
ARCHIVE DESTINATION libstatic
)
上面的例子会将可执行二进制myrun安装到{CMAKE_INSTALL_PREFIX}/bin目录,动态库libmylib安装到${CMAKE_INSTALL_PREFIX}/lib目录,静态库libmystaticlib安装到${CMAKE_INSTALL_PREFIX}/libstatic目录
特别注意的是无需关心TARGETS具体生成的路径,只需要写上TARGETS名称就可以了。
普通文件的安装:
INSTALL(FILES files... DESTINATION <dir>
[PERMISSIONS permissions...]
[CONFIGURATIONS [Debug|Release|...]]
[COMPONENT <component>]
[RENAME <name>] [OPTIONAL])
可用于安装一般文件,并可以指定访问权限,文件名是此指令所在路径下的相对路径。如果默认不定义权限PERMISSIONS,安装后的权限为:
OWNER_WRITE, OWNER_READ, GROUP_READ,和WORLD_READ,即644权限。
非目标文件的可执行程序安装(比如脚本之类):
INSTALL(PROGRAMS files... DESTINATION <dir>
[PERMISSIONS permissions...]
[CONFIGURATIONS [Debug|Release|...]]
[COMPONENT <component>]
[RENAME <name>] [OPTIONAL])
跟上面的FILES指令使用方法一样,唯一的不同是安装后权限为:
OWNER_EXECUTE, GROUP_EXECUTE, 和WORLD_EXECUTE,即755权限
目录的安装:
INSTALL(DIRECTORY dirs... DESTINATION <dir>
[FILE_PERMISSIONS permissions...]
[DIRECTORY_PERMISSIONS permissions...]
[USE_SOURCE_PERMISSIONS]
[CONFIGURATIONS [Debug|Release|...]]
[COMPONENT <component>]
[[PATTERN <pattern>| REGEX <regex>]
[EXCLUDE] [PERMISSIONS permissions...]] [...])
这里主要介绍其中的DIRECTORY、PATTERN以及PERMISSIONS参数。
DIRECTORY后面连接的是所在Source目录的相对路径,但务必注意:abc和abc/有很大的区别。 如果目录名不以/结尾,那么这个目录将被安装为目标路径下的abc,如果目录名以/结尾,代表将这个目录中的内容安装到目标路径,但不包括这个目录本身。
PATTERN用于使用正则表达式进行过滤
PERMISSIONS用于指定PATTERN过滤后的文件权限。
我们来看一个例子:
INSTALL(DIRECTORY icons scripts/ DESTINATION share/myproj
PATTERN "CVS" EXCLUDE
PATTERN "scripts/*"
PERMISSIONS OWNER_EXECUTE OWNER_WRITE OWNER_READ GROUP_EXECUTE GROUP_READ)
这条指令的执行结果是:将icons目录安装到<prefix>/share/myproj,将scripts/中的内容安装到 <prefix>/share/myproj
不包含目录名为CVS的目录,对于scripts/* 文件指定权限为 OWNER_EXECUTE OWNER_WRITE OWNER_READ GROUP_EXECUTE GROUP_READ.
安装时CMAKE脚本的执行:
INSTALL([[SCRIPT <file>] [CODE <code>]] [...])
SCRIPT参数用于在安装时调用cmake脚本文件(也就是<abc>.cmake文件)
CODE参数用于执行CMAKE指令,必须以双引号括起来。比如:
INSTALL(CODE "MESSAGE(\"Sample install message.\")")
安装还有几个被标记为过时的指令,比如INSTALL_FILES等,这些指令已经不再推荐使用,所以,这里就不再赘述了。
下面,我们就来改写我们的工程文件,让他来支持各种文件的安装,并且,我们要使用 CMAKE_INSTALL_PREFIX指令。
5.修改Helloworld支持安装
根据本节开头我们定义的本节任务,我们先补上为添加的文件。 添加doc目录及文件:
cd /data/cmake/demo2
mkdir doc
cd doc
vi hello.txt
随便填写一些内容并保存
在工程目录添加runhello.sh脚本,内容为:hello
添加工程目录中的COPYRIGHT和README
touch COPYRIGHT
touch README
下面改写各目录的CMakeLists.txt文件
①安装COPYRIGHT/README,直接修改主工程文件CMakelists.txt,加入以下指令:
INSTALL(FILES COPYRIGHT README DESTINATION share/doc/cmake/demo2)
②安装runhello.sh:直接修改主工程文件CMakeLists.txt,加入如下指令:
INSTALL(PROGRAMS runhello.sh DESTINATION bin)
③安装doc中的hello.txt,这里有两种方式:
一是通过在doc目录建立 CMakeLists.txt并将doc目录通过ADD_SUBDIRECTORY加入工程来完成。另一种方法是直接在工程目录通过INSTALL(DIRECTORY来完成)
前者比较简单,各位可以根据兴趣自己完成,我们来尝试后者,顺便演示DIRECTORY的安装。 因为hello.txt要安装到/<prefix>/share/doc/cmake/demo2,所以我们不能直接安装整个doc目录,这里采用的方式是安装doc目录中的内容,也就是使用"doc/"在工程文件中添加
INSTALL(DIRECTORY doc/ DESTINATION share/doc/cmake/demo2)
6.尝试我们修改的结果
现在进入build目录进行外部编译,注意使用CMAKE_INSTALL_PREFIX参数,这里我们将它安装到了/tmp/demo2目录:
cmake -DCMAKE_INSTALL_PREFIX=/tmp/demo2/usr ..
然后运行make
make install
让我们进入/tmp/demo2目录看一下安装结果:
./usr
./usr/share
./usr/share/doc
./usr/share/doc/cmake
./usr/share/doc/cmake/demo2
./usr/share/doc/cmake/demo2/hello.txt
./usr/share/doc/cmake/demo2/README
./usr/share/doc/cmake/demo2/COPYRIGHT
./usr/bin
./usr/bin/hello
./usr/bin/runhello.sh
如果你要直接安装到系统,可以使用如下指令:
cmake -DCMAKE_INSTALL_PREFIX=/usr ..
7.一个疑问
如果没有定义CMAKE_INSTALL_PREFIX会安装到什么地方?
cmake ..
make
make install
CMAKE_INSTALL_PREFIX的默认定义是/usr/local
8.小结
本小节主要描述了如何在工程中使用多目录、各种安装指令以及CMAKE_INSTALL_PREFIX变量
在下一小节,我们将探讨如何在cmake中构建动态库和静态库,以及如何使用外部头文件和外部共享库,这是程序编写中最常使用的。