JVM虚拟机之类结构

最新推荐文章于 2024-10-16 10:13:45 发布

海上钢琴师_1900

最新推荐文章于 2024-10-16 10:13:45 发布

阅读量163

点赞数

文章标签： java

本文链接：https://blog.csdn.net/weixin_47395433/article/details/120417791

版权

本文类文件结构常量池部分参考《深入理解Java虚拟机》第六章类文件结构，P222

重要的事情说三遍！！！由于参考文件太大，还需看官自行查阅

Class类文件结构

一个java文件要想运行，就得先编译成虚拟机可以看懂的代码，也就是class字节码文件，一个字节码文件要想运行，就得根据虚拟机指令集找到机器码指令集，而能让机器识别的只有机器码。

java文件经编译后的形成的字节码文件，有且仅由以下部分组成 魔数，次版本号，主版本号，常量池，常量池中各项信息，访问标识，父子类全限定名，接口索引集合，字段表集合，方法表集合，附加属性

下边以 HelloWorld 程序为例依次讲解

package com.zhao.JvmTest;

public class HelloWorld {
    public static void main(String[] args) {
        System.out.println("hello world");
    }
}

使用 od -t xC HelloWorld.class 命令编译字节码文件得到十六进制

0000000    ca  fe  ba  be  00  00  00  34  00  1f  0a  00  06  00  11  09
0000020    00  12  00  13  08  00  14  0a  00  15  00  16  07  00  17  07
0000040    00  18  01  00  06  3c  69  6e  69  74  3e  01  00  03  28  29
0000060    56  01  00  04  43  6f  64  65  01  00  0f  4c  69  6e  65  4e
0000100    75  6d  62  65  72  54  61  62  6c  65  01  00  04  6d  61  69
0000120    6e  01  00  16  28  5b  4c  6a  61  76  61  2f  6c  61  6e  67
0000140    2f  53  74  72  69  6e  67  3b  29  56  01  00  10  4d  65  74
0000160    68  6f  64  50  61  72  61  6d  65  74  65  72  73  01  00  04
0000200    61  72  67  73  01  00  0a  53  6f  75  72  63  65  46  69  6c
0000220    65  01  00  0f  48  65  6c  6c  6f  57  6f  72  6c  64  2e  6a
0000240    61  76  61  0c  00  07  00  08  07  00  19  0c  00  1a  00  1b
0000260    01  00  0b  68  65  6c  6c  6f  20  77  6f  72  6c  64  07  00
0000300    1c  0c  00  1d  00  1e  01  00  1b  63  6f  6d  2f  7a  68  61
0000320    6f  2f  4a  76  6d  54  65  73  74  2f  48  65  6c  6c  6f  57
0000340    6f  72  6c  64  01  00  10  6a  61  76  61  2f  6c  61  6e  67
0000360    2f  4f  62  6a  65  63  74  01  00  10  6a  61  76  61  2f  6c
0000400    61  6e  67  2f  53  79  73  74  65  6d  01  00  03  6f  75  74
0000420    01  00  15  4c  6a  61  76  61  2f  69  6f  2f  50  72  69  6e
0000440    74  53  74  72  65  61  6d  3b  01  00  13  6a  61  76  61  2f
0000460    69  6f  2f  50  72  69  6e  74  53  74  72  65  61  6d  01  00
0000500    07  70  72  69  6e  74  6c  6e  01  00  15  28  4c  6a  61  76
0000520    61  2f  6c  61  6e  67  2f  53  74  72  69  6e  67  3b  29  56
0000540    00  21  00  05  00  06  00  00  00  00  00  02  00  01  00  07
0000560    00  08  00  01  00  09  00  00  00  1d  00  01  00  01  00  00
0000600    00  05  2a  b7  00  01  b1  00  00  00  01  00  0a  00  00  00
0000620    06  00  01  00  00  00  03  00  09  00  0b  00  0c  00  02  00
0000640    09  00  00  00  25  00  02  00  01  00  00  00  09  b2  00  02
0000660    12  03  b6  00  04  b1  00  00  00  01  00  0a  00  00  00  0a
0000700    00  02  00  00  00  05  00  08  00  06  00  0d  00  00  00  05
0000720    01  00  0e  00  00  00  01  00  0f  00  00  00  02  00  10

魔数：表示这个文件格式，每种文件格式是特有的。“ca fe ba be” 就是java文件对应的魔数。

0000000 ca fe ba be 00 00 00 34 00 1f 0a 00 06 00 11 09

主次版本：jdk2至jdk12的次版本号都为0。jdk12以后重启了次版本号。34的十进制为52，对应jdk8

0000000 ca fe ba be 00 00 00 34 00 1f 0a 00 06 00 11 09

常量池：存放类文件信息。主要存放两大类：字面量和符号引用。00 1f 对应的十进制是31，表示常量池中有31项。注意：第0项是不进行记录的。

0000000 ca fe ba be 00 00 00 34 00 1f 0a 00 06 00 11 09

常量池中各项对应的含义字典：

CONSTANT_Class	7
CONSTANT_Fieldref	9
CONSTANT_Methodref	10
CONSTANT_InterfaceMethodref	11
CONSTANT_String	8
CONSTANT_Integer	3
CONSTANT_Float	4
CONSTANT_Long	5
CONSTANT_Double	6
CONSTANT_NameAndType	12
CONSTANT_Utf8	1
CONSTANT_MethodHandle	15
CONSTANT_MethodType	16
CONSTANT_InvokeDynamic	18
CONSTANT_Dynamic	17
CONSTANT_Module	19
CONSTANT_Package	20

常量池第一项：0a对应10进制为10，查找10得知这是一个 CONSTANT_Methodref （类中方法的符号引用），00 06 和 00 11（17）表示它引用了常量池中 #6 和 #17 项来获得这个方法的【所属类】和【方法名】

0000000 ca fe ba be 00 00 00 34 00 1f 0a 00 06 00 11 09

常量池第二项：09对应10进制为9，9表示一个 CONSTANT_Fieldref 信息（字段信息），00 12（18）和 00 13（19）表示它引用了常量池中 #18 和 #19 项来获得这个成员变量的【所属类】和【成员变量名】

0000000 ca fe ba be 00 00 00 34 00 1f 0a 00 06 00 11 09
0000020 00 12 00 13 08 00 14 0a 00 15 00 16 07 00 17 07

常量池第三项：08对应10进制为8，8 表示一个 CONSTANT_String （字符串常量名称）， 00 14（20）表示它引用了常量池中 #20 项。

0000020 00 12 00 13 08 00 14 0a 00 15 00 16 07 00 17 07

常量池第四项：0a对应10进制为10，查找10得知这是一个 CONSTANT_Methodref （类中方法的符号引用），00 15（21）和 00 16（22）表示它引用了常量池中 #21 和 #22 项来获得这个方法的【所属类】和【方法名】

0000020 00 12 00 13 08 00 14 0a 00 15 00 16 07 00 17 07

常量池第五项：07对应10进制为7，查找7得知这是一个 CONSTANT_Class （Class信息），00 17（23）表示它引用了常量池中 #23 项。

0000020 00 12 00 13 08 00 14 0a 00 15 00 16 07 00 17 07

常量池第六项：07对应10进制为7，查找7得知这是一个 CONSTANT_Class （Class信息），00 18（24）表示它引用了常量池中 #24 项。

0000020 00 12 00 13 08 00 14 0a 00 15 00 16 07 00 17 07
0000040 00 18 01 00 06 3c 69 6e 69 74 3e 01 00 03 28 29

常量池第七项：01对应10进制为1，查找1得知这是一个CONSTANT_Utf8 （u8字符串），00 06表示这个字符串占用了多少字节。3c 69 6e 69 74 3e 表示长度为6的u8编码的字符串【 <init> 】

0000040 00 18 01 00 06 3c 69 6e 69 74 3e 01 00 03 28 29

常量池第八项：01表示一个 utf8 串，00 03 表示长度。28 29 56 表示长度为3的u8编码的字符串【()V】其实就是表示无参、无返回值

0000040 00 18 01 00 06 3c 69 6e 69 74 3e 01 00 03 28 29
0000060 56 01 00 04 43 6f 64 65 01 00 0f 4c 69 6e 65 4e

常量池第九项：01表示一个 utf8 串，00 04 表示长度。43 6f 64 65 表示长度为4的u8编码的字符串【Code】

0000060 56 01 00 04 43 6f 64 65 01 00 0f 4c 69 6e 65 4e

常量池第十项：01表示一个 utf8 串， 00 0f (15)表示长度。4c 69 6e 65 4e 75 6d 62 65 72 54 61 62 6c 65表示长度为15的u8编码的字符串【LineNumberTable】

0000060 56 01 00 04 43 6f 64 65 01 00 0f 4c 69 6e 65 4e
0000100 75 6d 62 65 72 54 61 62 6c 65 01 00 04 6d 61 69

常量池第十一项：01表示一个 utf8 串，00 04 表示长度。6d 61 69 6e 表示长度为4的u8编码的字符串【main】

0000100 75 6d 62 65 72 54 61 62 6c 65 01 00 04 6d 61 69
0000120 6e 01 00 16 28 5b 4c 6a 61 76 61 2f 6c 61 6e 67

常量池第十二项：01表示一个 utf8 串，00 16 (22)表示长度。28 5b 4c 6a 61 76 61 2f 6c 61 6e 67 2f 53 74 72 69 6e 67 3b 29 56表示长度为22的u8编码的字符串【([Ljava/lang/String;)V】其实就是参数为字符串数组，无返回值

0000120 6e 01 00 16 28 5b 4c 6a 61 76 61 2f 6c 61 6e 67
0000140 2f 53 74 72 69 6e 67 3b 29 56 01 00 10 4d 65 74

常量池第十三项：01表示一个 utf8 串， 00 10 (16)表示长度。4d 65 74 68 6f 64 50 61 72 61 6d 65 74 65 72 73 表示长度为16的u8编码的字符串【MethodParameters】

0000140 2f 53 74 72 69 6e 67 3b 29 56 01 00 10 4d 65 74
0000160 68 6f 64 50 61 72 61 6d 65 74 65 72 73 01 00 04

常量池第十四项：01表示一个 utf8 串， 00 04 表示长度。61 72 67 73 表示长度为4的u8编码的字符串【args】

0000160 68 6f 64 50 61 72 61 6d 65 74 65 72 73 01 00 04
0000200 61 72 67 73 01 00 0a 53 6f 75 72 63 65 46 69 6c

常量池第十五项：01表示一个 utf8 串， 00 0a (10)表示长度。53 6f 75 72 63 65 46 69 6c 65 表示长度为10的u8编码的字符串是【SourceFile】

0000200 61 72 67 73 01 00 0a 53 6f 75 72 63 65 46 69 6c
0000220 65 01 00 0f 48 65 6c 6c 6f 57 6f 72 6c 64 2e 6a

常量池第十六项：01表示一个 utf8 串， 00 0f (15)表示长度。 48 65 6c 6c 6f 57 6f 72 6c 64 2e 6a 61 76 61 表示长度为15的u8编码的字符串【hello world.java】

0000220 65 01 00 0f 48 65 6c 6c 6f 57 6f 72 6c 64 2e 6a
0000240 61 76 61 0c 00 07 00 08 07 00 19 0c 00 1a 00 1b

常量池第十七项：0c对应10进制为12,查找12得知这是一个CONSTANT_NameAndType ,表示一个【名+类型】，00 07 00 08 引用了常量池中 #7 #8 两项

0000240 61 76 61 0c 00 07 00 08 07 00 19 0c 00 1a 00 1b

常量池第十八项：07对应10进制为7，查找7得知这是一个 CONSTANT_Class （Class信息），00 19（25）表示它引用了常量池中 #25 项。

0000240 61 76 61 0c 00 07 00 08 07 00 19 0c 00 1a 00 1b

常量池第十九项：0c对应10进制为12,查找12得知这是一个CONSTANT_NameAndType ,表示一个【名+类型】，00 1a(26) 00 1b(27) 引用了常量池中 #26 #27 两项

0000240 61 76 61 0c 00 07 00 08 07 00 19 0c 00 1a 00 1b

常量池第二十项：01表示一个 utf8 串， 00 0b (11)表示长度。68 65 6c 6c 6f 20 77 6f 72 6c 64 表示长度为11的u8编码的字符串【hello world】

0000260 01 00 0b 68 65 6c 6c 6f 20 77 6f 72 6c 64 07 00

常量池第二十一项：07对应10进制为7，查找7得知这是一个 CONSTANT_Class （Class信息），00 1c（28）表示它引用了常量池中 #28 项。

0000260 01 00 0b 68 65 6c 6c 6f 20 77 6f 72 6c 64 07 00
0000300 1c 0c 00 1d 00 1e 01 00 1b 63 6f 6d 2f 7a 68 61

常量池第二十二项：0c对应10进制为12,查找12得知这是一个CONSTANT_NameAndType ,表示一个【名+类型】，00 1d (29) 00 1e (30) 引用了常量池中 #29 #30 两项

0000300 1c 0c 00 1d 00 1e 01 00 1b 63 6f 6d 2f 7a 68 61

常量池第二十三项：01表示一个 utf8 串， 00 1b (27)表示长度。01 00 1b 63 ... 72 6c 64 表示长度为27的u8编码的字符串【 com/zhao/JvmTest/HelloWorld】

0000300 1c 0c 00 1d 00 1e 01 00 1b 63 6f 6d 2f 7a 68 61
0000320 6f 2f 4a 76 6d 54 65 73 74 2f 48 65 6c 6c 6f 57
0000340 6f 72 6c 64 01 00 10 6a 61 76 61 2f 6c 61 6e 67

常量池第二十四项：01表示一个 utf8 串， 00 10 (16)表示长度。6a 61 76 ... 65 63 74 表示长度为16的u8编码的字符串【 java/lang/Object】

0000340 6f 72 6c 64 01 00 10 6a 61 76 61 2f 6c 61 6e 67
0000360 2f 4f 62 6a 65 63 74 01 00 10 6a 61 76 61 2f 6c

常量池第二十五项：01表示一个 utf8 串，00 10 (16)表示长度。6a 61 76 ... 74 65 6d 表示长度为16的u8编码的字符串【 java/lang/System】

0000360 2f 4f 62 6a 65 63 74 01 00 10 6a 61 76 61 2f 6c
0000400 61 6e 67 2f 53 79 73 74 65 6d 01 00 03 6f 75 74

常量池第二十六项：01表示一个 utf8 串，00 03 表示长度。6f 75 74 表示长度为3的u8编码的字符串【out】

0000400 61 6e 67 2f 53 79 73 74 65 6d 01 00 03 6f 75 74

常量池第二十七项：01表示一个 utf8 串，00 15 表示长度。4c 6a 61 ... 61 6d 3b 表示长度为21的u8编码的字符串【 Ljava/io/PrintStream;】

0000420 01 00 15 4c 6a 61 76 61 2f 69 6f 2f 50 72 69 6e
0000440 74 53 74 72 65 61 6d 3b 01 00 13 6a 61 76 61 2f

常量池第二十八项：01表示一个 utf8 串，00 13 表示长度。6a 61 76 ... 61 6d 3b 表示长度为19的u8编码的字符串【 java/io/PrintStream】

0000440 74 53 74 72 65 61 6d 3b 01 00 13 6a 61 76 61 2f
0000460 69 6f 2f 50 72 69 6e 74 53 74 72 65 61 6d 01 00

常量池第二十九项：01表示一个 utf8 串，00 07 表示长度。70 72 69 6e 74 6c 6e 表示长度为7的u8编码的字符串【 println】

0000460 69 6f 2f 50 72 69 6e 74 53 74 72 65 61 6d 01 00
0000500 07 70 72 69 6e 74 6c 6e 01 00 15 28 4c 6a 61 76

常量池第三十项：01表示一个 utf8 串，00 15 表示长度。28 4c 6a ... 3b 29 56 表示长度为21的u8编码的字符串【 (Ljava/lang/String;)V】

0000500 07 70 72 69 6e 74 6c 6e 01 00 15 28 4c 6a 61 76
0000520 61 2f 6c 61 6e 67 2f 53 74 72 69 6e 67 3b 29 56

访问标识：用于识别一些类或者接口层次的访问信息。（这个Class是类还是接口；是否定义为public 类型；等等）

Flag Name	Value	Interpretation
ACC_PUBLIC	0x0001	Declared public ; may be accessed from outside its package.
ACC_FINAL	0x0010	Declared final ; no subclasses allowed.
ACC_SUPER	0x0020	Treat superclass methods specially when invoked by the invokespecial instruction.
ACC_INTERFACE	0x0200	Is an interface, not a class.
ACC_ABSTRACT	0x0400	Declared abstract ; must not be instantiated.
ACC_SYNTHETIC	0x1000	Declared synthetic; not present in the source code.
ACC_ANNOTATION	0x2000	Declared as an annotation type.
ACC_ENUM	0x4000	Declared as an enum type.

0000540 00 21 00 05 00 06 00 00 00 00 00 02 00 01 00 07

00 21 等价于 0x0020 ｜0x0001 = 0x0021；表示这个Class文件是一个公共的类。

父子类全限定名：根据项号从常量池中找；如下列的#05和#06

0000540 00 21 00 05 00 06 00 00 00 00 00 02 00 01 00 07

接口索引集合：00 00 表示接口的数量，本类中没有接口，所以为0。

0000540 00 21 00 05 00 06 00 00 00 00 00 02 00 01 00 07

字段表集合：00 00 表示成员变量的数量，本类中没有成员变量，所以为0。

0000540 00 21 00 05 00 06 00 00 00 00 00 02 00 01 00 07

方法表集合：00 02 表示方法的数量，本类中有两个方法，一个是无参构造，一个是main方法。

无参构造：

00 01 表示方法的访问修饰符01对应public。

00 07 表示方法的名字，07代表从常量池中查询第#7项【 <init> 】

00 08 表示方法的参数信息，08代表从常量池中查询第#8项【()V】

00 01 表示方法的属性数量，1个属性

00 09 表示这个属性，09代表从常量池中查询第#9项【Code】

00 00 00 1d 表示此属性的长度是 29

00 01 表示【操作数栈】最大深度

00 01 表示【局部变量表】最大槽（slot）数

00 00 00 05 Code属性代码的长度

2a b7 00 01 b1 是字节码指令

00 00 00 01 表示方法细节属性数量，本例是 1

00 0a 表示细节属性从常量池查找项【LineNumberTable】字节码行号和java源代码行号对应

00 00 00 06 表示此属性的总长度，本例是 6

00 01 表示【LineNumberTable】长度

00 00 表示【字节码】行号

00 03 表示【java 源码】行号

0000540 00 21 00 05 00 06 00 00 00 00 00 02 00 01 00 07
0000560 00 08 00 01 00 09 00 00 00 1d 00 01 00 01 00 00
0000600 00 05 2a b7 00 01 b1 00 00 00 01 00 0a 00 00 00
0000620 06 00 01 00 00 00 03

main方法：

00 09 代表访问修饰符（本类中是 public static）

00 0b 表示方法名称【main】

00 0c 表示方法类型【([Ljava/lang/String;)V】string数组

00 02 方法属性个数，2个属性

属性1

00 09 表示引用了常量池 #09 项，发现是【Code】属性

00 00 00 25 表示此属性的长度是 37

00 02 表示【操作数栈】最大深度

00 01 表示【局部变量表】最大槽（slot）数

00 00 00 09 表示字节码长度，本例是 9

b2 00 02 12 03 b6 00 04 b1 是字节码指令

00 00 00 01 表示方法细节属性数量，本例是 1

00 0a 表示细节属性从常量池查找项【LineNumberTable】字节码行号和java源代码行号对应

00 00 00 0a 表示此属性的总长度，本例是 10

00 02 表示【LineNumberTable】长度

00 00 表示【字节码】行号 00 05 表示【java 源码】行号

00 08 表示【字节码】行号 00 06 表示【java 源码】行号

属性2

00 0d 表示引用了常量池 #13 项，发现是【MethodParameters】

00 00 00 05 表示此属性的总长度，本例是 5

01 参数数量

00 0e 表示引用了常量池 #14 项，是【args】

00 00 访问修饰符（00代表正常，10代表final）

0000620 06 00 01 00 00 00 03 00 09 00 0b 00 0c 00 02 00
0000640 09 00 00 00 25 00 02 00 01 00 00 00 09 b2 00 02
0000660 12 03 b6 00 04 b1 00 00 00 01 00 0a 00 00 00 0a
0000700 00 02 00 00 00 05 00 08 00 06 00 0d 00 00 00 05
0000720 01 00 0e 00 00 00 01 00 0f 00 00 00 02 00 10

附加属性：一些类的描述信息

00 01 表示附加属性数量

00 0f 表示引用了常量池 #15 项，即【SourceFile】

00 00 00 02 表示此属性的长度

00 10 表示引用了常量池 #16 项，即【HelloWorld.java】

0000720 01 00 0e 00 00 00 01 00 0f 00 00 00 02 00 10

字节码指令：

2a b7 00 01 b1 字节码指令

经解释器识别这些指令，解释成机器码就可以运行了。jvm指令集中

2a => aload_0 加载 slot 0 的局部变量，即 this，做为下面的 invokespecial 构造方法调用的参数

b7 => invokespecial 预备调用构造方法，哪个方法呢？

00 01 引用常量池中 #1 项，即【 Method java/lang/Object."<init>":()V 】

b1 表示返回

b2 00 02 12 03 b6 00 04 b1 字节码指令

b2 => getstatic 用来加载静态变量，哪个静态变量呢？

00 02 引用常量池中 #2 项，即【Field java/lang/System.out:Ljava/io/PrintStream;】

12 => ldc 加载参数，哪个参数呢？

03 引用常量池中 #3 项，即【String hello world】

b6 => invokevirtual 预备调用成员方法，哪个方法呢？

00 04 引用常量池中 #4 项，即【Method java/io/PrintStream.println:(Ljava/lang/String;)V】

b1 表示返回

以上分析二进制字节码文件是不是很让人头疼，不但需要查阅资料，还需要借助各种工具才能达到目的。Oracle官方推出了 javap -v HelloWorld.class 命令来反编译二进制字节码。如下

HackerZhao:JvmTest apple$ javap -v HelloWorld.class 
Classfile /Users/apple/IdeaProjects/aliossdemo/src/main/java/com/zhao/JvmTest/com/zhao/JvmTest/HelloWorld.class
  Last modified 2021-9-23; size 479 bytes
  MD5 checksum 083db01ad93140402dd4c57d7ea45a2f
  Compiled from "HelloWorld.java"
public class com.zhao.JvmTest.HelloWorld 
  minor version: 0     //小版本号
  major version: 52    //大版本号
  flags: ACC_PUBLIC, ACC_SUPER    //类的修饰符
Constant pool:        //常量池
   #1 = Methodref          #6.#17         // java/lang/Object."<init>":()V
   #2 = Fieldref           #18.#19        // java/lang/System.out:Ljava/io/PrintStream;
   #3 = String             #20            // hello world
   #4 = Methodref          #21.#22        // java/io/PrintStream.println:(Ljava/lang/String;)V
   #5 = Class              #23            // com/zhao/JvmTest/HelloWorld
   #6 = Class              #24            // java/lang/Object
   #7 = Utf8               <init>
   #8 = Utf8               ()V
   #9 = Utf8               Code
  #10 = Utf8               LineNumberTable
  #11 = Utf8               main
  #12 = Utf8               ([Ljava/lang/String;)V
  #13 = Utf8               MethodParameters
  #14 = Utf8               args
  #15 = Utf8               SourceFile
  #16 = Utf8               HelloWorld.java
  #17 = NameAndType        #7:#8          // "<init>":()V
  #18 = Class              #25            // java/lang/System
  #19 = NameAndType        #26:#27        // out:Ljava/io/PrintStream;
  #20 = Utf8               hello world
  #21 = Class              #28            // java/io/PrintStream
  #22 = NameAndType        #29:#30        // println:(Ljava/lang/String;)V
  #23 = Utf8               com/zhao/JvmTest/HelloWorld
  #24 = Utf8               java/lang/Object
  #25 = Utf8               java/lang/System
  #26 = Utf8               out
  #27 = Utf8               Ljava/io/PrintStream;
  #28 = Utf8               java/io/PrintStream
  #29 = Utf8               println
  #30 = Utf8               (Ljava/lang/String;)V
{
  public com.zhao.JvmTest.HelloWorld();          //构造方法
    descriptor: ()V            //方法参数信息
    flags: ACC_PUBLIC          //方法修饰符
    Code:                      //具体代码
      stack=1, locals=1, args_size=1    //栈深度，局部变量表长度，参数的长度
         0: aload_0            //把局部变量中的第0项加载至操作数栈
         1: invokespecial #1                  // Method java/lang/Object."<init>":()V
         4: return
      LineNumberTable:        //方法属性
        line 3: 0        //源码中的行号：字节码中的行号

  public static void main(java.lang.String[]);    //main方法信息
    descriptor: ([Ljava/lang/String;)V        //方法参数信息，string数组
    flags: ACC_PUBLIC, ACC_STATIC            //访问修饰符
    Code:                    //方法属性
      stack=2, locals=1, args_size=1
         0: getstatic     #2                  // Field java/lang/System.out:Ljava/io/PrintStream;
         3: ldc           #3                  // String hello world
         5: invokevirtual #4                  // Method java/io/PrintStream.println:(Ljava/lang/String;)V
         8: return
      LineNumberTable:
        line 5: 0
        line 6: 8
    MethodParameters:  //方法参数信息
      Name   //方法参数名称                  Flags        //正常参数
      args
}
SourceFile: "HelloWorld.java"

图解方法执行流程

package com.zhao.JvmTest;

public class Demo1 {
    public static void main(String[] args) {
        int a = 10;
        int b = Short.MAX_VALUE + 1;
        int c = a + b;
        System.out.println(c);
    }
}

方法字节码指令

  public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
      stack=2, locals=4, args_size=1
         0: bipush        10
         2: istore_1
         3: ldc           #3                  // int 32768
         5: istore_2
         6: iload_1
         7: iload_2
         8: iadd
         9: istore_3
        10: getstatic     #4                  // Field java/lang/System.out:Ljava/io/PrintStream;
        13: iload_3
        14: invokevirtual #5                  // Method java/io/PrintStream.println:(I)V
        17: return

字节码指令详解：

stack=2，栈的容量为2。 locals=4，局部变量有4个。args_size=1，方法参数1个

bipush 10 ：表示将常量10加载至栈中（入栈）。

这里小的数字都是和字节码指令存在一起，超过 short 范围的数字存入了常量池

istore_1 ：表示将栈中的10存储到局部变量中 1 号槽位置（出栈）

ldc #3 ：将常量池中第#3项常量（32768）取出加载至栈（入栈）。注意 Short.MAX_VALUE 是 32767，所以 32768 = Short.MAX_VALUE + 1 实际是在编译期间计算好的

istore_2 ：将常量 32768 存储到局部变量中 2 号槽位置（出栈）

iload_1 ：将局部变量中槽1（10）加载至栈中（入栈）

iload_2 ：将局部变量中槽2（32768）加载至栈中（入栈）

iadd ：栈中两元素做相加操作。

istore_3 ：将常量 32778 存储到局部变量中 3 号槽位置（出栈）

getstatic #4 ：访问类的static字段（字段，称为类变量），堆中创建PrintStream对象

iload_3 ：将局部变量中槽3（32778）加载至栈中（入栈）

invokevirtual #5 ：找到常量池 #5 项，生成新的栈帧（分配 locals、stack等），传递参数，执行新栈帧中的字节码。

执行完毕，弹出栈帧。清除 main 操作数栈内容

return ：完成 main 方法调用，弹出 main 栈帧。程序结束。释放所有内存。

a++和++a 在字节码层到底做了什么

Eg：

package com.zhao.JvmTest;

/*** 从字节码角度分析 a++ 相关题目 */
public class Demo3 {
    public static void main(String[] args) {
        int a = 10;
        int b = a++ + ++a + a--;
        System.out.println(a); //11
        System.out.println(b); //34
    }
}

反编译字节码

  public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
      stack=2, locals=3, args_size=1
         0: bipush        10    // 将常量10加载至栈桢中
         2: istore_1            // 将常量10加载至1号槽位 a = 10
         3: iload_1             // 将1号槽位10加载至栈桢 
         4: iinc          1, 1  //iinc是在槽位上做自增,参1:哪个槽位做自增，参2:自增值。a=11
         7: iinc          1, 1  //iinc是在槽位上做自增,参1:哪个槽位做自增，参2:自增值。a=12
        10: iload_1             // 将1号槽位12加载至栈桢 
        11: iadd                // 做相加操作，10 + 12 = 22，栈桢值 22
        12: iload_1             // 将1号槽位12加载至栈桢 栈桢值 12 22
        13: iinc          1, -1 // 槽位自减1，a = 11
        16: iadd                // 栈桢值做相加操作 12 + 22 = 34
        17: istore_2            // 把相加的结果加载至2号槽位，此时 a = 11，b = 34
        18: getstatic     #2                  // Field java/lang/System.out:Ljava/io/PrintStream;
        21: iload_1
        22: invokevirtual #3                  // Method java/io/PrintStream.println:(I)V
        25: getstatic     #2                  // Field java/lang/System.out:Ljava/io/PrintStream;
        28: iload_2
        29: invokevirtual #3                  // Method java/io/PrintStream.println:(I)V
        32: return

注意 iinc 指令是直接在局部变量 slot 上进行运算
a++ 和 ++a 的区别是先执行 iload 还是先执行 iinc

常用的条件判断指令

0x99	ifeq	判断是否 == 0
0x9a	ifne	判断是否 != 0
0x9b	iflflt	判断是否 < 0
0x9c	ifge	判断是否 >= 0
0x9d	ifgt	判断是否 > 0
0x9e	iflfle	判断是否 <= 0
0x9f	if_icmpeq	两个int是否 ==
0xa0	if_icmpne	两个int是否 !=
0xa1	if_icmplt	两个int是否 <
0xa2	if_icmpge	两个int是否 >=
0xa3	if_icmpgt	两个int是否 >
0xa4	if_icmple	两个int是否 <=
0xa5	if_acmpeq	两个引用是否 ==
0xa6	if_acmpne	两个引用是否 !=
0xc6	ifnull	判断是否 == null
0xc7	ifnonnull	判断是否 != null

byte，short，char 都会按 int 比较，因为操作数栈都是 4 字节

goto 用来进行跳转到指定行号的字节码

Eg：

package com.zhao.JvmTest;

public class Demo5 {
    public static void main(String[] args) {
        int i = 0;
        int x = 0;
        while (i < 10) {
            x = x++;
            i++;
        }
        System.out.println(x); // 结果是 0
    }
}

这个结果可能会让人感到意外，不过了解了它底层原理就不会对此感到奇怪。

字节码文件

  public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
      stack=2, locals=3, args_size=1
         0: iconst_0            //加载0至操作数栈
         1: istore_1            //加载0至局部变量表1号槽位 i = 0
         2: iconst_0            //加载0至操作数栈
         3: istore_2            //加载0至局部变量表2号槽位 x = 0
         4: iload_1             //加载局部变量表1号槽位至操作数栈
         5: bipush        10    //加载常量10至操作数栈
         7: if_icmpge     21    //如果变量 x < 10
        10: iload_2             //加载局部变量表2号槽位至操作数栈
        11: iinc          2, 1  //槽位2的值自增 1，x = 1
        14: istore_2            //加载0至局部变量表2号槽位 x = 0
        15: iinc          1, 1
        18: goto          4
        21: getstatic     #2                  // Field java/lang/System.out:Ljava/io/PrintStream;
        24: iload_2
        25: invokevirtual #3                  // Method java/io/PrintStream.println:(I)V
        28: return

重点在这两句字节码

槽位2的值自增 1，x = 1

加载0至局部变量表2号槽位 x = 0

先自增，又被赋值。解决方式：不要用 x++，用 x + 1

Eg1：

package com.zhao.JvmTest;

public class Demo6 {
    static int i = 10;

    static {
        i = 20;
    }

    static {
        i = 30;
    }
}

反编译字节码文件

  static {};
    descriptor: ()V
    flags: ACC_STATIC
    Code:
      stack=1, locals=0, args_size=0
         0: bipush        10
         2: putstatic     #2                  // Field i:I
         5: bipush        20
         7: putstatic     #2                  // Field i:I
        10: bipush        30
        12: putstatic     #2                  // Field i:I
        15: return

编译器会按从上至下的顺序，收集所有 static 静态代码块和静态成员赋值的代码，合并为一个特殊的方法 <cinit>()V ，会在类加载的初始化阶段被调用。

Eg2：

package com.zhao.JvmTest;

public class Demo7 {
    private String a = "s1";

    {
        b = 20;
    }

    private int b = 10;

    {
        a = "s2";
    }

    public Demo7(String a, int b) {
        this.a = a;
        this.b = b;
    }

    public static void main(String[] args) {
        Demo7 d = new Demo7("s3", 30);
        System.out.println(d.a);
        System.out.println(d.b);
    }
}

反编译字节码文件

  public com.zhao.JvmTest.Demo7(java.lang.String, int);
    descriptor: (Ljava/lang/String;I)V
    flags: ACC_PUBLIC
    Code:
      stack=2, locals=3, args_size=3
         0: aload_0              //把this加载至操作数栈
         1: invokespecial #1     //调用父类中的无参构造
         4: aload_0              //把this加载至操作数栈
         5: ldc           #2     // “s1”加载至操作数栈
         7: putfield      #3     //把 “s1” 赋值给 this.a
        10: aload_0              //把this加载至操作数栈
        11: bipush        20     //把常量20加载至操作数栈
        13: putfield      #4     //把常量20赋值给变量b
        16: aload_0              
        17: bipush        10     //把常量10赋值给变量b
        19: putfield      #4                 
        22: aload_0
        23: ldc           #5     
        25: putfield      #3     //把字符串s2赋值给变量a
        28: aload_0
        29: aload_1              //把槽1对应的 “s1” 加载至操作数栈
        30: putfield      #3     
        33: aload_0
        34: iload_2
        35: putfield      #4                  // Field b:I
        38: return
      LineNumberTable:
        line 16: 0
        line 4: 4
        line 7: 10
        line 10: 16
        line 13: 22
        line 17: 28
        line 18: 33
        line 19: 38
    MethodParameters:
      Name                           Flags
      a
      b

  public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
      stack=4, locals=2, args_size=1
         0: new           #6                 
         3: dup
         4: ldc           #7       // 把字符串 “s3” 加载至操作数栈
         6: bipush        30       // 把 30 加载至操作数栈
         8: invokespecial #8       // 调用初始化方法，将两个值传给它们，完毕关掉栈桢          
        11: astore_1               // 把 s3 存入局部变量表 1号槽 a = “s3”
        12: getstatic     #9       
        15: aload_1
        16: getfield      #3                  // Field a:Ljava/lang/String;
        19: invokevirtual #10                 
        22: getstatic     #9                  
        25: aload_1
        26: getfield      #4                  // Field b:I
        29: invokevirtual #11                
        32: return

编译器会按从上至下的顺序，收集所有 {} 代码块和成员变量赋值的代码，形成新的构造方法，但原始构造方法内的代码总是在最后

Eg3：

package com.zhao.JvmTest;

public class Demo8 {
    public Demo8() {}

    private void test1() {}

    private final void test2() {}

    public void test3() {}

    public static void test4() {}

    public static void main(String[] args) {
        Demo8 d = new Demo8();
        d.test1();    //调用私有方法
        d.test2();    //调用final方法
        d.test3();    //调用公共方法
        d.test4();    //通过对象调用静态方法
        Demo8.test4();    //通过类名调用静态方法
    }
}

反编译字节码文件

  public static void main(java.lang.String[]);
    descriptor: ([Ljava/lang/String;)V
    flags: ACC_PUBLIC, ACC_STATIC
    Code:
      stack=2, locals=2, args_size=1
         0: new           #2  //堆内存中创建对象，把对象地址放入操作数栈（第一份）
         3: dup               //把对象地址复制一份（第二份）
         4: invokespecial #3  //根据栈顶的引用调用初始化方法，调用结束会将其清除掉
         7: astore_1          //把对象引用（第一份）存储至1号槽位变量 d 的位置
         8: aload_1           //从1号槽位加载对象引用
         9: invokespecial #4  //根据对象引用调用 test1 方法，调用结束将对象引用清除掉
        12: aload_1           //从1号槽位加载对象引用
        13: invokespecial #5                  // Method test2:()V
        16: aload_1
        17: invokevirtual #6  //子类可能会重写，这里是动态调用公共方法，耗一点性能
        20: aload_1           //从1号槽位加载对象引用
        21: pop               //弹出对象引用
        22: invokestatic  #7  //通过类名调用方法
        25: invokestatic  #7  //通过类名调用方法
        28: return

不建议通过对象调用静态方法，会做两步无用开销。

公共方法可能会被子类重写，需要动态查找方法的位置。私有的，final修饰的编译期间就可以确定位置。