从零开始编写一个操作系统（1）---编写mbr.s文件

参考链接：

https://www.bilibili.com/video/BV15o4y157Wm/?spm_id_from=333.999.0.0&vd_source=04945ad6c469ff06e0e2f8a48f612736

本节内容是运行mbr.s代码。

一、编写mbr.s文件

新建txt文档，将以下内容复制到文档中，保存文件，命名为mbr.s

保存mbr.s文件的位置是任意的，类似于编写c语言源代码，然后编译器需要对代码进行编译，然后才能运行。

                                ;主引导程序 
                                ;------------------------------------------------------------
SECTION MBR vstart=0x7c00         
    mov ax,cs                   ;此时cs寄存器为0，自然可以用来将ax寄存器置0
    mov ds,ax
    mov es,ax
    mov ss,ax
    mov fs,ax
    mov sp,0x7c00

                                ; 清屏 利用0x06号功能，上卷全部行，则可清屏。
                                ; -----------------------------------------------------------
                                ;INT 0x10   功能号:0x06	   功能描述:上卷窗口
                                ;------------------------------------------------------
                                ;输入：
                                ;AH 功能号= 0x06
                                ;AL = 上卷的行数(如果为0,表示全部)
                                ;BH = 上卷行属性
                                ;(CL,CH) = 窗口左上角的(X,Y)位置
                                ;(DL,DH) = 窗口右下角的(X,Y)位置
                                ;无返回值：
    mov ax, 0x600               ;ah中输入功能号
    mov bx, 0x700               ;设置上卷行属性，0x70表示用黑底白字的属性填充空白行
    mov cx, 0                   ;左上角: (0, 0)
    mov dx, 0x184f	            ;右下角: (80,25),
			                    ;VGA文本模式中,一行只能容纳80个字符,共25行。
			                    ;下标从0开始,所以0x18=24,0x4f=79
    int 0x10                    ;int 0x10

                                ;;;;;;;;;    下面这三行代码是获取光标位置    ;;;;;;;;;
    mov ah, 3		            ;输入: 3号子功能是获取光标位置,需要存入ah寄存器
    mov bh, 0		            ;bh寄存器存储的是待获取光标的页号

    int 0x10		            ;输出: ch=光标开始行,cl=光标结束行
		    	                ;dh=光标所在行号,dl=光标所在列号

                                ;;;;;;;;;    获取光标位置结束    ;;;;;;;;;;;;;;;;

                                ;;;;;;;;;     打印字符串    ;;;;;;;;;;;
                                ;还是用10h中断,不过这次是调用13号子功能打印字符串
    mov ax, message 
    mov bp, ax		            ; es:bp 为串首地址, es此时同cs一致，
			                    ; 开头时已经为sreg初始化

                                ; 光标位置要用到dx寄存器中内容,cx中的光标位置可忽略
    mov cx, 5		            ; cx 为串长度,不包括结束符0的字符个数
    mov ax, 0x1301	            ; 子功能号13是显示字符及属性,要存入ah寄存器,
			                    ; al设置写字符方式 ah=01: 显示字符串,光标跟随移动
    mov bx, 0x2		            ; bh存储要显示的页号,此处是第0页,
			                    ; bl中是字符属性, 属性黑底绿字(bl = 02h,07是黑底白字)
    int 0x10		            ; 执行BIOS 0x10 号中断
                                ;;;;;;;;;      打字字符串结束	 ;;;;;;;;;;;;;;;

    jmp $		                ; 使程序悬停在此

    message db "1 MBR"
    times 510-($-$$) db 0
    db 0x55,0xaa

我保存mbr.s的位置，在桌面的bochs文件下

二、编译mbr.s文件

在刚刚保存mbr.s文件位置的文件夹下打开终端，输入以下代码，回车

nasm -o mbr.bin mbr.s

然后就是将编译好的mbr.bin 文件写入虚拟机

 dd if=/your_path_1/mbr.bin of=/your_path_2/bochs/hd60M.img bs=512 count=1 conv=notrunc

 your_path_1：mbr.bin文件所在位置

your_path_2：bochs文件所在位置

三、启动虚拟机

打开bochs文件夹，打开终端，输入以下代码

bin/bochs -f bochsrc.disk

回车

输入c，回车

结果展示