oracle 导出数据到csv或excel文件

最新推荐文章于 2022-07-02 16:46:28 发布

李强 DST

最新推荐文章于 2022-07-02 16:46:28 发布

阅读量1.5k

点赞数

分类专栏：数据库

本文链接：https://blog.csdn.net/whereiwillgo/article/details/108297788

版权

数据库专栏收录该内容

17 篇文章 0 订阅

订阅专栏

oracle 导出数据到csv或excel文件

方法1：利用存储过程导出.csv文件

方法2：plsql developer->export query result

方法3：excel连接数据库导出

方法4：SQL*PLUS spool打印

工作中需要将Oracle中表数据导出到文本（csv、txt）或Excel（xls）文件时，有如下方法：

方法	1分钟导出的数据量	适用于
utl_file读写文件包	300万	大量导出时
plsql developer->export query result	10万	小量导出时
excel连接数据库	1万	excel 最大行数1048576
spool 循环打印	5000	可导出为文本或Excel格式

当有权限创建PL/SQL存储过程时，建议使用第一种方法，创建包含utl_file包的存储过程。

方法1：利用存储过程导出.csv文件

步骤1：创建SQL_TO_CSV存储过程

CREATE OR REPLACE PROCEDURE SQL_TO_CSV
(
 P_QUERY IN VARCHAR2, -- PLSQL文
 P_DIR IN VARCHAR2, -- 导出的文件放置目录
 P_FILENAME IN VARCHAR2 -- CSV名
 )
 IS
  L_OUTPUT UTL_FILE.FILE_TYPE;
  L_THECURSOR INTEGER DEFAULT DBMS_SQL.OPEN_CURSOR;
  L_COLUMNVALUE VARCHAR2(4000);
  L_STATUS INTEGER;
  L_COLCNT NUMBER := 0;
  L_SEPARATOR VARCHAR2(1);
  L_DESCTBL DBMS_SQL.DESC_TAB;
  P_MAX_LINESIZE NUMBER := 32000;
BEGIN
  --OPEN FILE
  L_OUTPUT := UTL_FILE.FOPEN(P_DIR, P_FILENAME, 'W', P_MAX_LINESIZE);
  --DEFINE DATE FORMAT
  EXECUTE IMMEDIATE 'ALTER SESSION SET NLS_DATE_FORMAT=''YYYY-MM-DD HH24:MI:SS''';
  --OPEN CURSOR
  DBMS_SQL.PARSE(L_THECURSOR, P_QUERY, DBMS_SQL.NATIVE);
  DBMS_SQL.DESCRIBE_COLUMNS(L_THECURSOR, L_COLCNT, L_DESCTBL);
  --DUMP TABLE COLUMN NAME
  FOR I IN 1 .. L_COLCNT LOOP
    UTL_FILE.PUT(L_OUTPUT,L_SEPARATOR || '"' || L_DESCTBL(I).COL_NAME || '"'); --输出表字段
    DBMS_SQL.DEFINE_COLUMN(L_THECURSOR, I, L_COLUMNVALUE, 4000);
    L_SEPARATOR := ',';
  END LOOP;
  UTL_FILE.NEW_LINE(L_OUTPUT); --输出表字段
  --EXECUTE THE QUERY STATEMENT
  L_STATUS := DBMS_SQL.EXECUTE(L_THECURSOR);
  --DUMP TABLE COLUMN VALUE
  WHILE (DBMS_SQL.FETCH_ROWS(L_THECURSOR) > 0) LOOP
    L_SEPARATOR := '';
    FOR I IN 1 .. L_COLCNT LOOP
      DBMS_SQL.COLUMN_VALUE(L_THECURSOR, I, L_COLUMNVALUE);
      UTL_FILE.PUT(L_OUTPUT,
                  L_SEPARATOR || '"' ||
                  TRIM(BOTH ' ' FROM REPLACE(L_COLUMNVALUE, '"', '""')) || '"');
      L_SEPARATOR := ',';
    END LOOP;
    UTL_FILE.NEW_LINE(L_OUTPUT);
  END LOOP;
  --CLOSE CURSOR
  DBMS_SQL.CLOSE_CURSOR(L_THECURSOR);
  --CLOSE FILE
  UTL_FILE.FCLOSE(L_OUTPUT);
EXCEPTION
  WHEN OTHERS THEN
    RAISE;
END;

步骤2：创建 directory目录

create or replace directory OUT_PATH as '/expdp_dir';

步骤3：拼接出导出的语句

SELECT 'EXEC sql_to_csv(''select * from ' ||T.TABLE_NAME ||''',''OUT_PATH''' || ',''ODS_MDS.' || T.TABLE_NAME ||'.csv'');' 
FROM user_TABLES T 
WHERE t.TABLE_NAME='表名';

步骤4：执行导出csv的语句

EXEC sql_to_csv('select * from A','OUT_PATH','ODS_MDS.A.csv');

.csv逗号分隔值格式文件，可用excel工具打开。

方法2：plsql developer->export query result

步骤1：查询要导出的数据，只查出部分数据即可,无需全部查询出来；

步骤2：再选择export query result ..导出csv文件，全部数据会被导出；

方法3：excel连接数据库导出

步骤：

打开excel -> 数据 -> 导入数据

-> 第一步选择数据源 -> ODBC DSN -> 根据情况输入连接信息

->选表字段等

方法4：SQL*PLUS spool打印

步骤1：进入sqlplus

步骤2：预设显示格式

col 字段 format a10  --字段设置
set term off verify off feedback off pagesize 5000 linesize 200 --查询结果设置
set markup html on entmap off spool on preformat off --HTML相关设置

SET MARKUP HTML {ON|OFF}：指定是否以html格式输出；
SET ENTMAP {ON|OFF}：指定是否用HTML字符实体如<, >, " and &等，替换特殊字符<, >, " and &
SET SPOOL {ON|OFF}：指定是否生成HTML标签<HTML> 和<BODY>, </BODY> 和</HTML>
SET PERFORMAT {ON|OFF}：指定生成HTML时输出<PRE>标签，还是HTML表格。HTML表格即是.xls保存格式。

步骤3：打开spool

spool &output_dir/&output_file.xls

步骤4：执行SQL

SQL > select * from t1;

步骤5：关闭spool

SQL > spool off

李强 DST

关注

0
点赞
踩
14

收藏

觉得还不错? 一键收藏
0
评论
oracle 导出数据到csv或excel文件

oracle 导出数据到csv文件目录oracle 导出数据到csv文件方法1：利用存储过程导出.csv文件方法2：plsql developer->export query result方法3：excel连接数据库导出方法4：SQL*PLUS spool打印工作中需要将Oracle中表数据导出到文本文件（csv、txt）时，有如下方法：方法 1分钟导出的数据量适用于 utl_file读写文件包
复制链接

扫一扫

专栏目录