【汇编语言（汇编语言第三版 王爽著）】--知识归纳--第八章

第八章 数据处理的两个基本问题

bx、si、di和bp

（1）在8086CPU中，只有这4个寄存器可以用在"[…]"中来寻找地址。
（2）在[…]中，这4个寄存器可以单个出现，或者以这四个组合出现：bx和si、bx和di、bp和si、bp和di。
（3）只要在[…]中使用寄存器bp，而指令中没有显性地给出段地址，段地址默认在ss中。

寻址方式

指令处理的数据长度

在没有寄存器名存在的情况下，用操作符X ptr指明内存单元的长度，X在汇编指令中可以为word或byte，例如：
mov word ptr ds:[0],1
mov byte prt ds:[0],1

寻址的综合应用

用bx定位整个结构体，用idata定位结构体中的某一个数据项，用si地位数组项中的每一个元素

div指令

（1）除数：有8为和16位两种，在一个reg或内存单元中。
（2）被除数：默认放在AX或DX和AX中，如果除数位8位，被除数则为16位，默认在AX中存放；如果除数位16位，被除数则为32位，在DX和AX中存放，DX存高16位，AX存低16位。
（3）结果：如果除数为8位，则AL存储除法操作的商，AH存储除法操作的余数；如果除数位16位，则AX存储除法操作的伤，DX存储除法操作的余数。

伪指令dd

用dd定义double word，即双字型的32位数据。

dup

dup是一个操作符，在汇编语言中同db、dw、dd等一样，也是由编译器识别处理的符号，使用格式：
db 重复的次数 dup（重复的字节型数据）
dw 重复的次数 dup（重复的字型数据）
dd 重复的次数 dup（重复的双字型数据）

实验7 寻址方式在结构化数据访问中的应用

存放位置：年分0~53H 收入54H~0A7H 雇员0A8~0D1

初始化阶段：

mov ax,data
mov ds,ax
mov ax,table
mov es,ax
mov bx,0
mov si,0
mov di,0
mov cx,15h

存放年份：

mov al,[bx]
mov es:[di],al
mov al,[bx+1]
mov es:[di+1],al
mov al,[bx+2]
mov es:[di+2],al
mov al,[bx+3]
mov es:[di+3],al

存放公司总收入：

mov ax,54h[bx]
mov dx,56h[bx]
mov es:5h[di],ax
mov es:7h[di],dx

存放公司人数：

mov ax,0A8h[si]
mov es:0Ah[di],ax

计算人均收入并存

mov ax,54h[bx]
mov dx,56h[bx]
div word ptr ds:0A8h[si]
mov es:0dh[di],ax

为下一次循环时存放数据做准备

add bx,4
add si,2
add di,16

代码：

assume cs:codesg ds:data

data segment
	db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
	db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
	db '1993','1994','1995'
	;以上表示21年的21个字符串
	
	dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
	dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
	;以上表示21年公司总收入的21个dword型数据
	
	dw 3,7,9,13,28,38,130,220,476,775,1001,1442,2258,2793,4037,5635,8226
	dw 11542,14430,15257,17800
	;以上是表示21年公司雇员人数的21个word型数据
data ends

table segment
	db 21 dup ('year summ ne ?? ')
table ends

codesg segment

	start:mov ax,data
		  mov ds,ax
		  mov ax,table
		  mov es,ax
		  mov bx,0
		  mov si,0
		  mov di,0
		  mov cx,15h
		  
		s:mov al,[bx]
		  mov es:[di],al
		  mov al,[bx+1]
		  mov es:[di+1],al
		  mov al,[bx+2]
		  mov es:[di+2],al
		  mov al,[bx+3]
		  mov es:[di+3],al
		  ;以上存放年份
		  
		  mov ax,54h[bx]
		  mov dx,56h[bx]
		  mov es:5h[di],ax
		  mov es:7h[di],dx
		  ;以上存放总收入
		  
		  mov ax,0A8h[si]
		  mov es:0Ah[di],ax
		  ;以上存放公司人数
		  
		  mov ax,54h[bx]
		  div word ptr ds:0A8h[si]
		  mov es:0dh[di],ax
		  ;以上存放人均收入
		  
		  add bx,4
		  add si,2
		  add di,10h
		  
	loop s
	
	mov ax,4c00H
	int 21h
codesg ends
end start