windows自动压缩zip打包

Firewormq

已于 2024-04-18 05:29:58 修改

阅读量1.6k

点赞数 7

文章标签： windows 运维 batch

于 2023-11-30 12:53:47 首次发布

本文链接：https://blog.csdn.net/weixin_61708367/article/details/134709238

版权

前言

相信大家有的备份的习惯吧，但自动备份后文件又很大，占用硬盘资源，又需要手动处理打包压缩。以下脚本文件将处理自动打包压缩文件。

脚本语言

batch

代码

话不多说直接上代码：

REM 作者：Fireworm
REM 联系方式：firewormq@qq.com

@echo off
setlocal

REM 设置要压缩的文件夹路径、文件类型、文件要移动到的路径
set "folderPath=C:\Users\Administrator\Desktop\123"
set "fileType=.txt"
set "move_path=.\"

REM 获取当前日期和时间（YYYY-mm-DD-HHMM）
REM 判断小时部分是否大于9做格式处理(HH)
if %time:~0,2% leq 9 (set hour=0%time:~1,1%) else (set hour=%time:~0,2%)
set datetime=%date:~0,4%-%date:~5,2%-%date:~8,2%-%hour%%time:~3,2%

REM 设置压缩文件的名称和保存路径
set "zipName=%datetime%.zip"
set "zipPath=%folderPath%\%zipName%"

REM 检查并删除已存在的 ZIP 文件
if exist "%zipPath%" (
    echo 正在删除现有的 ZIP 文件： "%zipPath%"
    del "%zipPath%"
)

REM 获取要压缩的文件列表
echo 正在查找并压缩文件...
for %%F in ("%folderPath%\*%fileType%") do (
    echo 添加文件： "%%~nxF" 到 "%zipPath%"
    bz a -y "%zipPath%" "%%~fF"
)

REM 删除原有文件中的已压缩的内容
echo 正在删除原始文件中已压缩的内容： "%folderPath%"
del /q "%folderPath%\*%fileType%"

echo ZIP 文件已创建： "%zipPath%"

REM 如果move_path文件目录不存在则创建文件
if not exist "%move_path%" (
    echo 目录不存在，正在创建...
    mkdir "%move_path%"
    echo 目录创建成功！
) else (
    echo 目录已存在！
)
REM 移动文件到指定路径"move_path"
move %folderPath%\*.* %move_path%
endlocal