IV_KEY 为企业微信机器人KEY
IV_MEGTYPE 传输 message / file /template 来确认发送什么
IV_MEDIA_ID 传输上传文件后返回的MEDIA_ID
ZTEMPLATE_CARD_STR 参考企微机器人开发文档 TEMPLATE_CARD的结构
FUNCTION zfm_send_message.
*"----------------------------------------------------------------------
*"*"本地接口:
*" IMPORTING
*" VALUE(IV_KEY) TYPE STRING
*" REFERENCE(IV_WECHAT) TYPE STRING
*" VALUE(IV_MSGTYPE) TYPE STRING
*" VALUE(IV_TEXT) TYPE STRING OPTIONAL
*" VALUE(IV_MEDIA_ID) TYPE STRING OPTIONAL
*" VALUE(IV_TEMPLATE_CARD) TYPE ZTEMPLATE_CARD_STR OPTIONAL
*"----------------------------------------------------------------------
DATA: lv_url TYPE string, "http 服务接口地址
lv_json TYPE string, "发送报文
lv_result_string TYPE string,
lv_message TYPE string,
lo_respone_data TYPE REF TO data,
lv_field_symbols_string TYPE string.
DATA:lv_len TYPE i."发送报文长度
DATA:lv_uuid TYPE sysuuid_x16.
DATA:lo_http_client TYPE REF TO if_http_client.
TYPES: ty_mentioned_list TYPE string.
TYPES: tt_mentioned_list TYPE STANDARD TABLE OF ty_mentioned_list WITH DEFAULT KEY.
TYPES: ty_mentioned_mobile_list TYPE string.
TYPES: tt_mentioned_mobile_list TYPE STANDARD TABLE OF ty_mentioned_mobile_list WITH DEFAULT KEY.
TYPES: BEGIN OF ty_text,
content TYPE string,
mentioned_list TYPE tt_mentioned_list,
mentioned_mobile_list TYPE tt_mentioned_mobile_list,
END OF ty_text.
TYPES: BEGIN OF ty_markdown,
content TYPE string,
END OF ty_markdown.
TYPES: BEGIN OF ty_file,
media_id TYPE string,
END OF ty_file.
DATA:ls_text TYPE ty_text.
DATA ls_markdown TYPE ty_markdown.
DATA ls_file TYPE ty_file.
DATA:ls_mentioned_list TYPE ty_mentioned_list,
ls_mentioned_mobile_list TYPE ty_mentioned_mobile_list.
DATA:lt_mobile_list TYPE tt_mentioned_mobile_list.
TYPES: BEGIN OF ty_json,
msgtype TYPE string,
markdown TYPE ty_markdown,
text TYPE ty_text,
file TYPE ty_file,
template_card TYPE ztemplate_card_str,
END OF ty_json.
DATA:ls_json TYPE ty_json.
"根据LV_WECHAT获取要@的人,企业微信注册的手机号
SELECT * INTO
TABLE @DATA(lt_zmobile)
FROM ztmobile WHERE wechat = @iv_wechat.
ls_json-msgtype = iv_msgtype.
TRANSLATE ls_json-msgtype TO LOWER CASE.
CASE ls_json-msgtype.
WHEN 'file'.
ls_file-media_id = iv_media_id.
ls_json-file = ls_file.
WHEN 'text'.
LOOP AT lt_zmobile INTO DATA(ls_zmobile).
APPEND INITIAL LINE TO lt_mobile_list ASSIGNING FIELD-SYMBOL(<fs_mobile_list>).
<fs_mobile_list> = ls_zmobile-phone_number.
CLEAR:ls_zmobile.
ENDLOOP.
ls_text-mentioned_mobile_list = lt_mobile_list.
ls_text-content = iv_text.
ls_json-text = ls_text.
WHEN 'template_card'.
ls_json-template_card = iv_template_card.
ENDCASE.
* 设置HTTP接口地址
lv_url = 'https://qyapi.weixin.qq.com/cgi-bin/webhook/send?key=' && iv_key.
"----创建客户端请求
CALL METHOD cl_http_client=>create_by_url
EXPORTING
url = lv_url
IMPORTING
client = lo_http_client
EXCEPTIONS
argument_not_found = 1
plugin_not_active = 2
internal_error = 3
OTHERS = 4.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH
sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
"---设置传输请求内容的格式和编码格式
lo_http_client->request->set_content_type( content_type = 'application/json;charset=utf-8' ).
"---设置调用服务
lo_http_client->request->set_method( if_http_request=>co_request_method_post ).
"---lv_json存放json格式数据/ 设置报文内容(json格式字符串)
lv_json = /ui2/cl_json=>serialize( data = ls_json compress = abap_true pretty_name = 'L' ).
"---设置要传输内容
lv_len = strlen( lv_json ).
CALL METHOD lo_http_client->request->if_http_entity~set_cdata
EXPORTING
data = lv_json
length = lv_len.
"---发送请求
CALL METHOD lo_http_client->send
EXCEPTIONS
http_communication_failure = 1
http_invalid_state = 2
http_processing_failed = 3
http_invalid_timeout = 4
OTHERS = 5.
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH
sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
"读取远程服务返回的处理过结果。
CALL METHOD lo_http_client->receive
EXCEPTIONS
http_communication_failure = 1
http_invalid_state = 2
http_processing_failed = 3.
IF sy-subrc <> 0 .
lo_http_client->get_last_error( IMPORTING message = lv_message ).
* ZMESG-MESSAGE = LV_MESSAGE.
* ZMESG-TYPE = 'E'.
RETURN.
ELSE.
lv_result_string = lo_http_client->response->get_cdata( ).
lo_respone_data = /ui2/cl_json=>generate( json = lv_result_string ).
IF lo_respone_data IS NOT INITIAL.
ENDIF.
ENDIF.
*BREAK-POINT.
ENDFUNCTION.