参考PR创建采购合同（ME31K) BDC模式

最新推荐文章于 2024-08-05 16:21:22 发布
置顶 最新推荐文章于 2024-08-05 16:21:22 发布
阅读量3k 收藏 3
点赞数
分类专栏： SAP ABAP MM 文章标签： BDC ABAP sap 服务类采购合同
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/wenyitao880901/article/details/53113703
版权
ABAP 同时被 3 个专栏收录
50 篇文章 2 订阅
订阅专栏
SAP
48 篇文章 4 订阅
订阅专栏
MM
7 篇文章 0 订阅
订阅专栏 
SAP目前没有BAPI 创建服务类采购合同，所以采用BDC创建。以下是参考PR，以BDC的模式创建有服务行的采购合同（可包含物资行）
 
FUNCTION zfun1039.
*"----------------------------------------------------------------------
*"*"局部接口：
*"  IMPORTING
*"     REFERENCE(IV_BDCMODE) TYPE  CHAR1 OPTIONAL
*"     REFERENCE(IV_MODE) TYPE  CHAR1
*"     REFERENCE(IS_HEADER) TYPE  ZMM_S_CONTRACT_HEADER
*"     REFERENCE(IT_ITEM) TYPE  ZMM_T_CONTRACT_ITEM
*"     REFERENCE(IT_ACCOUNT) TYPE  ZMM_T_CONTRACT_ACCOUNT
*"     REFERENCE(IT_CONDITIONS) TYPE  ZMM_T_CONTRACT_CONDITIONS
*"     REFERENCE(IT_PARTNER) TYPE  ZMM_T_CONTRACT_PARTNER
*"     REFERENCE(IT_SERVICES) TYPE  ZMM_T_CONTRACT_SERVICES
*"     REFERENCE(IT_HEADER_TEXT) TYPE  ZMM_T_LONGTEXT
*"     REFERENCE(IT_ITEM_TEXT) TYPE  ZMM_T_LONGTEXT
*"  EXPORTING
*"     VALUE(EV_MSG) TYPE  CHAR255
*"     VALUE(EV_CODE) TYPE  STRING
*"     VALUE(EV_CONTRACT_NUM) TYPE  EBELN
*"  EXCEPTIONS
*"      UNKOWN_MODE
*"----------------------------------------------------------------------

  DATA:rec_ite TYPE zmm_s_contract_item,
       rec_acc TYPE zmm_s_contract_account,
       rec_ser TYPE zmm_s_contract_services,
       rec_con TYPE zmm_s_contract_conditions,
       rec_par TYPE zmm_s_contract_partner,
       rec_txt TYPE zmm_s_longtext.
  DATA:tab_bdc TYPE TABLE OF bdcdata.

*bdc值转化数据定义
  DATA:l_date_str1 TYPE char10,
       l_date_str2 TYPE char10,
       l_ktwrt_str TYPE char15,
       l_wkurs_str TYPE char10,
       l_bukrs     TYPE bukrs,
       l_ktmng_str TYPE char20,
       l_netpr_str TYPE char20,
       l_menge_str TYPE char20,
       l_tbtwr_str TYPE char20,
       l_poski_str TYPE char8,
       l_vbelp_str TYPE char5.
*bdc 数据定义
  DATA:tab_msg TYPE TABLE OF bdcmsgcoll,
       rec_msg TYPE bdcmsgcoll ,
       l_mode TYPE c VALUE 'N'.

  DATA:l_lines TYPE i,
       l_ebelp TYPE char5.
  DATA:tab_esll TYPE TABLE OF esll,
       rec_esll TYPE esll.

  WRITE is_header-bedat TO l_date_str1 DD/MM/YYYY.
***********************初始屏幕  start**********************************
  PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPMM06E' '0200'.
  PERFORM frm_bdc_add_field:
           TABLES tab_bdc USING 'BDC_OKCODE'  'KOPF',      "抬头明细按钮
           TABLES tab_bdc USING 'EKKO-EKGRP'  is_header-ekgrp,"采购组
           TABLES tab_bdc USING 'EKKO-EKORG'  is_header-ekorg,"采购组织
           TABLES tab_bdc USING 'RM06E-VEDAT' l_date_str1,    "协议日期
           TABLES tab_bdc USING 'RM06E-EVART' is_header-bsart,"协议类型
           TABLES tab_bdc USING 'EKKO-LIFNR'  is_header-lifnr. "供应商
  SELECT SINGLE bukrs INTO l_bukrs
     FROM t024e
  WHERE ekorg = is_header-ekorg.
  IF sy-subrc NE 0 OR l_bukrs IS INITIAL.
    "公司代码输入屏幕
    PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPMM06E' '0514'.
    PERFORM frm_bdc_add_field:
          TABLES tab_bdc USING 'BDC_OKCODE' '=ENTE',         "回车
          TABLES tab_bdc USING 'EKKO-BUKRS' is_header-bukrs. "公司代码
  ENDIF.
***********************初始屏幕    end**********************************

***********************抬头屏幕  start**********************************
*数据格式转化
  WRITE is_header-kdatb TO l_date_str1 MM/DD/YYYY.
  WRITE is_header-kdate TO l_date_str2 MM/DD/YYYY.
  WRITE is_header-ktwrt TO l_ktwrt_str NO-GROUPING DECIMALS 2.
  WRITE is_header-wkurs TO l_wkurs_str NO-GROUPING DECIMALS 2.

  PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPMM06E' '0201'.
  PERFORM frm_bdc_add_field:
        TABLES tab_bdc USING 'BDC_OKCODE'     '=PRTN',    "合作伙伴按钮
        TABLES tab_bdc USING 'EKKO-KDATB'     l_date_str1,"有效期开始
        TABLES tab_bdc USING 'EKKO-KDATE'     l_date_str2,"有效期结束
        TABLES tab_bdc USING 'EKKO-UNSEZ'     is_header-unsez,"我方参考
        TABLES tab_bdc USING 'EKKO_CI-ZZHTBH' is_header-zzhtbh,"合同编号
        TABLES tab_bdc USING 'EKKO_CI-ZZHTMC' is_header-zzhtmc,"合同名称
        TABLES tab_bdc USING 'EKKO-KTWRT'     l_ktwrt_str,"目标值
        TABLES tab_bdc USING 'EKKO-WAERS'     is_header-waers, "货币
        TABLES tab_bdc USING 'EKKO-WKURS'     l_wkurs_str,     "汇率
        TABLES tab_bdc USING 'EKKO-ANGNR'     is_header-angnr, "报价
        TABLES tab_bdc USING 'EKKO-INCO1'     is_header-incoterms1,
        TABLES tab_bdc USING 'EKKO-INCO2'     is_header-incoterms2,
        TABLES tab_bdc USING 'EKKO-ZTERM'     is_header-zterm. "付款条款
***********************抬头屏幕    end**********************************

***********************合作伙伴屏幕start********************************
  IF it_partner[] IS NOT INITIAL.
    PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPLEKPA'  '0102'.
    PERFORM frm_bdc_add_field:
          TABLES tab_bdc USING 'BDC_OKCODE'      '=DISL',"显示按钮
          TABLES tab_bdc USING 'RM06E-SELKZ(01)' 'X'.    "选择第一行

    LOOP AT it_partner INTO rec_par.
      PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPLEKPA' '0101'.
     PERFORM frm_bdc_add_field TABLES tab_bdc USING 'BDC_OKCODE' '=NEW'.

      PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPLEKPA' '0101'.
      PERFORM frm_bdc_add_field:
            TABLES tab_bdc USING 'BDC_OKCODE'       '/00',
            TABLES tab_bdc USING 'MMPA-PARVW(02)'   rec_par-parvw,"功能
            TABLES tab_bdc USING 'WRF02K-GPARN(02)' rec_par-lifn2."伙伴号
    ENDLOOP.

*回退级别合作伙伴屏幕
    PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPLEKPA'   '0101'.
    PERFORM frm_bdc_add_field TABLES tab_bdc USING 'BDC_OKCODE' '=BACK'.
  ENDIF.

*回退抬头屏幕
  PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPLEKPA'   '0102'.
  PERFORM frm_bdc_add_field TABLES tab_bdc USING 'BDC_OKCODE' '=BACK'.

*进入概览屏幕（抬头+行）
  PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPMM06E'    '0201'.
  PERFORM frm_bdc_add_field TABLES tab_bdc USING 'BDC_OKCODE'  '=AB'.
***********************合作伙伴屏幕  end********************************

***********************概览屏幕    start********************************

  LOOP AT it_item INTO rec_ite.
    WRITE rec_ite-ktmng TO l_ktmng_str NO-GROUPING DECIMALS 2.
    WRITE rec_ite-netpr TO l_netpr_str NO-GROUPING DECIMALS 2.
*参考采购申请按钮
    PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPMM06E'    '0220'.
    PERFORM frm_bdc_add_field TABLES tab_bdc USING 'BDC_OKCODE'  '=BS'.
*填写采购申请编号屏幕
    DATA:l_bnfpo_str TYPE char5.
    l_bnfpo_str = rec_ite-bnfpo.
    PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPMM06E'    '0501'.
    PERFORM frm_bdc_add_field:
         TABLES tab_bdc USING 'BDC_OKCODE'         '=ENTE',
         TABLES tab_bdc USING 'EKET-BANFN'         rec_ite-banfn,
         TABLES tab_bdc USING 'EKET-BNFPO'         l_bnfpo_str,
         TABLES tab_bdc USING 'EBAN-EKGRP'         is_header-ekgrp,
         TABLES tab_bdc USING 'RM06E-OFFBA'        ''.
*复制采购申请
    PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPMM06E'    '0125'.
    PERFORM frm_bdc_add_field:
         TABLES tab_bdc USING 'BDC_OKCODE'         '=REFH',
         TABLES tab_bdc USING 'BDC_CURSOR'         'EBAN-BANFN(01)',
         TABLES tab_bdc USING 'RM06E-TCSELFLAG(01)' 'X'.

*行明细屏幕
    PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPMM06E'    '0211'.
    PERFORM frm_bdc_add_field:
         TABLES tab_bdc USING 'BDC_OKCODE'         '/00',
         TABLES tab_bdc USING 'EKPO-MWSKZ'         rec_ite-mwskz.


    CLEAR:tab_esll[].
    SELECT * INTO TABLE tab_esll
      FROM esll
        WHERE packno IN (
            SELECT  sub_packno  "取出子包号
              FROM esll
                WHERE packno IN (
                  SELECT packno "采购行 概览包号
                   FROM eban
                     WHERE banfn EQ rec_ite-banfn
                      AND  bnfpo EQ rec_ite-bnfpo
              )
          ).
    CLEAR l_lines.
    DESCRIBE TABLE tab_esll LINES l_lines.
    IF l_lines IS INITIAL.
      DATA:l_bpumn_str TYPE char3,
           l_bpumz_str TYPE char3.
      WRITE rec_ite-ktmng TO l_ktmng_str NO-GROUPING DECIMALS 2.
      WRITE rec_ite-netpr TO l_netpr_str NO-GROUPING DECIMALS 2.
      WRITE rec_ite-bpumn TO l_bpumn_str.
      WRITE rec_ite-bpumz TO l_bpumz_str.
*非服务类采购申请行，填写行其他信息
      PERFORM frm_bdc_add_field:
             TABLES tab_bdc USING  'EKPO-KTMNG'  l_ktmng_str, "数量
             TABLES tab_bdc USING  'EKPO-NETPR'  l_netpr_str, "单价
             TABLES tab_bdc USING  'EKPO-BPRME'  rec_ite-bprme,"定价单位
             TABLES tab_bdc USING  'EKPO-BPUMN'  l_bpumn_str, "分子
             TABLES tab_bdc USING  'EKPO-BPUMZ'  l_bpumz_str. "分母
    ELSE."服务行
      PERFORM frm_bdc_add_field:
            TABLES tab_bdc USING 'EKPO-TXZ01'   rec_ite-txz01,
            TABLES tab_bdc USING 'EKPO-MATKL'   rec_ite-matkl.
    ENDIF.
    DO l_lines TIMES.
*退出账户分配屏幕
      PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPLMLSK'  '0200'.
      PERFORM frm_bdc_add_field
                    TABLES tab_bdc USING  'BDC_OKCODE' '=BACK'.
    ENDDO.

*定位行
    l_ebelp = rec_ite-ebelp.
    PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPMM06E'    '0220'.
    PERFORM frm_bdc_add_field:
         TABLES tab_bdc USING 'BDC_OKCODE'         '/00' ,
         TABLES tab_bdc USING 'RM06E-EBELP'        l_ebelp. "定位行


    IF tab_esll[] IS NOT INITIAL.
*进入行服务屏幕
    PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPMM06E'    '0220'.
      PERFORM frm_bdc_add_field:
           TABLES tab_bdc USING 'BDC_OKCODE'          '=DIEN',
           TABLES tab_bdc USING 'RM06E-TCSELFLAG(01)' 'X'.
    ENDIF.


    LOOP AT tab_esll INTO rec_esll.
*定位行
      DATA:l_extrow TYPE char10.
      l_extrow = rec_esll-extrow.
*定位服务明细行
      PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPLMLSP' '0201'.
      PERFORM frm_bdc_add_field:
            TABLES tab_bdc USING 'BDC_OKCODE'    '/00',
            TABLES tab_bdc USING 'RM11P-NEW_ROW' l_extrow .
      READ TABLE it_services INTO rec_ser
                              WITH KEY ebelp  = rec_ite-ebelp
                                       extrow = rec_esll-extrow.
      IF sy-subrc EQ 0.
*修改数据
        WRITE rec_ser-menge TO l_menge_str NO-GROUPING DECIMALS 2.
        WRITE rec_ser-tbtwr TO l_tbtwr_str NO-GROUPING DECIMALS 2.
        PERFORM frm_bdc_add_dynnr
          TABLES tab_bdc USING 'SAPLMLSP' '0201'.
        PERFORM frm_bdc_add_field:
            TABLES tab_bdc USING 'BDC_OKCODE'         '/00',
            TABLES tab_bdc USING 'ESLL-KTEXT1(01)'    rec_ser-ktext1,
            TABLES tab_bdc USING 'ESLL-MENGE(01)'     l_menge_str,
"            TABLES tab_bdc USING 'ESLL-MEINS(01)'     rec_ser-meins,
            TABLES tab_bdc USING 'ESLL-TBTWR(01)'     l_tbtwr_str.
*科目确认屏幕(退出）
        PERFORM frm_bdc_add_dynnr
            TABLES tab_bdc USING 'SAPLMLSK' '0200'.
        PERFORM frm_bdc_add_field:
            TABLES tab_bdc USING 'BDC_OKCODE'         '=BACK'.
      ELSE."接口中无此服务行，则需要删除
        PERFORM frm_bdc_add_dynnr
         TABLES tab_bdc USING 'SAPLMLSP' '0201'.
        PERFORM frm_bdc_add_field:
          TABLES tab_bdc USING 'BDC_OKCODE'         '/EBDZ',
          TABLES tab_bdc USING 'RM11P-SELKZ(01)'    'X'.

*删除确认屏幕
        PERFORM frm_bdc_add_dynnr
                         TABLES tab_bdc USING 'SAPLSPO1'  '0100'.
        PERFORM frm_bdc_add_field
                         TABLES tab_bdc USING 'BDC_OKCODE' '=YES'.
      ENDIF.

    ENDLOOP.
*退出服务屏幕
    PERFORM frm_bdc_add_dynnr TABLES tab_bdc USING 'SAPLMLSP'   '0201'.
    PERFORM frm_bdc_add_field TABLES tab_bdc USING 'BDC_OKCODE' '=ESB'.
  ENDLOOP."END OF it_item
***********************概览屏幕      end********************************
  IF iv_mode EQ 'C'."创建
*保存
    PERFORM frm_bdc_add_dynnr
        TABLES tab_bdc USING 'SAPMM06E' '0220'.
    PERFORM frm_bdc_add_field:
        TABLES tab_bdc USING 'BDC_OKCODE' '=BU'.
*无消息确认
    PERFORM frm_bdc_add_dynnr
        TABLES tab_bdc USING 'SAPLSPO1' '0300'.
    PERFORM frm_bdc_add_field:
        TABLES tab_bdc USING 'BDC_OKCODE' '=YES'.
  ELSEIF iv_mode EQ 'X'."数据校验
*退出事务
    PERFORM frm_bdc_add_dynnr
        TABLES tab_bdc USING 'SAPMM06E' '0220'.
    PERFORM frm_bdc_add_field:
        TABLES tab_bdc USING 'BDC_OKCODE' '=BACK'.
*不保存数据
    PERFORM frm_bdc_add_dynnr
        TABLES tab_bdc USING 'SAPLSPO1' '0100'.
    PERFORM frm_bdc_add_field:
        TABLES tab_bdc USING 'BDC_OKCODE' '=NO'.
  ELSE.
    RAISE unkown_mode.
  ENDIF.

  IF iv_bdcmode CO 'AEN'.
    l_mode = iv_bdcmode.
  ENDIF.
*调用BDC
  CALL TRANSACTION 'ME31K' USING tab_bdc
                           MODE l_mode MESSAGES INTO tab_msg.
  LOOP AT tab_msg INTO rec_msg.
    IF rec_msg-msgtyp = 'S' AND
       rec_msg-msgid = '06' AND
       rec_msg-msgnr = '017'. "创建成功
      MESSAGE s017(06) WITH rec_msg-msgv1 rec_msg-msgv2 INTO ev_msg.
      ev_code = 0.
      ev_contract_num = rec_msg-msgv2.
*创建成功，更新文本
      CALL FUNCTION 'ZFUN1034'
        EXPORTING
          iv_contract_num = ev_contract_num
          it_header_text  = it_header_text
          it_item_text    = it_item_text.
      EXIT.
    ELSEIF rec_msg-msgtyp = 'E'.
      ev_code = 4.
      MESSAGE ID rec_msg-msgid TYPE rec_msg-msgtyp NUMBER rec_msg-msgnr
              WITH rec_msg-msgv1 rec_msg-msgv2
                   rec_msg-msgv3 rec_msg-msgv4
              INTO ev_msg.
    ENDIF.
  ENDLOOP.

  IF iv_mode EQ 'X'."数据校验模式
    IF ev_code IS INITIAL AND ev_msg IS INITIAL.
      ev_code = 0.
      ev_msg = '数据校验成功'.
    ENDIF.
  ENDIF.
ENDFUNCTION.


 

无语_843
关注
专栏目录
SAP_ABAP_MM_BAPI清单案例教程——框架协议-合同_BAPI_CONTRACT_CREATE_ME31K
java_zhong1990的专栏
08-24 708
BAPI_CONTRACT_CREATE BAPI_CONTRACT_CHANGE SAP ABAP 采购框架协议合同创建
SAP 批量创建采购信息记录（BDC）
SAP阿狸
06-25 2192
REPORT zmm_me11_batch. ******************************** *upload template: *column1: serial(can be empty) *colmn2: *colmn3: price. OBLIGATORY *colmn4: per (if it is empty, system will defind it as...
SAP MM ME31K 创建合同（登録契約：第一画面）
晴天的博客分享技术知识
05-01 119
双击警告消息即可查看消息编号系统消息可在物料管理定制的采购→环境数据→定义系统消息的属性下定义。另外，如果像上图一样，【现金割引日数】和【%】有输入的话，事先没有设定许容范围也会报错！注：有购买情报的品目会自动从 购买情报 里面取出来，而且还改不了，可能是 购买情报优先。如果没有 购买情报 的品目的话，契约 里面就可以手动输入了，而且必须输入。打开画面以后，输入 仕入先，契约Type，购买组织等信息，按下回车。契约有两种形式，MK：数量契约，WK：金额契约。在合同执行订单中检查目标数量、目标值和有效期。
ME31K-创建合同
最新发布
Heroism_的博客
08-05 132
可以引用这个合同号，去创建采购订单或者计划协议。CMK代表数量合同。CWK代表价值合同。系统会带出一个合同号。输入对应数量或价值后，点击保存。合同分为：数量合同和价值合同。
ME31K 创建框架协议
BinGeneral的博客
03-26 1320
1业务说明 在实际业务需求中，需要和供应商签订协议。 此文档使用BAPI：BAPI_CONTRACT_CREATE创建协议 2前台实现 事务代码：ME31K 输入抬头信息 行项目 行项目详细内容 保存即可 3代码实现 3.1调用BAPI 抬头 行项目 导入BAPI 3.2问题解决 3.2.1 SUBOBJECT_NOT_FOUND 在创建时报错， 错误位置在此...
创建合同-contract及应用
03-13 890
一、创建合同---ME31K 1.初始界面 initial screen： 输入vendor, 采购组织，采购组，工厂（可无）         Contract Type:1) Distribte contract 2) Value contract 3) Quanlity contract 回车。 2. 抬头数据Header data： 输入有效日期（一年或半年合同有效），目标值=总
ABAP report BDC实现创建采购合同
05-18
下面是一个简单的 ABAP Report BDC 实现创建采购合同的示例： 1. 创建一个自定义的屏幕布局，包含需要输入的采购合同信息。 2. 使用 TCODE SHDB 记录一个标准的采购合同创建过程的 BDC 数据。 3. 通过 ABAP 代码...
SAP_ABAP_MM_BADI清单案例教程——PR采购申请创建_ME_PROCESS_REQ_CUST_ME51N
java_zhong1990的专栏
10-08 597
SAP ABAP 顾问（开发工程师）能力模型_Terry谈企业数字化的博客-CSDN博客目标：基于对SAP abap 顾问能力模型的梳理，给一年左右经验的abaper 快速成长为三年经验提参考ALV/REPORT|SMARTFROM|SCREEN|OLE|BAPI|BDC|PI|IDOC|RFC|API|WEBSERVICE|Enhancement|UserExits|Badi|Debug。
SAP_ABAP_MM_BAPI清单案例教程——采购申请_BAPI_PR_CREATE_ME51N
java_zhong1990的专栏
08-25 989
SAP ABAP BAPI_PR_CREATE 采购申请 BAPI 采购申请创建函数
[MM]ME31K和ME32K采购合同保存校验的增强
07-11 454
2、ME_PURCHDOC_POSTED 该badi 订单的流水号已经生成，会出现跳号！一、想找一个仅针对采购合同校验的增强点，网上看了下，大都是和采购订单通用的，如。二、通过调试代码，找到一个比较针对采购合同的增强点：MM_PUR_S4_CTR。( mm_pur_s4_sa还顺便找到计划协议)。
SAP配置大全(MM部分)
08-08
SAP　MM　配置
SAP MM操作手册-第六套
01-29
JOMOO-MM-用户操作手册清单及完成计划-V1.0.xls JOMOO-PP-140 标准委外操作手册（二次开发）.doc JOMOO-PP-140 标准委外操作手册（标准功能）.doc SAP-MM-UM-002 供应商主数据维护操作手册.doc SAP-MM-UM-003 供应商考核评估维护用户操作手册.doc SAP-MM-UM-004 信息记录维护操作手册 .doc SAP-MM-UM-005 货源清单维护用户操作手册.doc SAP-MM-UM-006 配额协议维护用户操作手册.doc SAP-MM-UM-007 非生产性采购申请维护用户操作手册.doc SAP-MM-UM-008 标准采购操作手册.doc SAP-MM-UM-009 标准采购收货操作手册.doc SAP-MM-UM-010 固定资产、费用类采购用户操作手册.doc SAP-MM-UM-011 固定资产费用类收货用户操作手册.doc SAP-MM-UM-012 采购退货操作手册.doc SAP-MM-UM-013 供应商寄售维护用户操作手册.doc SAP-MM-UM-015 出入库管理用户操作手册.doc SAP-MM-UM-016 仓库调拨用户操作手册.doc SAP-MM-UM-017 库存盘点用户操作手册.doc
SAP 《MM学习指南》操作记录----寄售业务(创建寄售合同、订单、收货等操作)
热门推荐
heng0757的专栏
05-31 1万+
Consignment Contract 寄售合同   步骤：     1. 创建寄售信息记录（ME11）     2. 显示寄售信息记录（ME13）     3. 创建寄售合同（ME31K）     4. 货源清单管理（ME01）     5. 创建采购申请（ME51N）     6. 创建采购订单(参考采购申请)（ME21N）     7.
SAP MM 计划协议
wodegaolai的博客
01-09 2428
框架协议一般含合同me31k和计划协议me31l两种,合同是采购订单引用，计划协议当做采购订单 1 创建货源清单，注意MRP选择2，与计划协议有关 2 LP的不能对未来交货，做增强可以 3 LPA可以做JIT报表 计划协议类型： LP：仅仅只有计划行 LPA：有计划行、预测、JIT及时送货 批准凭证：预测，LPA的区别 LP: 手动创建流程 ME31L：创建协议 ME38：创建交货行 MIGO：根据交货行做系统收货 注意：计划协议在ME38中维护交货行后，日期是按照系统工厂日历日期判断，不能提前交货。
【MM系列】SAP MRKO如何操作
weixin_30532987的博客
07-12 1287
公众号：SAP Technical 本文作者：matinal 原文出处：http://www.cnblogs.com/SAPmatinal/ 原文链接：【MM系列】SAP MRKO如何操作 前言部分 大家可以关注我的公众号，公众号里的排版更好，阅读更舒适。 正文部分 求解，MRKO怎么操作 转载于:https://www.cnblogs.com/SAPma...
Custom Fields in ME31K , ME32K , ME33K
ChampaignWolf的专栏
09-19 1043
Custom Fields in ME31K , ME32K , ME33K As we know the enhancement to the screen isnot impossiblebut it is notsupportedbecause we need some S_DEVELOP authorisation and modify some of the Standard t...
使用BAPI_CONTRACT_CREATE创建采购合同框架协议
少年休闲海
12-08 1394
*&---------------------------------------------------------------------* *& Report  ZMMF201 采购合同框架协议批导程序 *& T-code  ZZME31K *&-----------------------------------------------------------------
MM采购合同和计划协议，创建物料主数据分类的特性值 BAPI :BAPI_CONTRACT_CREATE
cishai0841的博客
06-24 454
Normal 0 7.8 磅 0 2 false false false ...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值