Oracle实现分页查询

1、创建包

create or replace package pkg_query_z as
  type cur_query is ref cursor;
PROCEDURE prc_query_z
       (p_tableName        in  varchar2,   --表名
        p_strWhere         in  varchar2,   --查询条件
        p_orderColumn      in  varchar2,   --排序的列
        p_orderStyle       in  varchar2,   --排序方式
        p_curPage          in out Number,  --当前页
        p_pageSize         in out Number,  --每页显示记录条数
        p_totalRecords     out Number,     --总记录数
        p_totalPages       out Number,     --总页数
        v_cur              out pkg_query_z.cur_query,--返回的结果集
        p_selectField      in varchar2);   --查询的字段
end pkg_query_z;

2、创建包体，既存储过程

CREATE OR REPLACE PACKAGE BODY PKG_QUERY_Z AS
PROCEDURE PRC_QUERY_Z
       (P_TABLENAME        IN  VARCHAR2,   --表名
        P_STRWHERE         IN  VARCHAR2,   --查询条件
        P_ORDERCOLUMN      IN  VARCHAR2,   --排序的列
        P_ORDERSTYLE       IN  VARCHAR2,   --排序方式
        P_CURPAGE          IN OUT NUMBER,  --当前页
        P_PAGESIZE         IN OUT NUMBER,  --每页显示记录条数
        P_TOTALRECORDS     OUT NUMBER,     --总记录数
        P_TOTALPAGES       OUT NUMBER,     --总页数
        V_CUR              OUT PKG_QUERY_Z.CUR_QUERY, --返回的结果集
        p_selectField      IN VARCHAR2)    --查询的字段
IS
   V_SQL VARCHAR2(20000) := '';      --SQL语句
   V_STARTRECORD NUMBER(18);         --开始显示的记录条数
   V_ENDRECORD NUMBER(18);           --结束显示的记录条数
BEGIN
   --记录中总记录条数
   V_SQL := 'SELECT COUNT(1) FROM ' || P_TABLENAME || ' WHERE 1=1 ';
   IF P_STRWHERE IS NOT NULL OR P_STRWHERE <> '' THEN
       V_SQL := V_SQL || P_STRWHERE;
   END IF;
   EXECUTE IMMEDIATE V_SQL INTO P_TOTALRECORDS;

   --验证页面记录大小
   --P_PAGESIZE := P_TOTALRECORDS;
   IF P_PAGESIZE < 0 THEN
       P_PAGESIZE := 0;
   END IF;

   --根据页大小计算总页数
   IF MOD(P_TOTALRECORDS,P_PAGESIZE) = 0 THEN
       P_TOTALPAGES := P_TOTALRECORDS / P_PAGESIZE;
   ELSE
       P_TOTALPAGES := FLOOR(P_TOTALRECORDS / P_PAGESIZE) + 1;
   END IF;

   --验证页号
   IF P_CURPAGE < 1 THEN
       P_CURPAGE := 1;
   END IF;
   IF P_CURPAGE > P_TOTALPAGES THEN
       P_CURPAGE := P_TOTALPAGES;
   END IF;

   --实现分页查询
   V_STARTRECORD := (P_CURPAGE - 1) * P_PAGESIZE + 1;
   V_ENDRECORD := P_CURPAGE * P_PAGESIZE;
   V_SQL := 'SELECT * FROM (SELECT ROWNUM RWN,A.* FROM ' ||
            '(SELECT ' || p_selectField || ' FROM ' || P_TABLENAME || ' WHERE 1=1 ';
   IF P_STRWHERE IS NOT NULL OR P_STRWHERE <> '' THEN
       V_SQL := V_SQL || P_STRWHERE;
   END IF;
   IF P_ORDERCOLUMN IS NOT NULL OR P_ORDERCOLUMN <> '' THEN
       V_SQL := V_SQL || ' ORDER BY ' || P_ORDERCOLUMN || ' ' || P_ORDERSTYLE;
   END IF;
   V_SQL := V_SQL || ') A WHERE ROWNUM <= ' || V_ENDRECORD || ') WHERE RWN >= '
            || V_STARTRECORD;
   DBMS_OUTPUT.PUT_LINE(V_SQL);
   OPEN V_CUR FOR V_SQL;
END PRC_QUERY_Z;
END PKG_QUERY_Z;