HIT_OS_LAB3 操作系统的引导

已于 2024-01-04 11:09:40 修改
阅读量402 收藏 1
点赞数
文章标签： 开发语言
于 2023-11-11 10:10:58 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/weixin_65199878/article/details/134344607
版权

操作系统实验三

3.1. 实验目的

  • 熟悉实验环境；
  • 建立对操作系统引导过程的深入认识；
  • 掌握操作系统的基本开发过程；
  • 能对操作系统代码进行简单的控制，揭开操作系统的神秘面纱。

3.2. 实验内容

3.2.1. 改写 bootsect.s 主要完成如下功能：

bootsect.s 可以在屏幕上输出提示信息
输出语句“BDSOS is booting…”
检查bootsect.s，以下代码用于打印信息

ljmp    $BOOTSEG, $_start  
_start:  
    mov $0x03,%ah  
    xor %bh,%bh  
    int $0x10  
	mov	$24, %cx
	mov	$0x0007, %bx		# page 0, attribute 7 (normal)
	#lea	msg1, %bp
	mov     $msg1, %bp
	mov	$0x1301, %ax		# write string, move cursor
	int	$0x10
    msg1:
	.byte 13,10
	.ascii "Loading system ..."
	.byte 13,10,13,10 
.org 510  
boot_flag:  
    .word   0xAA55

因此，对bootsect.s的内容进行修改，使其输出所需的信息，然后删除其余代码，最终，bootsect.s的完整内容如下：

.code16  
.global _start   
.equ SETUPLEN, 4		# nr of setup-sectors  
.equ BOOTSEG, 0x07c0		# original address of boot-sector  
.equ INITSEG, 0x9000		# we move boot here - out of the way  
.equ SETUPSEG, 0x9020		# setup starts here  
.equ ROOT_DEV, 0x301  
ljmp    $BOOTSEG, $_start  
_start:  
 mov $0x03,%ah  
 xor %bh,%bh  
 int $0x10  
 mov $31,%cx  
 mov $0x0007,%bx  
 mov $msg1,%bp  
 mov $0x07c0,%ax  
 mov %ax,%es  
 mov $0x1301,%ax  
 int $0x10  
msg1:  
 .byte 13,10  
 .ascii "BDSOS is booting..."  
 .byte 13,10,13,10  
.org 510  
boot_flag:  
 .word   0xAA55

最后，编译文件并执行，结果如下图，显示bootsect.s的修改是正确的，成功输出语句“BDSOS is booting…”
在这里插入图片描述

3.2.2. 改写 setup.s 主要完成如下功能：

首先，确保setup.s能够向屏幕输出信息，这个功能已经在前一个问题中在bootsect.s中完成，因此，将相应代码复制到setup.s中，然后删除多余代码，完整的setup.s代码如下：

       .code16
       .equ SETUPSEG, 0x9020
       .global _start
       ljmp $SETUPSEG, $_start	
       _start:
           mov $0x03,%ah
           xor %bh,%bh
           int $0x10
           mov $25,%cx
           mov $0x0007,%bx
           mov $msg2,%bp
           mov $0x07c0,%ax
           mov %cs,%ax
           mov %ax,%es
           mov $0x1301,%ax
           int $0x10
       inf_loop:
           jmp inf_loop
       msg2:
           .byte   13,10
           .ascii "Now we are in SETUP"
           .byte   13,10,13,10
       .org 510
       boot_flag:
           .word   0xAA55

接下来，对bootsect.s进行修改，以使其能够加载并跳转到setup.s的起始地址执行。检查原bootsect.s的内容，找到以下代码实现了这个功能：

        load_setup:
        	mov	$0x0000, %dx		# drive 0, head 0
        	mov	$0x0002, %cx		# sector 2, track 0
        	mov	$0x0200, %bx		# address = 512, in INITSEG
        	.equ    AX, 0x0200+SETUPLEN
        	mov     $AX, %ax		# service 2, nr of sectors
        	int	$0x13			# read it
        	jnc	ok_load_setup		# ok - continue
        	mov	$0x0000, %dx
        	mov	$0x0000, %ax		# reset the diskette
        	int	$0x13
        	jmp	load_setup
        ok_load_setup:
    	    ljmp	$SETUPSEG, $0

因此，对bootsect.s的代码进行修改，首先加载setup.s，然后显示语句“BDSOS is booting…”，最后跳转至setup.s。完成这些功能并删除多余代码后，bootsect.s的完整代码如下：

   	.code16
       	.equ SETUPLEN, 2		# nr of setup-sectors
       	.equ BOOTSEG, 0x07c0		# original address of boot-sector
       	.equ INITSEG, 0x9000		# we move boot here - out of the way
       	.equ SETUPSEG, 0x9020		# setup starts here
       	.equ ROOT_DEV, 0x301
       	ljmp    $BOOTSEG, $_start
       _start:
       	mov	$BOOTSEG, %ax
       	mov	%ax, %ds
       	mov	$INITSEG, %ax
       	mov	%ax, %es
       	mov	$256, %cx
       	sub	%si, %si
       	sub	%di, %di
       	rep	
       	movsw

       load_setup:
       	mov	$0x0000, %dx		# drive 0, head 0
       	mov	$0x0002, %cx		# sector 2, track 0
       	mov	$0x0200, %bx		# address = 512, in INITSEG
       	.equ    AX, 0x0200+SETUPLEN
       	mov     $AX, %ax		# service 2, nr of sectors
       	int	$0x13			# read it
       	jnc	ok_load_setup		# ok - continue
       	mov	$0x0000, %dx
       	mov	$0x0000, %ax		# reset the diskette
       	int	$0x13
       	jmp	load_setup

       ok_load_setup:
       	mov	$0x03, %ah		# read cursor pos
       	xor	%bh, %bh
       	int	$0x10
       	mov	$31, %cx
       	mov	$0x0007, %bx		# page 0, attribute 7 (normal)
       	mov     $msg1, %bp
       	mov	$0x1301, %ax		# write string, move cursor
       	int	$0x10
       	ljmp	$SETUPSEG, $0

       msg1:
       	.byte 13,10
       	.ascii "BDSOS is booting..."
       	.byte 13,10,13,10
       	.org 508
       root_dev:
       	.word ROOT_DEV
       boot_flag:
       	.word 0xAA55

最后，编译文件并执行，结果如下图，bootsect.s和setup.s的修改是正确的，成功显示语句“Now we are in SETUP”
在这里插入图片描述

setup.s 可以获取至少一个基本的硬件参数（如内存参数、显卡参数、硬盘参数等），将其存储在内存的特定地址，并在屏幕上输出。
在保持setup.s原有功能不变的同时，使其能够读取硬件参数。首先，在原setup.s文件中，有以下代码可以读取各项硬件信息：

        mov	$INITSEG, %ax	# get Cursor Poser
	    mov	%ax, %ds
	    mov	$0x03, %ah	
	    xor	%bh, %bh
	    int	$0x10		
	    mov	%dx, %ds:0      # get Memory Size
    	mov	$0x88, %ah 
	    int	$0x15
	    mov	%ax, %ds:2
	    mov	$0x0000, %ax        # get hd0 data
	    mov	%ax, %ds
	    lds	%ds:4*0x41, %si
	    mov	$INITSEG, %ax
	    mov	%ax, %es
	    mov	$0x0004, %di
	    mov	$0x10, %cx
	    rep
	    movsb

但是，读取出的数以无符号整数形式存在，需要对这些数进行处理，以十六进制形式显示。可以通过以下函数完成这个操作：

       print_hex:
           mov    $4,%cx
       print_digit:
           rol    $4,%dx
           mov    $0xe0f,%ax  
           and    %dl,%al  
           add    $0x30,%al
           cmp    $0x3a,%al
           jl     outp  
           add    $0x07,%al  
       outp:
           int    $0x10
           loop   print_digit
           ret
       print_nl:
           mov    $0xe0d,%ax
           int    $0x10
           mov    $0xa,%al
           int    $0x10
           ret

然后，结合以上两点信息，使setup.s在显示"Now we are in SETUP"之后，进一步打印"Memory Size:"、内存大小、“KB”、"Cursor Poser:"等信息，以满足要求。完整的setup.s代码如下：

       .code16
       .equ SETUPSEG, 0x9020	# this is the current segment
       .equ INITSEG, 0x9000	# we move boot here - out of the way
       .global _start
       ljmp $SETUPSEG, $_start	
       _start:
           mov $0x03,%ah       # print "Now we are in SETUP"
           xor %bh,%bh
           int $0x10
           mov $25,%cx
           mov $0x0007,%bx
           mov $msg2,%bp       
           mov $0x07c0,%ax
           mov %cs,%ax
           mov %ax,%es
           mov $0x1301,%ax
           int $0x10
       	mov	$INITSEG, %ax	# get Cursor Poser
       	mov	%ax, %ds
       	mov	$0x03, %ah	
       	xor	%bh, %bh
       	int	$0x10		
       	mov	%dx, %ds:0
       	mov	$0x88, %ah      # get memory size
       	int	$0x15
       	mov	%ax, %ds:2
           mov $0x03,%ah       # print "Memory Size:"
           xor %bh,%bh
           int $0x10
           mov $12,%cx
           mov $0x0007,%bx
           mov $msg3,%bp
           mov $0x1301,%ax
           int $0x10
       	mov	%ds:2 , %dx     # print memory size
           call print_hex
           mov $0x03,%ah       # print "KB"
           xor %bh,%bh
           int $0x10
           mov $2,%cx
           mov $0x0007,%bx
           mov $msg4,%bp
           mov $0x1301,%ax
           int $0x10
           call print_nl 
           mov $0x03,%ah       # print "Memory Size:"
           xor %bh,%bh
           int $0x10
           mov $12,%cx
           mov $0x0007,%bx
           mov $msg8,%bp
           mov $0x1301,%ax
           int $0x10
       	mov	%ds:0 , %dx     # print memory size
           call print_hex
           call print_nl
           mov $0x03,%ah       # print "Cylinders:"
           xor %bh,%bh
           int $0x10
           mov $10,%cx
           mov $0x0007,%bx
           mov $msg5,%bp
           mov $0x1301,%ax
           int $0x10
       	mov	$0x0000, %ax        # get hd0 data
       	mov	%ax, %ds
       	lds	%ds:4*0x41, %si
       	mov	$INITSEG, %ax
       	mov	%ax, %es
       	mov	$0x0004, %di
       	mov	$0x10, %cx
       	rep
       	movsb
       	mov	$INITSEG, %ax       # print Cylinders
       	mov	%ax, %ds
       	mov	%ds:4 , %dx     
           call print_hex
           call print_nl
           mov $0x03,%ah       # print "Headers:"
           xor %bh,%bh
           int $0x10
           mov $8,%cx
           mov $0x0007,%bx
           mov $msg6,%bp       
           mov $0x07c0,%ax
           mov %cs,%ax
           mov %ax,%es
           mov $0x1301,%ax
           int $0x10
       	mov	$INITSEG, %ax       # print Headers
       	mov	%ax, %ds
       	mov	%ds:6 , %dx     
           call print_hex
           call print_nl
           mov $0x03,%ah       # print "Sectors Per Track:"
           xor %bh,%bh
           int $0x10
           mov $18,%cx
           mov $0x0007,%bx
           mov $msg7,%bp
           mov $0x1301,%ax
           int $0x10
       	mov	$INITSEG, %ax       # print Sectors Per Track
       	mov	%ax, %ds
       	mov	%ds:18 , %dx     
           call print_hex
           call print_nl
       inf_loop:
           jmp inf_loop
       print_hex:
           mov    $4,%cx
       print_digit:
           rol    $4,%dx
           mov    $0xe0f,%ax  
           and    %dl,%al  
           add    $0x30,%al
           cmp    $0x3a,%al
           jl     outp  
           add    $0x07,%al  
       outp:
           int    $0x10
           loop   print_digit
           ret
       print_nl:
           mov    $0xe0d,%ax   
           int    $0x10
           mov    $0xa,%al    
           int    $0x10
           ret
       msg2:
           .byte   13,10
           .ascii "Now we are in SETUP"
           .byte   13,10,13,10
       msg3:
           .ascii "Memory Size:"
       msg4:
           .ascii "KB"
       msg5:
           .ascii "Cylinders:"
       msg6:
           .ascii "Headers:"
       msg7:
           .ascii "Sectors Per Track:"
       msg8:
           .ascii "Cursor Pose:"
       .org 510
       boot_flag:
           .word   0xAA55

最后，编译文件并执行，结果如下图。
在这里插入图片描述

  • 成功显示信息“Memory Size:3C00KB”。表明3C00KB即为15MB，又有15MB+1MB=16MB。查看bochs配置文件bochs/bochsrc.bxrc，发现有"megs: 16"，则配置的bochs为16MB内存，所以这项信息正确。
  • 成功显示信息“Cursor Poser:1800”，光标位置为1800，也是正确的。
  • 成功显示信息“Cylinders：00cc”、“Headers:0010”、“Sectors Per Track:0026”。查看bochs配置文件bochs/bochsrc.bxrc，发现有“ata0-master: type=disk, path=“$OSLAB_PATH/hdc-0.11.img”, mode=flat, cylinders=204, heads=16, spt=38”，设定的cylinders=204=0x00CC，heads=16=0x0010，spt(Sectors Per Track)=38=0x0026，与所显示的信息相符，因此这几项信息也是正确的。

3.3. 实验报告

有时，继承传统意味着别手蹩脚。 x86 计算机为了向下兼容，导致启动过程比较复杂。 请找出 x86 计算机启动过程中，被硬件强制，软件必须遵守的两个“多此一举”的步骤（多找几个也无妨），说说它们为什么多此一举，并设计更简洁的替代方案。

实模式和保护模式切换：

  • 初始时，x86处理器以实模式运行，这是旧版处理器的工作模式。为了支持现代操作系统，处理器在启动后需要切换到保护模式。这一切换包括加载新的段描述符、设置新的全局描述符表（GDT）和禁用一些过时的实模式特性。
  • 实模式是为老软件和硬件设计的，而保护模式提供更强大和安全的特性。然而，切换过程增加了启动的复杂性，而在现代系统中，实模式的许多特性是多余的。
  • 直接从启动时开始在保护模式下运行，省略实模式和保护模式的切换，以简化启动过程。

BIOS中断调用：

  • 在启动过程中，操作系统通常需要与硬件交互。在x86中，传统方式是通过调用BIOS中断请求服务，例如，读取键盘输入、显示字符等。这导致了对中断向量表的依赖，增加了复杂性。
  • 随着计算机硬件和操作系统的发展，直接调用硬件驱动程序或使用更现代的接口方式可以更高效地进行硬件交互。
  • 直接使用现代的硬件抽象层和驱动程序模型，避免对BIOS中断的依赖。通过在内核中嵌入适当的驱动程序，而不是依赖BIOS中断调用，可以更为简洁地实现相同的功能。
B.D.S.
关注
  • 0
    点赞
  • 踩
  • 1
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 0
    评论
专栏目录
HIT_OS_LAB
11-24
哈尔滨工业大学 计算机学院 操作系统实验 实现的代码 少了lab_7 ,放在机房电脑上了，有空传上来
HIT-OS-Lab:哈工大操作系统实验（含报告，PPT，以及做实验过程中的一些小记录README.md）
03-11
HIT-OS-Lab 哈工大操作系统实验 含报告，PPT，以及做实验过程中的一些小记录README.md 说明：*不保证所有的代码都正确，如果有问题，欢迎发送拉请求。融合大量学长学姐的结晶完成！
hit-oslab 实验1和实验2
weixin_45693672的博客
08-30 228
操作系统启动 注意：此部分的代码 /boot/bootsect.s 和 /boot/setup.s是需要重构的，而不是按照源码修改 1.1我对于开机的系统理解 1。就我个人而言开机相当于让整个机器热起来，在通电之后，机器是无知的，这时候需要让源源不断的“内容”加载到内存中，让处理器热起来一直处于工作状态！但是如果一开始不在内存中永久的加入相当于“指路功能的”boot，计算机永远找不到记录在磁盘上的数据，所以我们在内存0xffff0处添加了一直存在的信息就是为了找到操作系统的第一个程序bootsect.s！！
hit-oslab:哈尔滨工业大学《操作系统》课程实验指导手册，实验环境（64位支持）及
03-11
命中oslab 本仓库涵盖了哈尔滨工业大学《操作系统》课程实验指导手册，实验环境（64位支持）及子系统。针对针对32位和64位的Ubuntu系统，一键式建造好环境，为同学们节省环境配置时间。 在线学习与实验 由于历史原因，推荐大家使用实验楼提供的实验环境。本项目只做替换使用。 安装 本安装脚本调试实验环境安装在用户目录下，文件名为oslab。如果有特殊需要，请自行移动文件夹位置。注意，请不要使用超级用户执行此安装命令，当有需要时hit-oslab会请求超级用户权限。 git clone https://github.com/DeathKing/hit-oslab.git ~ /hit-oslab cd ~ /hit-oslab ./setup.sh 如果想要跳过软件源更新步骤，请在./setup.sh后加上参数-s或--skip-update 。 复原 考虑到操作系统试验每次需要重置li
oslab实验环境hit-oslab-linux
08-28
包含linux-0.11源码,bochs模拟器等，配套李治军老师操作系统系列课程
HIT_OS
03-30
总结来说，“HIT_OS”是一个关于操作系统引导的主题，特别关注汇编语言在其中的作用。从BIOS/UEFI到引导加载器，再到内核的加载和初始化，每一个步骤都可能涉及到汇编语言编程。通过学习和理解这些细节，开发者可以...
HIT_IR_Lab
03-15
HIT_IR_Lab
哈工大计算机系统Lab3 报告+源代码，供学弟学妹参考。
08-25
在哈工大的计算机系统课程中，Lab3通常涉及操作系统的核心概念和实现，旨在让学生深入理解计算机系统的底层工作原理。这份报告结合源代码，为学习者提供了宝贵的实践经验和理论知识。 一、计算机系统基础 计算机...
HIT哈工大软件构造实验lab3
06-17
实验环境配置是指在实验过程中所需的软硬件环境的配置，包括操作系统、编程语言、开发工具等。 面向复用性和可维护性的设计 面向复用性和可维护性的设计是软件构造的核心思想，本实验中，我们将设计一个 ...
【HIT-OSLAB-实验报告】
一个腰部以上的叛逆
11-29 774
哈工大操作系统李志军老师的系列实验课程的实验报告。里面没有实验步骤，思路，只有结果的汇报，和代码的呈现。如果想看思路和可能的步骤，可以看看我另外一篇具体实验过程的记录。迷时师渡，悟了自渡。愿与诸君共勉。
hit-oslab-linux0.11
12-04
配套网易云课堂学习linux0.11，内有环境配置全套工具，实验楼实验环境可亲自搭建。学习操作系统不二之选。
实验一-操作系统的引导.zip
06-26
实验一-操作系统的引导，一、问题回答 有时，继承传统意味着别手蹩脚。x86 计算机为了向下兼容，导致启动过程比较复杂。请找出 x86 计算机启动过程中，被硬件强制，软件必须遵守的两个“多此一举”的步骤（多找几个也无妨），说说它们为什么多此一举，并设计更简洁的替代方案。
【HIT-OSLAB-实验中的碎碎念】
一个腰部以上的叛逆
11-29 932
做哈工大李志军操作系统实验过程中遇到的问题，思路，代码的记录
哈工大-操作系统-HitOSlab-李治军-实验0-在自己电脑上搭建实验环境
garbage_man的博客
08-17 6068
哈工大李治军老师的操作系统实验课程是一门不可多得的好课程，该课程基于linux0.11让学生们编写代码实现：系统启动、系统调用、进程切换、内核级线程等操作系统的基本功能。这个课程在蓝桥云课上有对应的在线虚拟机系统。不过，该系统单次只能运行60分钟，如果要连续长时间使用，需要不断延时，错过延时系统就会关闭，之前做的进度无法保存，所以很多小伙伴会选择在自己的电脑上搭载相应的实验环境，方便随时随地进行实验。 第一步：在自己电脑上通过VMware安装Ubuntu系统 首先，下载VMware虚拟机软件； 然后，去.
【HIT-OSLAB-1-操作系统的引导】
一个腰部以上的叛逆
10-30 986
哈工大，李治军老师操作系统课程对应的实验一。 给出了代码
【Linux】HIT-oslab实验环境搭建
恒治学
03-25 700
欲搭建的环境 Bochs + gcc + vim + Ubuntu + Linux 0.11源码 \qquad在这篇文章之前，务必阅读： \qquadUbuntu 20.04 (64位) 配置gcc-3.4用于编译linux-0.11 准备Linux 0.11源码 \qquadhit-oslab-linux-20110823.tar.gz \qquad拷贝到实验工作目录后解压，这里以3exps为例. cd 3exps tar zxvf hit-oslab-linux-20110823.tar.gz 进入源
hit-oslab 实验环境准备(一)
chumingqian的博客
11-18 1114
下面开始真正的旅途了，
【操作系统hit-oslab环境搭建】
purebook的博客
11-23 678
这里写自定义目录标题欢迎使用Markdown编辑器新的改变功能快捷键合理的创建标题，有助于目录的生成nihao如何改变文本的样式插入链接与图片如何插入一段漂亮的代码片生成一个适合你的列表创建一个表格设定内容居中、居左、居右SmartyPants创建一个自定义列表如何创建一个注脚注释也是必不可少的KaTeX数学公式新的甘特图功能，丰富你的文章UML 图表FLowchart流程图导出与导入导出导入 欢迎使用Markdown编辑器 你好！ 这是你第一次使用 Markdown编辑器 所展示的欢迎页。如果你想学习如何
Hit-oslab lab3 report
Focus5679的博客
04-20 348
源代码在github库： https://github.com/Focus5679/hit-oslab 1.编写process.c文件 参考： https://www.cnblogs.com/dongguolei/p/8086346.html //fork的使用 https://www.cnblogs.com/LUO77/p/5804436.html //wait/waitpid的使...
hit_rs422_dll
最新发布
06-06
hit_rs422_dll 提供了可以在 Windows 操作系统下使用 RS422 端口的 API 接口。 使用 hit_rs422_dll，可以在 Windows 操作系统下实现对 RS422 端口的操作，例如打开端口、读取数据、发送数据、关闭端口等。对于需要...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

B.D.S.

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值