sap-ABAP动态内表使用的例子

原文地址:http://wfly2004.blog.163.com/blog/static/117642720098227319456/

 

测试OK!

 

关键技巧:

1, 创建动态内表:

a, 动态内表的结构的定义.

动态内表表结构的定义必须使用表结构与 table type: lvc_t_fcat一样的内表.

一般情况下,我们都内表的所有列定义成字符型.

b, 根据表结构生成内表.

系统提供了一个标准的method来产生动态表,使用方法如下:

2, 动态内表的赋值:

a, 获取指定的字段

b, 给指定的字段赋值

3, 读取动态内表的值:

a, 获取指定的字段

b, 读取指定的字段值

 

 

*&---------------------------------------------------------------------*

*& Report  YDYN_TEST

*&

*&---------------------------------------------------------------------*

*&

*&

*&---------------------------------------------------------------------*

 

REPORT  YDYN_TEST.

FIELD-SYMBOLS:<DYN_TABLE> TYPE STANDARD TABLE,

               <DYN_WA>,

               <DYN_FIELD>.

 

DATA: DY_TABLE TYPE REF TO DATA,

      DY_LINE  TYPE REF TO DATA,

      IT_STRUCTURE TYPE LVC_T_FCAT,

      WA_STRUCTURE TYPE LVC_S_FCAT.

 

START-OF-SELECTION.

  PERFORM CREATE_STRUCTURE." 定义内表的结构

  PERFORM CREATE_DYNAMIC_TABLE." 按照定义的内表结构,产生一个内表

  PERFORM WRITE_DATA_TO_DYNTABLE." 向动态内表中写数

  PERFORM OUTPUT_DYNTABLE_DATA." 从动态内表中取数,并写到屏幕

 

*&---------------------------------------------------------------------*

*&      Form  CREATE_STRUCTURE

*&---------------------------------------------------------------------*

*       text

*----------------------------------------------------------------------*

FORM CREATE_STRUCTURE.

  WA_STRUCTURE-FIELDNAME = 'COL1'." 第列名

  WA_STRUCTURE-COL_POS = 1.         " 表示第三列 ---

  WA_STRUCTURE-INTTYPE = 'C'.        " 数据类型

  WA_STRUCTURE-INTLEN  = 6.         " 长度

  APPEND WA_STRUCTURE TO IT_STRUCTURE.

  WA_STRUCTURE-FIELDNAME = 'COL2'." 第 列名

  WA_STRUCTURE-COL_POS = 2.         " 表示第三列 ---

  WA_STRUCTURE-INTTYPE = 'C'.        " 数据类型

  WA_STRUCTURE-INTLEN  = 6.         " 长度

  APPEND WA_STRUCTURE TO IT_STRUCTURE.

  WA_STRUCTURE-FIELDNAME = 'COL3'." 第三列名

  WA_STRUCTURE-COL_POS = 3.         " 表示第三列 ---

  WA_STRUCTURE-INTTYPE = 'C'.        " 数据类型

  WA_STRUCTURE-INTLEN  = 6.         " 长度

  APPEND WA_STRUCTURE TO IT_STRUCTURE.

ENDFORM.                    "CREATE_STRUCTURE

 

*&---------------------------------------------------------------------*

*&      Form  CREATE_DYNAMIC_TABLE

*&---------------------------------------------------------------------*

*       text

*----------------------------------------------------------------------*

FORM CREATE_DYNAMIC_TABLE.

  CALL METHOD CL_ALV_TABLE_CREATE=>CREATE_DYNAMIC_TABLE

    EXPORTING

      IT_FIELDCATALOG = IT_STRUCTURE

    IMPORTING

      EP_TABLE        = DY_TABLE.

  ASSIGN DY_TABLE->* TO <DYN_TABLE>.

  "表类型指针 <dyn_table> 指向 数据对象的内容.

ENDFORM.  " create_dynamic_table

 

*&---------------------------------------------------------------------*

*&      Form  write_data_to_dyntable

*&---------------------------------------------------------------------*

FORM WRITE_DATA_TO_DYNTABLE .

  DATA:WA_NEW_LINE TYPE REF TO DATA.

  DATA:I TYPE N.

  DATA:J TYPE N.

  CREATE DATA WA_NEW_LINE LIKE LINE OF <DYN_TABLE>.

*建立一个与动态内表结构相同的数据对象,且数据对象为是一个结构

  ASSIGN WA_NEW_LINE->* TO <DYN_WA>." 用<dyn_wa>指针指向该结构

  DO 3 TIMES.

    I = I + 1.

    CLEAR J.

    LOOP AT IT_STRUCTURE INTO WA_STRUCTURE.

      J = J + 1.

      ASSIGN COMPONENT WA_STRUCTURE-FIELDNAME OF STRUCTURE <DYN_WA>

      TO <DYN_FIELD>.

*   " 用指针<DYN_FIELD>指向工作区<DYN_WA>中的一个字段,字段名为WA_STRUCTURE-FIELDNAME.

      CONCATENATE I J INTO <DYN_FIELD>." 给指针指向的字段赋值

    ENDLOOP.

    APPEND <DYN_WA> TO <DYN_TABLE>.

  ENDDO.

ENDFORM.                    "WRITE_DATA_TO_DYNTABLE

 

*&---------------------------------------------------------------------*

*&      Form  OUTPUT_DYNTABLE_DATA

*&---------------------------------------------------------------------*

*       text

*----------------------------------------------------------------------*

FORM OUTPUT_DYNTABLE_DATA.

  LOOP AT IT_STRUCTURE INTO WA_STRUCTURE.

    WRITE: WA_STRUCTURE-FIELDNAME(5).

  ENDLOOP.

  LOOP AT <DYN_TABLE> INTO <DYN_WA>.

    WRITE: / .

    LOOP AT IT_STRUCTURE INTO WA_STRUCTURE.

      ASSIGN COMPONENT WA_STRUCTURE-FIELDNAME OF STRUCTURE <DYN_WA>

       TO <DYN_FIELD>.

*用指针<DYN_FIELD>指向工作区<DYN_WA>中的一个字段,字段名为WA_STRUCTURE-FIELDNAME.

      WRITE : <DYN_FIELD>.

    ENDLOOP.

  ENDLOOP.

ENDFORM.                    "OUTPUT_DYNTABLE_DATA

  • 1
    点赞
  • 6
    收藏
    觉得还不错? 一键收藏
  • 0
    评论

“相关推荐”对你有帮助么?

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

红包个数最小为10个

红包金额最低5元

当前余额3.43前往充值 >
需支付:10.00
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值